libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 AC_ARG_ENABLE(plugin,
  88   AS_HELP_STRING([--enable-plugin],
  89                  [build gcjwebplugin web browser plugin]),
  90     [case "$enableval" in
  91       yes) plugin_enabled=yes ;;
  92       no)  plugin_enabled=no ;;
  93       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  94      esac],
  95     [plugin_enabled=no]
  96 )
  97
  98 AC_ARG_ENABLE(gconf-peer,
  99   AS_HELP_STRING([--enable-gconf-peer],
 100                  [compile GConf native peers for util.preferences]),
 101     [case "$enableval" in
 102       yes) gconf_enabled=yes ;;
 103       no)  gconf_enabled=no ;;
 104       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
 105      esac],
 106     [gconf_enabled=no]
 107 )
 108
 109 AC_ARG_ENABLE(java-maintainer-mode,
 110         AS_HELP_STRING([--enable-java-maintainer-mode],
 111         [allow rebuilding of .class and .h files]))
 112 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 113
 114 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 115 GCC_NO_EXECUTABLES
 116
 117 # (1) We use an abnormal CXX (without library references), so we
 118 # must cache it under a different name.
 119 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 120 # the non-multilib-adjusted value will be used in multilibs.
 121 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 122 # (4) As another side effect, automake doesn't automatically include them
 123 # in Makefile.in.
 124 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 125 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 126 # used in later tests.  This may not be necessary in libjava; I don't know.
 127 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 128 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 129 save_CXXFLAGS="$CXXFLAGS"
 130 CXXFLAGS="$CXXFLAGS -fno-builtin"
 131 AC_PROG_CC
 132 AC_PROG_CXX
 133 CXXFLAGS="$save_CXXFLAGS"
 134 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 135 AC_SUBST(CFLAGS)
 136 AC_SUBST(CXXFLAGS)
 137 AC_SUBST(LDFLAGS)
 138
 139 AM_INIT_AUTOMAKE([1.9.0])
 140
 141 AC_CHECK_TOOL(AS, as)
 142 AC_CHECK_TOOL(LD, ld)
 143 AC_CHECK_TOOL(AR, ar)
 144 AC_CHECK_TOOL(RANLIB, ranlib, :)
 145 AC_PROG_AWK
 146 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 147 AC_PATH_PROG([ZIP], [zip], no)
 148 AC_PATH_PROG([UNZIP], [unzip], unzip)
 149 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 150 if test "$ZIP" = no; then
 151   if test "$JAR" = no; then
 152     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 153   fi
 154 else
 155   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 156   JAR=`pwd`/scripts/jar
 157 fi
 158
 159 AC_PROG_INSTALL
 160
 161 AM_MAINTAINER_MODE
 162
 163 AC_EXEEXT
 164
 165 # configure.host sets the following important variables
 166 #       libgcj_cflags    - host specific C compiler flags
 167 #       libgcj_cxxflags  - host specific C++ compiler flags
 168 #       libgcj_javaflags - host specific Java compiler flags
 169
 170 libgcj_cflags=
 171 libgcj_cxxflags=
 172 libgcj_javaflags=
 173
 174 . ${srcdir}/configure.host
 175
 176 LIBGCJ_CFLAGS="${libgcj_cflags}"
 177 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 178 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 179 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 180 AC_SUBST(LIBGCJ_CFLAGS)
 181 AC_SUBST(LIBGCJ_CXXFLAGS)
 182 AC_SUBST(LIBGCJ_JAVAFLAGS)
 183 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 184
 185 # Only use libltdl for non-newlib builds.
 186 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 187    AC_LTDL_SHLIBPATH
 188 fi
 189
 190 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 191
 192 # See if the user has requested runtime debugging.
 193 LIBGCJDEBUG="disable"
 194 AC_SUBST(LIBGCJDEBUG)
 195 AC_ARG_ENABLE(libgcj-debug,
 196   AS_HELP_STRING([--enable-libgcj-debug],
 197                  [enable runtime debugging code]),
 198   [if test "$enable_libgcj_debug" = yes; then
 199     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 200     LIBGCJDEBUG="enable"
 201   fi])
 202
 203 AC_ARG_WITH([escher],
 204          AS_HELP_STRING([--with-escher=ABS.PATH],
 205                         [specify path to escher dir or JAR for X peers]))
 206 case "$with_escher" in
 207 "")
 208         use_escher=false
 209         ;;
 210 "no")
 211         use_escher=false
 212         ;;
 213 "yes")
 214         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 215         ;;
 216 *)
 217         use_escher=true
 218         ;;
 219 esac
 220
 221 # Determine which AWT peer libraries to build
 222 AC_ARG_ENABLE(java-awt,
 223   AS_HELP_STRING([--enable-java-awt],
 224                  [list of AWT peer implementations to be built]))
 225
 226 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 227 use_xlib_awt=""
 228 use_gtk_awt=""
 229 use_qt_awt=""
 230 use_x_awt=""
 231 # The default toolkit to use is the first one specified.
 232 TOOLKIT=
 233 AC_SUBST(TOOLKIT)
 234
 235 for peer in $peerlibs ; do
 236   case $peer in
 237     xlib)
 238       if test "$no_x" = yes; then
 239         echo "*** xlib peers requested but no X library available" 1>&2
 240         exit 1
 241       else
 242         use_xlib_awt="yes"
 243         if test -z "$TOOLKIT"; then
 244            TOOLKIT=gnu.awt.xlib.XToolkit
 245         fi
 246       fi
 247       ;;
 248     gtk)
 249       if test "$no_x" = yes; then
 250          echo "*** gtk peers requested but no X library available" 1>&2
 251          exit 1
 252       else
 253          use_gtk_awt=yes
 254          if test -z "$TOOLKIT"; then
 255             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 256          fi
 257       fi
 258       ;;
 259     qt)
 260       if test "$no_x" = yes; then
 261          # Perhaps we should admit the possibility of embedded Qt.
 262          echo "*** Qt peers requested but no X library available" 1>&2
 263          exit 1
 264       else
 265          use_qt_awt=yes
 266          if test -z "$TOOLKIT"; then
 267             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 268          fi
 269       fi
 270       ;;
 271     x)
 272       use_x_awt=yes
 273       if test -z "$TOOLKIT"; then
 274          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 275       fi
 276       ;;
 277     no)
 278       use_xlib_awt=
 279       use_gtk_awt=
 280       use_qt_awt=
 281       use_x_awt=
 282       break
 283       ;;
 284     *)
 285       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 286       exit 1
 287   esac
 288 done
 289
 290 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 291 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 292
 293 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 294
 295 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 296
 297 # Create standard.omit based on decisions we just made.
 298 cp $srcdir/standard.omit.in standard.omit
 299 if test "$use_xlib_awt" != yes; then
 300    echo gnu/awt/xlib >> standard.omit
 301    echo gnu/gcj/xlib >> standard.omit
 302 fi
 303 if test "$use_x_awt" != yes; then
 304    echo gnu/java/awt/peer/x >> standard.omit
 305 fi
 306
 307 if test -z "${with_multisubdir}"; then
 308    builddotdot=.
 309 else
 310    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 311 fi
 312
 313 NATIVE=yes
 314
 315 # Which gcj and host gcj (for ecjx) do we use?
 316 which_gcj=default
 317 host_exeext=${ac_exeext}
 318 GCJ_FOR_ECJX=
 319 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 320 if test -n "${with_cross_host}"; then
 321   # We are being configured with a cross compiler. We can't
 322   # use ac_exeext, because that is for the target platform.
 323   NATIVE=no
 324   cross_host_exeext=
 325   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 326   case "${with_cross_host}" in
 327      *mingw* | *cygwin*)
 328          cross_host_exeext=.exe
 329      ;;
 330   esac
 331   host_exeext=${cross_host_exeext}
 332   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 333      if test x"$build_noncanonical" = x"$with_cross_host"; then
 334         # Ordinary cross (host!=target and host=build)
 335         which_gcj=built
 336      else
 337         # Canadian cross (host!=target and host!=build)
 338         which_gcj=cross
 339      fi
 340   else
 341      which_gcj=cross
 342   fi
 343 else
 344   # We are being configured with a native or crossed-native compiler
 345   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 346      if test x"$build" = x"$host"; then
 347         # True native build (host=target and host=build)
 348         which_gcj=built
 349      else
 350         # Crossed-native build (host=target and host!=build)
 351         which_gcj=cross
 352      fi
 353   else
 354      which_gcj=path
 355   fi
 356 fi
 357 case "${which_gcj}" in
 358    built)
 359       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 360       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 361    ;;
 362    cross)
 363       if test "x${with_newlib}" = "xyes"; then
 364          # FIXME (comment): Why is this needed?
 365          GCC_UNWIND_INCLUDE=
 366          GCJ="${target_noncanonical}-gcj"
 367       else
 368          GCJ="$built_gcc_dir/gcj -B$built_gcc_dir/"
 369       fi
 370       GCJH="$built_gcc_dir/gcjh"
 371    ;;
 372    path)
 373       GCJ="gcj -B`${PWDCMD-pwd}`/"
 374       GCJH=gcjh
 375    ;;
 376 esac
 377
 378 AC_SUBST(GCJ_FOR_ECJX)
 379 AC_SUBST(GCJH)
 380 AC_SUBST(host_exeext)
 381
 382 # Create it, so that compile/link tests don't fail
 383 test -f libgcj.spec || touch libgcj.spec
 384
 385
 386
 387 # Set up to configure Classpath.
 388 # FIXME: no supported way to pass args in autoconf.
 389 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 390 # Disable tool wrappers to avoid ltdl.h configure check.
 391 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 392 ac_configure_args="$ac_configure_args --disable-load-library"
 393 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 394 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 395 dir1=`cd $srcdir && pwd`
 396 dir2=`pwd`
 397 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 398 ac_configure_args="$ac_configure_args --disable-core-jni"
 399 dnl FIXME?
 400 ac_configure_args="$ac_configure_args --disable-examples"
 401 ac_configure_args="$ac_configure_args --with-glibj=build"
 402 if test "$plugin_enabled" != yes; then
 403   ac_configure_args="$ac_configure_args --disable-plugin"
 404 fi
 405 if test "$gconf_enabled" != yes; then
 406   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 407   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 408 fi
 409 if test "$use_gtk_awt" != yes; then
 410   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 411 fi
 412 if test "$use_qt_awt" != yes; then
 413   ac_configure_args="$ac_configure_args --disable-qt-peer"
 414 else
 415   # We need this as qt is disabled by default in classpath.
 416   ac_configure_args="$ac_configure_args --enable-qt-peer"
 417 fi
 418 if test "$use_x_awt" != yes; then
 419   ac_configure_args="$ac_configure_args --without-escher"
 420 else
 421   # We need this as escher is disabled by default in classpath.
 422   if test "$use_escher" != true; then
 423     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 424   else
 425     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 426   fi
 427 fi
 428 # -Werror causes unavoidable problems in code using alsa.
 429 ac_configure_args="$ac_configure_args --disable-Werror"
 430 dnl --with-gcj=$GCJ
 431 dnl --with-javah=$GCJH
 432 dnl gjdoc?
 433 dnl gtk-cairo -- just export here...
 434 dnl --enable-regen-headers?
 435
 436 # Only use libltdl for non-newlib builds.
 437 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 438    AC_LIBLTDL_CONVENIENCE
 439    AC_LIBTOOL_DLOPEN
 440    DIRLTDL=libltdl
 441    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 442    # Sigh.  Libtool's macro doesn't do the right thing.
 443    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 444    # FIXME: this is a hack.
 445    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 446    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 447 fi
 448 AC_SUBST(INCLTDL)
 449 AC_SUBST(LIBLTDL)
 450 AC_SUBST(DIRLTDL)
 451 AC_PROG_LIBTOOL
 452 AM_PROG_GCJ
 453 AM_PROG_CC_C_O
 454
 455 AC_CONFIG_SUBDIRS(classpath libltdl)
 456
 457 # The -no-testsuite modules omit the test subdir.
 458 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 459
 460 # Should the runtime set system properties by examining the
 461 # environment variable GCJ_PROPERTIES?
 462 AC_ARG_ENABLE(getenv-properties,
 463   AS_HELP_STRING([--disable-getenv-properties],
 464                  [don't set system properties from GCJ_PROPERTIES]))
 465
 466 # Whether GCJ_PROPERTIES is used depends on the target.
 467 if test -z "$enable_getenv_properties"; then
 468    enable_getenv_properties=${enable_getenv_properties_default-yes}
 469 fi
 470 if test "$enable_getenv_properties" = no; then
 471    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 472      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 473 fi
 474
 475 # Whether we should use arguments to main()
 476 if test -z "$enable_main_args"; then
 477    enable_main_args=${enable_main_args_default-yes}
 478 fi
 479 if test "$enable_main_args" = no; then
 480    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 481 fi
 482
 483
 484 # Should we use hashtable-based synchronization?
 485 # Currently works only for Linux X86/ia64
 486 # Typically faster and more space-efficient
 487 AC_ARG_ENABLE(hash-synchronization,
 488   AS_HELP_STRING([--enable-hash-synchronization],
 489                  [use global hash table for monitor locks]))
 490
 491 if test -z "$enable_hash_synchronization"; then
 492    enable_hash_synchronization=$enable_hash_synchronization_default
 493 fi
 494
 495
 496 install_ecj_jar=no
 497 ECJ_BUILD_JAR=
 498 ECJ_JAR=
 499 AC_ARG_WITH(ecj-jar,
 500         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 501         [ECJ_JAR=$withval],
 502         [if test -f $libgcj_basedir/../ecj.jar; then
 503            ECJ_BUILD_JAR=$libgcj_basedir/../ecj.jar
 504            ECJ_JAR='$(jardir)/ecj.jar'
 505            install_ecj_jar=yes
 506          fi])
 507 AC_SUBST(ECJ_BUILD_JAR)
 508 AC_SUBST(ECJ_JAR)
 509 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 510 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 511
 512 AC_ARG_WITH(java-home,
 513   AS_HELP_STRING([--with-java-home=DIRECTORY],
 514                  [value of java.home system property]),
 515                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 516 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 517 AC_SUBST(JAVA_HOME)
 518
 519 # What is the native OS API for MinGW?
 520 AC_ARG_WITH(win32-nlsapi,
 521   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 522                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 523 [case "${withval}" in
 524   ansi) with_win32_nlsapi=ansi ;;
 525   unicows) with_win32_nlsapi=unicows ;;
 526   unicode) with_win32_nlsapi=unicode ;;
 527   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 528 esac],[with_win32_nlsapi=ansi])
 529
 530 case "${with_win32_nlsapi}" in
 531   unicows | unicode)
 532     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 533       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 534     ;;
 535 esac
 536
 537 # configure.host sets slow_pthread_self if the synchronization code should
 538 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 539 if test "${slow_pthread_self}" = "yes"; then
 540   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 541     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 542 fi
 543
 544 # Check for gc debugging.  This option is handled both here and in the GC.
 545 AC_ARG_ENABLE(gc-debug,
 546    AS_HELP_STRING([--enable-gc-debug],
 547                   [include full support for pointer backtracing etc.]),
 548 [ if test "$enable_gc_debug" = "yes"; then
 549     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 550               [Define if we want to use debug calls into the garbage collector.])
 551   fi])
 552
 553 # See if the user has the interpreter included.
 554 AC_ARG_ENABLE(interpreter,
 555   AS_HELP_STRING([--enable-interpreter],
 556                  [enable interpreter]),
 557   [if test "$enable_interpreter" = yes; then
 558     # This can also be set in configure.host.
 559     libgcj_interpreter=yes
 560   elif test "$enable_interpreter" = no; then
 561     libgcj_interpreter=no
 562   fi])
 563
 564 if test "$libgcj_interpreter" = yes; then
 565    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 566 fi
 567 INTERPRETER="$libgcj_interpreter"
 568 AC_SUBST(INTERPRETER)
 569
 570 AC_MSG_CHECKING([for exception model to use])
 571 AC_LANG_PUSH(C++)
 572 AC_ARG_ENABLE(sjlj-exceptions,
 573   AS_HELP_STRING([--enable-sjlj-exceptions],
 574                  [force use of builtin_setjmp for exceptions]),
 575 [:],
 576 [dnl Botheration.  Now we've got to detect the exception model.
 577 dnl Link tests against libgcc.a are problematic since -- at least
 578 dnl as of this writing -- we've not been given proper -L bits for
 579 dnl single-tree newlib and libgloss.
 580 dnl
 581 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 582 dnl conftest files before we got a change to grep them first.
 583 cat > conftest.$ac_ext << EOF
 584 [#]line __oline__ "configure"
 585 struct S { ~S(); };
 586 void bar();
 587 void foo()
 588 {
 589   S s;
 590   bar();
 591 }
 592 EOF
 593 old_CXXFLAGS="$CXXFLAGS"
 594 CXXFLAGS=-S
 595 if AC_TRY_EVAL(ac_compile); then
 596   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 597     enable_sjlj_exceptions=yes
 598   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 599     enable_sjlj_exceptions=no
 600   fi
 601 fi
 602 CXXFLAGS="$old_CXXFLAGS"
 603 rm -f conftest*])
 604 if test x$enable_sjlj_exceptions = xyes; then
 605   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 606         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 607   ac_exception_model_name=sjlj
 608 elif test x$enable_sjlj_exceptions = xno; then
 609   ac_exception_model_name="call frame"
 610 else
 611   AC_MSG_ERROR([unable to detect exception model])
 612 fi
 613 AC_LANG_POP(C++)
 614 AC_MSG_RESULT($ac_exception_model_name)
 615
 616 # If we are non using SJLJ exceptions, and this host does not have support
 617 # for unwinding from a signal handler, enable checked dereferences and divides.
 618 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 619   CHECKREFSPEC=-fcheck-references
 620   DIVIDESPEC=-fuse-divide-subroutine
 621   EXCEPTIONSPEC=
 622 fi
 623
 624 # See if the user wants to disable java.net.  This is the mildly
 625 # ugly way that we admit that target-side configuration sucks.
 626 AC_ARG_ENABLE(java-net,
 627   AS_HELP_STRING([--disable-java-net],
 628                  [disable java.net]))
 629
 630 # Whether java.net is built by default can depend on the target.
 631 if test -z "$enable_java_net"; then
 632    enable_java_net=${enable_java_net_default-yes}
 633 fi
 634 if test "$enable_java_net" = no; then
 635    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 636 fi
 637
 638 # See if the user wants to configure without libffi.  Some
 639 # architectures don't support it, and default values are set in
 640 # configure.host.
 641 AC_ARG_WITH(libffi,
 642   AS_HELP_STRING([--without-libffi],
 643                  [don't use libffi]),
 644   [:],
 645   [with_libffi=${with_libffi_default-yes}])
 646
 647 LIBFFI=
 648 LIBFFIINCS=
 649 if test "$with_libffi" != no; then
 650    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 651    LIBFFI=../libffi/libffi_convenience.la
 652    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 653 fi
 654 AC_SUBST(LIBFFI)
 655 AC_SUBST(LIBFFIINCS)
 656
 657 # See if the user wants to disable JVMPI support.
 658 AC_ARG_ENABLE(jvmpi,
 659   AS_HELP_STRING([--disable-jvmpi],
 660                  [disable JVMPI support]))
 661
 662 if test "$enable_jvmpi" != no; then
 663     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 664 fi
 665
 666 # If the target is an eCos system, use the appropriate eCos
 667 # I/O routines.
 668 # FIXME: this should not be a local option but a global target
 669 # system; at present there is no eCos target.
 670 TARGET_ECOS=${PROCESS-"no"}
 671 AC_ARG_WITH(ecos,
 672 [  --with-ecos             enable runtime eCos target support],
 673 TARGET_ECOS="$with_ecos"
 674 )
 675
 676 case "$TARGET_ECOS" in
 677    no) case "$host" in
 678       *mingw*)
 679             PLATFORM=Win32
 680             PLATFORMNET=Win32
 681             PLATFORMH=win32.h
 682         CHECK_FOR_BROKEN_MINGW_LD
 683       ;;
 684       *)
 685             PLATFORM=Posix
 686             PLATFORMNET=Posix
 687             PLATFORMH=posix.h
 688       ;;
 689       esac
 690       ;;
 691    *)
 692       PLATFORM=Ecos
 693       PLATFORMNET=NoNet
 694       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 695       PLATFORMH=posix.h
 696       ;;
 697 esac
 698 AC_SUBST(PLATFORM)
 699 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 700
 701 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 702                                       [Define if you have int32_t and uint32_t.]))
 703 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 704                                         [Define if you have int32_t and uint32_t.]))
 705 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 706                                           [Define if you have u_int32_t]))
 707 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 708                                            [Define if you have u_int32_t]))
 709
 710 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 711 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 712
 713 case "$host" in
 714   *-darwin*) DARWIN_CRT=true ;;
 715   *) DARWIN_CRT=false ;;
 716 esac
 717 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 718
 719 # These may not be defined in a non-ANS conformant embedded system.
 720 # FIXME: Should these case a runtime exception in that case?
 721 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 722                                   [Define is you have 'mktime' in <time.h>]))
 723 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 724                                   [Define is you have 'localtime' in <time.h>]))
 725
 726 # Create the subdirectory for natFile.cc, or the attempt
 727 # to create the link will fail.
 728 test -d java || mkdir java
 729 test -d java/io || mkdir java/io
 730 test -d gnu || mkdir gnu
 731 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 732
 733 # Likewise for natConcreteProcess.cc.
 734 test -d java/lang || mkdir java/lang
 735 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 736
 737 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 738 test -d java/net || mkdir java/net
 739 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 740 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 741
 742 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 743 test -d gnu/java || mkdir gnu/java
 744 test -d gnu/java/net || mkdir gnu/java/net
 745 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 746 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 747
 748 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 749 test -d gnu/java/nio || mkdir gnu/java/nio
 750 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 751 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 752 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 753 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 754
 755 case "${host}" in
 756     *mingw*)
 757       SYSTEMSPEC="-lgdi32 -lws2_32"
 758       if test "${with_win32_nlsapi}" = "unicows"; then
 759         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 760       fi
 761     ;;
 762     *)
 763       SYSTEMSPEC=
 764     ;;
 765 esac
 766 AC_SUBST(SYSTEMSPEC)
 767
 768 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 769 AC_SUBST(LIBGCJTESTSPEC)
 770
 771 AC_ARG_WITH(system-zlib,
 772   AS_HELP_STRING([--with-system-zlib],
 773                  [use installed libz]))
 774 ZLIBSPEC=
 775 AC_SUBST(ZLIBSPEC)
 776 ZLIBTESTSPEC=
 777 AC_SUBST(ZLIBTESTSPEC)
 778
 779 AC_PATH_XTRA
 780
 781 # FIXME: this should be _libs on some hosts.
 782 libsubdir=.libs
 783
 784 # extra LD Flags which are required for targets
 785 case "${host}" in
 786 *-*-darwin[[0-7]].*)
 787     # For now we have to disable it on darwin[8-9] because it slows down
 788     # the linking phase. A possible bug in ld?
 789     # on Darwin -single_module speeds up loading of the dynamic libraries.
 790     extra_ldflags_libjava=-Wl,-single_module
 791     ;;
 792 esac
 793 AC_SUBST(extra_ldflags_libjava)
 794
 795 # Allow the GC to be disabled.  Can be useful when debugging.
 796 AC_MSG_CHECKING([for garbage collector to use])
 797 AC_ARG_ENABLE(java-gc,
 798   AS_HELP_STRING([--enable-java-gc=TYPE],
 799                  [choose garbage collector (default is boehm)]),
 800   [GC=$enableval],
 801   [GC=boehm])
 802 GCLIBS=
 803 GCINCS=
 804 GCDEPS=
 805 GCSPEC=
 806 JC1GCSPEC=
 807 GCTESTSPEC=
 808 case "$GC" in
 809  boehm)
 810     AC_MSG_RESULT(boehm)
 811     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 812     JC1GCSPEC='-fuse-boehm-gc'
 813     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 814     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 815     GCOBJS=boehm.lo
 816     GCHDR=boehm-gc.h
 817     # The POSIX thread support needs to know this.
 818     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 819     ;;
 820  no)
 821     AC_MSG_RESULT(none)
 822     GCHDR=no-gc.h
 823     ;;
 824  *)
 825     AC_MSG_ERROR([unrecognized collector "$GC"])
 826     ;;
 827 esac
 828 AC_SUBST(GCLIBS)
 829 AC_SUBST(GCINCS)
 830 AC_SUBST(GCDEPS)
 831 AC_SUBST(GCSPEC)
 832 AC_SUBST(JC1GCSPEC)
 833 AC_SUBST(GCTESTSPEC)
 834 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 835 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 836 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 837
 838
 839 AC_MSG_CHECKING([for thread model used by GCC])
 840 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 841 AC_MSG_RESULT([$THREADS])
 842
 843 case "$THREADS" in
 844  no | none | single)
 845     THREADS=none
 846     ;;
 847  posix | posix95 | pthreads)
 848     THREADS=posix
 849     case "$host" in
 850      *-*-linux*)
 851         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 852         ;;
 853     esac
 854     ;;
 855  win32)
 856     ;;
 857  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 858     AC_MSG_ERROR(thread package $THREADS not yet supported)
 859     ;;
 860  *)
 861     AC_MSG_ERROR($THREADS is an unknown thread package)
 862     ;;
 863 esac
 864
 865 THREADCXXFLAGS=
 866 THREADLDFLAGS=
 867 THREADLIBS=
 868 THREADINCS=
 869 THREADDEPS=
 870 THREADH=
 871 THREADSPEC=
 872 THREADSTARTFILESPEC=
 873 case "$THREADS" in
 874  posix)
 875     case "$host" in
 876      *-*-cygwin*)
 877         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 878         ;;
 879      *-*-freebsd[[1234]]*)
 880         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 881         # merely adds pthread_* functions) but it does have a -pthread switch
 882         # which is required at link-time to select -lc_r *instead* of -lc.
 883         THREADLDFLAGS=-pthread
 884         # Don't set THREADSPEC here as might be expected since -pthread is
 885         # not processed when found within a spec file, it must come from
 886         # the command line.  For now, the user must provide the -pthread
 887         # switch to link code compiled with gcj.  In future, consider adding
 888         # support for weak references to pthread_* functions ala gthr.h API.
 889         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 890         ;;
 891      *-*-freebsd*)
 892         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 893         # systems which support threads and -lpthread.
 894         THREADLDFLAGS=-pthread
 895         THREADSPEC=-lpthread
 896         ;;
 897      alpha*-dec-osf* | hppa*-hp-hpux*)
 898         THREADCXXFLAGS=-pthread
 899         # boehm-gc needs some functions from librt, so link that too.
 900         THREADLIBS='-lpthread -lrt'
 901         THREADSPEC='-lpthread -lrt'
 902         ;;
 903      *)
 904         THREADLIBS=-lpthread
 905         THREADSPEC=-lpthread
 906         ;;
 907     esac
 908     THREADH=posix-threads.h
 909     # MIT pthreads doesn't seem to have the mutexattr functions.
 910     # But for now we don't check for it.  We just assume you aren't
 911     # using MIT pthreads.
 912     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 913
 914     # If we're using the Boehm GC, then we happen to know that it
 915     # defines _REENTRANT, so we don't bother.  Eww.
 916     if test "$GC" != boehm; then
 917        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 918     fi
 919     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 920     ;;
 921
 922  win32)
 923     THREADH=win32-threads.h
 924     THREADCXXFLAGS=-mthreads
 925     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 926     # But we do not want the executables created to be dependent on
 927     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 928     # exception handling contexts.  The following kludge achieves this effect
 929     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 930     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 931     # A workaround is to explicitly use -mthreads while linking Java programs.
 932     # See PR libgcj/28263.
 933     #
 934     # FIXME: In Java we are able to detect thread death at the end of
 935     # Thread.run() so we should be able to clean up the exception handling
 936     # contexts ourselves.
 937     THREADSTARTFILESPEC='crtmt%O%s'
 938     ;;
 939
 940  none)
 941     THREADH=no-threads.h
 942     ;;
 943 esac
 944 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 945 AC_SUBST(THREADLIBS)
 946 AC_SUBST(THREADINCS)
 947 AC_SUBST(THREADDEPS)
 948 AC_SUBST(THREADSPEC)
 949 AC_SUBST(THREADSTARTFILESPEC)
 950 AC_SUBST(THREADLDFLAGS)
 951 AC_SUBST(THREADCXXFLAGS)
 952 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 953 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 954 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 955 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 956
 957 if test -d sysdep; then true; else mkdir sysdep; fi
 958 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 959 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 960 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 961
 962 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 963 if test "$use_libgcj_bc" = yes; then
 964   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 965 fi
 966 AC_SUBST(LIBGCJ_SPEC)
 967
 968 HASH_SYNC_SPEC=
 969 # Hash synchronization is only useful with posix threads right now.
 970 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 971    HASH_SYNC_SPEC=-fhash-synchronization
 972    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 973 fi
 974 AC_SUBST(HASH_SYNC_SPEC)
 975
 976 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 977
 978 # We're in the tree with gcc, and need to include some of its headers.
 979 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 980
 981 if test "x${with_newlib}" = "xyes"; then
 982    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 983    # may not work correctly, because the compiler may not be able to
 984    # link executables.
 985
 986    # We assume newlib.  This lets us hard-code the functions we know
 987    # we'll have.
 988    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 989    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 990    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 991    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 992    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 993    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 994    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 995    # This is only for POSIX threads.
 996    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 997    # We also assume we are using gcc, which provides alloca.
 998    AC_DEFINE(HAVE_ALLOCA)
 999
1000    # Assume we do not have getuid and friends.
1001    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1002    PLATFORMNET=NoNet
1003 else
1004    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
1005                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
1006                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1007                    nl_langinfo setlocale \
1008                    inet_pton uname inet_ntoa \
1009                    fork execvp pipe sigaction ftruncate mmap \
1010                    getifaddrs])
1011    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1012    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
1013    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1014    AC_CHECK_LIB(dl, dladdr, [
1015        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1016        AC_CHECK_LIB(dld, dladdr, [
1017        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1018
1019    if test x"$build" = x"$host"; then
1020      AC_CHECK_FILES(/proc/self/exe, [
1021        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1022    else
1023      case $host in
1024      *-linux*)
1025        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1026        ;;
1027      esac
1028    fi
1029
1030    AM_ICONV
1031    AM_LC_MESSAGES
1032    AC_STRUCT_TIMEZONE
1033
1034    AC_CHECK_FUNCS(gethostbyname_r, [
1035      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1036        [Define if you have the 'gethostbyname_r' function.])
1037      # There are two different kinds of gethostbyname_r.
1038      # We look for the one that returns `int'.
1039      # Hopefully this check is robust enough.
1040      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1041        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1042
1043      case " $GCINCS " in
1044      *" -D_REENTRANT "*) ;;
1045      *)
1046         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1047         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1048         [libjava_cv_gethostbyname_r_needs_reentrant],
1049         [ AC_LANG_PUSH(C++)
1050           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1051             [[gethostbyname_r("", 0, 0);]])],
1052             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1053                 CPPFLAGS_SAVE="$CPPFLAGS"
1054                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1055                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1056                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1057                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1058                 CPPFLAGS="$CPPFLAGS_SAVE"
1059           ])
1060           AC_LANG_POP(C++)
1061         ])
1062         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1063           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1064         fi
1065      ;;
1066      esac
1067
1068      AC_CACHE_CHECK([for struct hostent_data],
1069         [libjava_cv_struct_hostent_data], [dnl
1070         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1071 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1072 # define _REENTRANT 1
1073 #endif
1074 #include <netdb.h>]], [[struct hostent_data data;]])],
1075           [libjava_cv_struct_hostent_data=yes],
1076           [libjava_cv_struct_hostent_data=no])])
1077      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1078        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1079          [Define if struct hostent_data is defined in netdb.h])
1080      fi
1081    ])
1082
1083    # FIXME: libjava source code expects to find a prototype for
1084    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1085    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1086    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1087    # linkage check is enough, yet C++ code requires proper prototypes.)
1088    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1089    AC_CHECK_FUNCS(gethostbyaddr_r, [
1090      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1091        [Define if you have the 'gethostbyaddr_r' function.])
1092      # There are two different kinds of gethostbyaddr_r.
1093      # We look for the one that returns `int'.
1094      # Hopefully this check is robust enough.
1095      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1096        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1097          [Define if gethostbyaddr_r returns 'int'.])])])])
1098
1099    AC_CHECK_FUNCS(gethostname, [
1100      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1101        [Define if you have the 'gethostname' function.])
1102      AC_EGREP_HEADER(gethostname, unistd.h, [
1103        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1104          [Define if gethostname is declared in <unistd.h>.])])])
1105
1106    AC_CHECK_FUNCS(usleep, [
1107      AC_EGREP_HEADER(usleep, unistd.h, [
1108        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1109           [Define if usleep is declared in <unistd.h>.])])])
1110
1111    # Look for these functions in the thread library, but only bother
1112    # if using POSIX threads.
1113    if test "$THREADS" = posix; then
1114       save_LIBS="$LIBS"
1115       LIBS="$LIBS $THREADLIBS"
1116       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1117       # E.g., Solaris.
1118       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1119
1120       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1121       # Solaris 7 the name librt is preferred.
1122       AC_CHECK_FUNCS(sched_yield, , [
1123         AC_CHECK_LIB(rt, sched_yield, [
1124           AC_DEFINE(HAVE_SCHED_YIELD)
1125           THREADLIBS="$THREADLIBS -lrt"
1126           THREADSPEC="$THREADSPEC -lrt"], [
1127           AC_CHECK_LIB(posix4, sched_yield, [
1128             AC_DEFINE(HAVE_SCHED_YIELD)
1129             THREADLIBS="$THREADLIBS -lposix4"
1130             THREADSPEC="$THREADSPEC -lposix4"])])])
1131
1132       AC_CHECK_LIB(rt, clock_gettime, [
1133          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1134          case "$THREADSPEC" in
1135            *-lrt*) ;;
1136            *)
1137              THREADSPEC="$THREADSPEC -lrt"
1138              THREADLIBS="$THREADLIBS -lrt"
1139              ;;
1140          esac])
1141
1142       LIBS="$save_LIBS"
1143
1144       # We can save a little space at runtime if the mutex has m_count
1145       # or __m_count.  This is a nice hack for Linux.
1146       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1147           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1148         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1149              [Define if pthread_mutex_t has m_count member.]), [
1150         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1151             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1152           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1153             [Define if pthread_mutex_t has __m_count member.]))])
1154    fi
1155
1156    # We require a way to get the time.
1157    time_found=no
1158    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1159    if test "$time_found" = no; then
1160       AC_MSG_ERROR([no function found to get the time])
1161    fi
1162
1163    AC_CHECK_FUNCS(memmove)
1164
1165    # We require memcpy.
1166    memcpy_found=no
1167    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1168    if test "$memcpy_found" = no; then
1169       AC_MSG_ERROR([memcpy is required])
1170    fi
1171    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1172    AC_CHECK_LIB(dl, dlopen, [
1173        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1174        AC_CHECK_LIB(dld, dlopen, [
1175        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1176
1177    # Some library-finding code we stole from Tcl.
1178    #--------------------------------------------------------------------
1179    #    Check for the existence of the -lsocket and -lnsl libraries.
1180    #    The order here is important, so that they end up in the right
1181    #    order in the command line generated by make.  Here are some
1182    #    special considerations:
1183    #    1. Use "connect" and "accept" to check for -lsocket, and
1184    #       "gethostbyname" to check for -lnsl.
1185    #    2. Use each function name only once:  can't redo a check because
1186    #       autoconf caches the results of the last check and won't redo it.
1187    #    3. Use -lnsl and -lsocket only if they supply procedures that
1188    #       aren't already present in the normal libraries.  This is because
1189    #       IRIX 5.2 has libraries, but they aren't needed and they're
1190    #       bogus:  they goof up name resolution if used.
1191    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1192    #       To get around this problem, check for both libraries together
1193    #       if -lsocket doesn't work by itself.
1194    #--------------------------------------------------------------------
1195
1196    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1197     [gcj_cv_lib_sockets=
1198      gcj_checkBoth=0
1199      unset ac_cv_func_connect
1200      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1201      if test "$gcj_checkSocket" = 1; then
1202          unset ac_cv_func_connect
1203          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1204                       gcj_checkBoth=1)
1205      fi
1206      if test "$gcj_checkBoth" = 1; then
1207          gcj_oldLibs=$LIBS
1208          LIBS="$LIBS -lsocket -lnsl"
1209          unset ac_cv_func_accept
1210          AC_CHECK_FUNC(accept,
1211                        [gcj_checkNsl=0
1212                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1213          unset ac_cv_func_accept
1214          LIBS=$gcj_oldLibs
1215      fi
1216      unset ac_cv_func_gethostbyname
1217      gcj_oldLibs=$LIBS
1218      LIBS="$LIBS $gcj_cv_lib_sockets"
1219      AC_CHECK_FUNC(gethostbyname, ,
1220                    [AC_CHECK_LIB(nsl, main,
1221                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1222      unset ac_cv_func_gethostbyname
1223      LIBS=$gcj_oldLIBS
1224    ])
1225    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1226
1227    if test "$with_system_zlib" = yes; then
1228       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1229    fi
1230
1231    LIBMAGIC=
1232    AC_CHECK_LIB(magic, magic_open, [
1233       AC_DEFINE([HAVE_MAGIC_OPEN], 1, [Define if you have magic_open().])
1234       LIBMAGIC="-lmagic"])
1235    AC_SUBST(LIBMAGIC)
1236
1237    # Test for Gtk stuff, if asked for.
1238    if test "$use_gtk_awt" = yes; then
1239       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1240       AC_SUBST(GTK_CFLAGS)
1241       AC_SUBST(GTK_LIBS)
1242
1243       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1244       AC_SUBST(GLIB_CFLAGS)
1245       AC_SUBST(GLIB_LIBS)
1246
1247       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1248       AC_SUBST(LIBART_CFLAGS)
1249       AC_SUBST(LIBART_LIBS)
1250
1251       # We require the XTest Extension to support java.awt.Robot.
1252       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1253                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1254                    [${X_LIBS}])
1255    fi
1256
1257    # On Solaris, and maybe other architectures, the Boehm collector
1258    # requires -ldl.
1259    if test "$GC" = boehm; then
1260       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1261    fi
1262 fi
1263
1264 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1265 case $build in
1266     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1267     *)         CLASSPATH_SEPARATOR=':' ;;
1268 esac
1269 AC_SUBST(CLASSPATH_SEPARATOR)
1270
1271 # We must search the source tree for java.lang, since we still don't
1272 # have libgcj.jar nor java/lang/*.class
1273 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1274 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1275
1276 # Since some classes depend on this one, we need its source available
1277 # before we can do any GCJ compilation test :-(
1278 if test ! -f gnu/classpath/Configuration.java; then
1279   test -d gnu || mkdir gnu
1280   test -d gnu/classpath || mkdir gnu/classpath
1281   # Note that it is not crucial that all the values here be correct.
1282   sed -e "s,@prefix@,$prefix," \
1283       -e "s,@VERSION@,$VERSION," \
1284       -e "s,@LIBDEBUG@,false," \
1285       -e "s,@INIT_LOAD_LIBRARY@,false," \
1286       -e "s,@@,$LIBGCJDEBUG," \
1287       -e "s,@default_toolkit@,$TOOLKIT," \
1288       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1289       -e "s,@GTK_CAIRO_ENABLED@,false," \
1290         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1291         > gnu/classpath/Configuration.java
1292   # We do not want to redirect the output of the grep below to /dev/null,
1293   # but we add /dev/null to the input list so that grep will print the
1294   # filename of Configuration.java in case it finds any matches.
1295   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1296     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1297   fi
1298 fi
1299
1300 LT_AC_PROG_GCJ
1301
1302 # Now remove it.
1303 rm -f gnu/classpath/Configuration.java
1304
1305 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1306
1307 AC_CHECK_SIZEOF(void *)
1308
1309 AC_C_BIGENDIAN
1310
1311 ZLIBS=
1312 SYS_ZLIBS=
1313 ZINCS=
1314
1315 if test -z "$ZLIBSPEC"; then
1316    # Use zlib from the GCC tree.
1317    ZINCS='-I$(top_srcdir)/../zlib'
1318    ZLIBS=../zlib/libzgcj_convenience.la
1319 else
1320    # System's zlib.
1321    SYS_ZLIBS="$ZLIBSPEC"
1322 fi
1323 AC_SUBST(ZLIBS)
1324 AC_SUBST(SYS_ZLIBS)
1325 AC_SUBST(ZINCS)
1326 AC_SUBST(DIVIDESPEC)
1327 AC_SUBST(CHECKREFSPEC)
1328 AC_SUBST(EXCEPTIONSPEC)
1329 AC_SUBST(BACKTRACESPEC)
1330 AC_SUBST(IEEESPEC)
1331
1332 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1333 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1334 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1335 AC_SUBST(GCC_UNWIND_INCLUDE)
1336
1337 # Process the option "--enable-version-specific-runtime-libs"
1338 # Calculate toolexeclibdir
1339 case ${version_specific_libs} in
1340   yes)
1341     # Need the gcc compiler version to know where to install libraries
1342     # and header files if --enable-version-specific-runtime-libs option
1343     # is selected.
1344     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1345     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1346     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1347     toolexeclibdir=$toolexecmainlibdir
1348     ;;
1349   no)
1350     if test -n "$with_cross_host" &&
1351        test x"$with_cross_host" != x"no"; then
1352       # Install a library built with a cross compiler in tooldir, not libdir.
1353       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1354       toolexecmainlibdir='$(toolexecdir)/lib'
1355     else
1356       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1357       toolexecmainlibdir='$(libdir)'
1358     fi
1359     multi_os_directory=`$CC -print-multi-os-directory`
1360     case $multi_os_directory in
1361       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1362       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1363     esac
1364     ;;
1365 esac
1366 AC_SUBST(toolexecdir)
1367 AC_SUBST(toolexecmainlibdir)
1368 AC_SUBST(toolexeclibdir)
1369
1370 # Determine where the standard .db file and GNU Classpath JNI
1371 # libraries are found.
1372 multi_os_directory=`$CC -print-multi-os-directory`
1373 case $multi_os_directory in
1374   .)
1375    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1376    ;;
1377   *)
1378    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1379    ;;
1380 esac
1381 AC_SUBST(dbexecdir)
1382
1383 # Determine gcj version number.
1384 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1385 GCJVERSION=$gcjversion
1386 AC_SUBST(GCJVERSION)
1387 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1388
1389 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1390 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1391
1392 TL_AC_GXX_INCLUDE_DIR
1393
1394 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1395 # On that system, sys/ioctl.h will not include sys/filio.h unless
1396 # BSD_COMP is defined; just including sys/filio.h is simpler.
1397 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1398 # for now.  If you change this, you also must update natFile.cc.
1399 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1400                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1401                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1402                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1403                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1404 AC_CHECK_HEADERS(inttypes.h, [
1405     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1406     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1407 ])
1408 AC_HEADER_SYS_WAIT
1409
1410 AC_CHECK_TYPE([ssize_t], [int])
1411
1412 AC_MSG_CHECKING([for in_addr_t])
1413 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1414 #if STDC_HEADERS
1415 #include <stdlib.h>
1416 #include <stddef.h>
1417 #endif
1418 #if HAVE_NETINET_IN_H
1419 #include <netinet/in.h>
1420 #endif]], [[in_addr_t foo;]])],
1421   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1422      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1423    AC_MSG_RESULT(yes)],
1424   [AC_MSG_RESULT(no)])
1425
1426 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1427 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1428   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1429      [Define if struct ip_mreq is defined in netinet/in.h.])
1430    AC_MSG_RESULT(yes)],
1431   [AC_MSG_RESULT(no)])
1432
1433 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1434 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1435   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1436      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1437    AC_MSG_RESULT(yes)],
1438   [AC_MSG_RESULT(no)])
1439
1440 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1441 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1442   [AC_DEFINE(HAVE_INET6, 1,
1443      [Define if inet6 structures are defined in netinet/in.h.])
1444    AC_MSG_RESULT(yes)],
1445   [AC_MSG_RESULT(no)])
1446
1447 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1448 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1449 #include <sys/types.h>
1450 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1451   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1452    AC_MSG_RESULT(yes)],
1453   [AC_MSG_RESULT(no)])
1454
1455 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1456 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1457   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1458    AC_MSG_RESULT(yes)],
1459   [AC_MSG_RESULT(no)
1460    AC_MSG_CHECKING([for global timezone variable])
1461    dnl FIXME: we don't want a link check here because that won't work
1462    dnl when cross-compiling.  So instead we make an assumption that
1463    dnl the header file will mention timezone if it exists.
1464    dnl Don't find the win32 function timezone
1465    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1466      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1467       AC_MSG_RESULT(yes)],
1468      [AC_MSG_RESULT(no)
1469        AC_MSG_CHECKING([for global _timezone variable])
1470        dnl FIXME: As above, don't want link check
1471        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1472          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1473             [Define if your platform has the global _timezone variable.])
1474           AC_MSG_RESULT(yes)],
1475           [AC_MSG_RESULT(no)])])])
1476
1477 AC_FUNC_ALLOCA
1478
1479 AC_CHECK_PROGS(PERL, perl, false)
1480
1481 SYSDEP_SOURCES=
1482 SIGNAL_HANDLER_AUX=
1483
1484 case "${host}" in
1485  i?86-*-linux*)
1486     SIGNAL_HANDLER=include/i386-signal.h
1487     ;;
1488  sparc*-sun-solaris*)
1489     SIGNAL_HANDLER=include/sparc-signal.h
1490     ;;
1491 # ia64-*)
1492 #    SYSDEP_SOURCES=sysdep/ia64.c
1493 #    test -d sysdep || mkdir sysdep
1494 #    ;;
1495  hppa*-*-linux*)
1496     SIGNAL_HANDLER=include/pa-signal.h
1497     ;;
1498  hppa*-hp-hpux*)
1499     SIGNAL_HANDLER=include/hppa-signal.h
1500     ;;
1501  ia64-*-linux*)
1502     SIGNAL_HANDLER=include/dwarf2-signal.h
1503     ;;
1504  powerpc*-*-linux*)
1505     SIGNAL_HANDLER=include/powerpc-signal.h
1506     ;;
1507  alpha*-*-linux*)
1508     SIGNAL_HANDLER=include/dwarf2-signal.h
1509     ;;
1510  s390*-*-linux*)
1511     SIGNAL_HANDLER=include/s390-signal.h
1512     ;;
1513  x86_64*-*-linux*)
1514     SIGNAL_HANDLER=include/x86_64-signal.h
1515     SIGNAL_HANDLER_AUX=include/i386-signal.h
1516     ;;
1517  sparc*-*-linux*)
1518     SIGNAL_HANDLER=include/dwarf2-signal.h
1519     ;;
1520  sh*-*-linux*)
1521     SIGNAL_HANDLER=include/sh-signal.h
1522     ;;
1523  *mingw*)
1524     SIGNAL_HANDLER=include/win32-signal.h
1525     ;;
1526  mips*-*-linux*)
1527     SIGNAL_HANDLER=include/mips-signal.h
1528     ;;
1529  powerpc*-*-darwin*)
1530     SIGNAL_HANDLER=include/darwin-signal.h
1531     ;;
1532  *)
1533     SIGNAL_HANDLER=include/default-signal.h
1534     ;;
1535 esac
1536
1537 # If we're using sjlj exceptions, forget what we just learned.
1538 if test "$enable_sjlj_exceptions" = yes; then
1539    SIGNAL_HANDLER=include/default-signal.h
1540    SIGNAL_HANDLER_AUX=
1541 fi
1542
1543 AC_SUBST(SYSDEP_SOURCES)
1544
1545 if test -z "$SIGNAL_HANDLER_AUX"; then
1546   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1547 fi
1548
1549 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1550                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1551
1552 if test "${multilib}" = "yes"; then
1553   multilib_arg="--enable-multilib"
1554 else
1555   multilib_arg=
1556 fi
1557
1558 # See if we support thread-local storage.
1559 GCC_CHECK_TLS
1560
1561 # For _Unwind_GetIPInfo.
1562 GCC_CHECK_UNWIND_GETIPINFO
1563
1564 # Check if linker supports static linking on a per library basis
1565 LD_START_STATIC_SPEC=
1566 LD_FINISH_STATIC_SPEC=
1567 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1568   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1569     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1570     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1571   fi
1572 fi
1573 AC_SUBST(LD_START_STATIC_SPEC)
1574 AC_SUBST(LD_FINISH_STATIC_SPEC)
1575
1576 here=`${PWDCMD-pwd}`
1577 AC_SUBST(here)
1578
1579 # We get this from the environment.
1580 AC_SUBST(GCJFLAGS)
1581
1582 AC_CONFIG_FILES([
1583 Makefile
1584 libgcj.pc
1585 libgcj.spec
1586 libgcj-test.spec
1587 gcj/Makefile
1588 include/Makefile
1589 testsuite/Makefile
1590 ])
1591
1592 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1593
1594 AC_CONFIG_COMMANDS([default],
1595 [# Only add multilib support code if we just rebuilt top-level Makefile.
1596 case " $CONFIG_FILES " in
1597  *" Makefile "*)
1598    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1599    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1600    ;;
1601 esac
1602 for ac_multi_file in $CONFIG_FILES; do
1603   case $ac_multi_file in
1604   */Makefile)
1605     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1606   esac
1607 done
1608 ],
1609 srcdir=${srcdir}
1610 host=${host}
1611 target=${target}
1612 with_multisubdir=${with_multisubdir}
1613 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1614 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1615 libgcj_basedir=${libgcj_basedir}
1616 CC="${CC}"
1617 CXX="${CXX}"
1618 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1619 )
1620
1621 AC_OUTPUT