libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 AM_PROG_LIBTOOL
  21
  22 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  23    COMPPATH=.
  24 else
  25    COMPPATH=..
  26 fi
  27 AC_SUBST(COMPPATH)
  28
  29 dnl The -no-testsuite modules omit the test subdir.
  30 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  31
  32 dnl See whether the user prefers size or speed for Character.
  33 dnl The default is size.
  34 AC_ARG_ENABLE(fast-character,
  35 [  --enable-fast-character prefer speed over size for Character],
  36 # Nothing
  37 , AC_DEFINE(COMPACT_CHARACTER))
  38
  39 dnl Should the runtime set system properties by examining the
  40 dnl environment variable GCJ_PROPERTIES?
  41 AC_ARG_ENABLE(getenv-properties,
  42 [  --disable-getenv-properties
  43                           don't set system properties from GCJ_PROPERTIES])
  44
  45 dnl Whether GCJ_PROPERTIES is used depends on the target.
  46 if test -n "$enable_getenv_properties"; then
  47    enable_getenv_properties=${enable_getenv_properties_default-yes}
  48 fi
  49 if test "$enable_getenv_properties" = no; then
  50    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  51 fi
  52
  53 dnl See if the user has requested runtime debugging.
  54 AC_ARG_ENABLE(libgcj-debug,
  55 [  --enable-libgcj-debug   enable runtime debugging code],
  56   if test "$enable_libgcj_debug" = yes; then
  57      AC_DEFINE(DEBUG)
  58   fi)
  59
  60 dnl See if the user has the enterpreter included.
  61 AC_ARG_ENABLE(interpreter,
  62 [  --enable-interpreter    enable interpreter],
  63   if test "$enable_interpreter" = yes; then
  64      AC_DEFINE(INTERPRETER)
  65   fi)
  66
  67 dnl See if the user wants to disable java.net.  This is the mildly
  68 dnl ugly way that we admit that target-side configuration sucks.
  69 AC_ARG_ENABLE(java-net,
  70 [  --disable-java-net      disable java.net])
  71
  72 dnl Whether java.net is built by default can depend on the target.
  73 if test -n "$enable_java_net"; then
  74    enable_java_net=${enable_java_net_default-yes}
  75 fi
  76 if test "$enable_java_net" = no; then
  77    AC_DEFINE(DISABLE_JAVA_NET)
  78 fi
  79
  80 dnl If the target is an eCos system, use the appropriate eCos
  81 dnl I/O routines.
  82 dnl FIXME: this should not be a local option but a global target
  83 dnl system; at present there is no eCos target.
  84 TARGET_ECOS="no"
  85 AC_ARG_WITH(ecos,
  86 [  --with-ecos             enable runtime eCos target support],
  87 TARGET_ECOS="$with_ecos"
  88 )
  89
  90 case "$TARGET_ECOS" in
  91    no)
  92       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
  93       PROCESS=${PROCESS-Posix}
  94       ;;
  95    *)
  96       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
  97       PROCESS=Ecos
  98       AC_DEFINE(ECOS)
  99       ;;
 100 esac
 101
 102 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 103 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 104 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 105 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 106
 107
 108 dnl These may not be defined in a non-ANS conformant embedded system.
 109 dnl FIXME: Should these case a runtime exception in that case?
 110 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 111 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 112
 113 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 114 dnl to create the link will fail.
 115 test -d java || mkdir java
 116 test -d java/io || mkdir java/io
 117 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 118
 119 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 120 test -d java/lang || mkdir java/lang
 121 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 122 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 123
 124 SYSTEMSPEC=
 125 AC_SUBST(SYSTEMSPEC)
 126
 127 AC_ARG_WITH(system-zlib,
 128 [  --with-system-zlib      use installed libz])
 129 ZLIBSPEC=
 130 AC_SUBST(ZLIBSPEC)
 131
 132 dnl FIXME: this should be _libs on some hosts.
 133 libsubdir=.libs
 134
 135 dnl Allow the GC to be disabled.  Can be useful when debugging.
 136 AC_MSG_CHECKING([for garbage collector to use])
 137 AC_ARG_ENABLE(java-gc,
 138 changequote(<<,>>)dnl
 139 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 140 changequote([,])
 141   GC=$enableval,
 142   GC=boehm)
 143 GCLIBS=
 144 GCINCS=
 145 GCDEPS=
 146 GCOBJS=
 147 GCSPEC=
 148 case "$GC" in
 149  boehm)
 150     AC_MSG_RESULT(boehm)
 151     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 152     # We include the path to the boehm-gc build directory.
 153     # See Makefile.am to understand why.
 154     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 155     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 156     GCSPEC='-lgcjgc'
 157     dnl We also want to pick up some cpp flags required when including
 158     dnl boehm-config.h.  Yuck.
 159     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 160     GCOBJS=boehm.lo
 161     GCHDR=boehm-gc.h
 162     dnl The POSIX thread support needs to know this.
 163     AC_DEFINE(HAVE_BOEHM_GC)
 164     ;;
 165  no)
 166     AC_MSG_RESULT(none)
 167     GCOBJS=nogc.lo
 168     GCHDR=no-gc.h
 169     ;;
 170  *)
 171     AC_MSG_ERROR(unrecognized collector \"$GC\")
 172     ;;
 173 esac
 174 AC_SUBST(GCLIBS)
 175 AC_SUBST(GCINCS)
 176 AC_SUBST(GCDEPS)
 177 AC_SUBST(GCOBJS)
 178 AC_SUBST(GCSPEC)
 179 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 180
 181
 182 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 183 dnl In particular both packages must make the same decision about which
 184 dnl thread package to use.
 185 AC_MSG_CHECKING([for threads package to use])
 186 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 187   THREADS=$enableval,
 188   dnl FIXME: figure out native threads to use here.
 189   THREADS=no)
 190
 191 if test "$THREADS" = yes; then
 192    case "$host" in
 193     *-*-vxworks*)
 194        THREADS=vxworks
 195        ;;
 196     *-*-linux*)
 197        # FIXME: this isn't correct in all cases.
 198        THREADS=posix
 199        ;;
 200     *-*-win*)
 201        THREADS=win32
 202        ;;
 203     *-*-irix*)
 204        # FIXME: for now, choose POSIX, because we implement that.
 205        # Later, choose irix threads.
 206        THREADS=posix
 207        ;;
 208     *-*-solaris*)
 209        # FIXME: for now, choose POSIX, because we implement that.
 210        # Later, choose solaris threads.
 211        THREADS=posix
 212        ;;
 213     *)
 214        # For now.
 215        THREADS=none
 216        ;;
 217    esac
 218 fi
 219
 220 case "$THREADS" in
 221  no | none | single)
 222     THREADS=none
 223     ;;
 224  posix | pthreads)
 225     THREADS=posix
 226     case "$host" in
 227      *-*-linux*)
 228         AC_DEFINE(LINUX_THREADS)
 229         ;;
 230     esac
 231     ;;
 232  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 233     AC_MSG_ERROR(thread package $THREADS not yet supported)
 234     ;;
 235  *)
 236     AC_MSG_ERROR($THREADS is an unknown thread package)
 237     ;;
 238 esac
 239 AC_MSG_RESULT($THREADS)
 240
 241 THREADLIBS=
 242 THREADINCS=
 243 THREADDEPS=
 244 THREADOBJS=
 245 THREADH=
 246 THREADSPEC=
 247 case "$THREADS" in
 248  posix)
 249     THREADLIBS=-lpthread
 250     THREADSPEC=-lpthread
 251     THREADOBJS=posix-threads.lo
 252     THREADH=posix-threads.h
 253     # MIT pthreads doesn't seem to have the mutexattr functions.
 254     # But for now we don't check for it.  We just assume you aren't
 255     # using MIT pthreads.
 256     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 257     ;;
 258
 259  none)
 260     THREADOBJS=no-threads.lo
 261     THREADH=no-threads.h
 262     ;;
 263 esac
 264 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 265 AC_SUBST(THREADLIBS)
 266 AC_SUBST(THREADINCS)
 267 AC_SUBST(THREADDEPS)
 268 AC_SUBST(THREADOBJS)
 269 AC_SUBST(THREADSPEC)
 270
 271 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 272
 273 CANADIAN=no
 274 NULL_TARGET=no
 275 NATIVE=yes
 276
 277 # Find eh-common.h and support headers.  If we're in the tree with
 278 # gcc, then look there.  Otherwise look in compat-include.  If all else
 279 # fails, just hope the user has set things up somehow.
 280 if test -r $srcdir/../gcc/eh-common.h; then
 281    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 282 else
 283    if test -d $srcdir/../compat-include; then
 284       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 285    else
 286       EH_COMMON_INCLUDE=
 287    fi
 288 fi
 289
 290 if test -n "${with_cross_host}"; then
 291    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 292    # may not work correctly, because the compiler may not be able to
 293    # link executables.
 294
 295    # We assume newlib.  This lets us hard-code the functions we know
 296    # we'll have.
 297    AC_DEFINE(HAVE_MEMMOVE)
 298    AC_DEFINE(HAVE_MEMCPY)
 299    AC_DEFINE(HAVE_STRERROR)
 300    AC_DEFINE(HAVE_GMTIME_R)
 301    AC_DEFINE(HAVE_LOCALTIME_R)
 302    dnl This is only for POSIX threads.
 303    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 304    dnl We also assume we are using gcc, which provides alloca.
 305    AC_DEFINE(HAVE_ALLOCA)
 306
 307    ZLIBSPEC=-lzgcj
 308
 309    # If Canadian cross, then don't pick up tools from the build
 310    # directory.
 311    if test "$build" != "$with_cross_host"; then
 312       CANADIAN=yes
 313       EH_COMMON_INCLUDE=
 314       GCJ="${target_alias}-gcj"
 315    else
 316       GCJ=
 317    fi
 318    NATIVE=no
 319 else
 320    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 321    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r)
 322    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 323    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 324    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 325
 326    AC_CHECK_FUNCS(gethostbyname_r, [
 327      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 328      # There are two different kinds of gethostbyname_r.
 329      # We look for the one that returns `int'.
 330      # Hopefully this check is robust enough.
 331      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 332        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 333
 334      case " $GCINCS " in
 335      *" -D_REENTRANT "*) ;;
 336      *)
 337         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 338         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 339         [libjava_cv_gethostbyname_r_needs_reentrant],
 340         [ AC_LANG_SAVE
 341           AC_LANG_CPLUSPLUS
 342           AC_TRY_COMPILE([#include <netdb.h>],
 343             [gethostbyname_r("", 0, 0);],
 344             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 345                 CPPFLAGS_SAVE="$CPPFLAGS"
 346                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 347                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 348                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 349                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 350                 CPPFLAGS="$CPPFLAGS_SAVE"
 351           ])
 352           AC_LANG_RESTORE
 353         ])
 354         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 355           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 356         fi
 357      ;;
 358      esac
 359
 360      AC_CACHE_CHECK([for struct hostent_data],
 361         [libjava_cv_struct_hostent_data], [dnl
 362         AC_TRY_COMPILE([
 363 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 364 # define _REENTRANT 1
 365 #endif
 366 #include <netdb.h>], [struct hostent_data data;],
 367           [libjava_cv_struct_hostent_data=yes],
 368           [libjava_cv_struct_hostent_data=no])])
 369      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 370        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 371          [Define if struct hostent_data is defined in netdb.h])
 372      fi
 373    ])
 374
 375    AC_CHECK_FUNCS(gethostbyaddr_r, [
 376      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 377      # There are two different kinds of gethostbyaddr_r.
 378      # We look for the one that returns `int'.
 379      # Hopefully this check is robust enough.
 380      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 381        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 382
 383    AC_CHECK_FUNCS(gethostname, [
 384      AC_DEFINE(HAVE_GETHOSTNAME)
 385      AC_EGREP_HEADER(gethostname, unistd.h, [
 386        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 387
 388    # Look for these functions in the thread library, but only bother
 389    # if using POSIX threads.
 390    if test "$THREADS" = posix; then
 391       save_LIBS="$LIBS"
 392       LIBS="$LIBS $THREADLIBS"
 393       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 394       # E.g., Solaris.
 395       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 396
 397       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 398       # Solaris 7 the name librt is preferred.
 399       AC_CHECK_FUNCS(sched_yield, , [
 400         AC_CHECK_LIB(rt, sched_yield, [
 401           AC_DEFINE(HAVE_SCHED_YIELD)
 402           THREADLIBS="$THREADLIBS -lrt"
 403           THREADSPEC="$THREADSPEC -lrt"], [
 404           AC_CHECK_LIB(posix4, sched_yield, [
 405             AC_DEFINE(HAVE_SCHED_YIELD)
 406             THREADLIBS="$THREADLIBS -lposix4"
 407             THREADSPEC="$THREADSPEC -lposix4"])])])
 408       LIBS="$save_LIBS"
 409
 410       # We can save a little space at runtime if the mutex has m_count
 411       # or __m_count.  This is a nice hack for Linux.
 412       AC_TRY_COMPILE([#include <pthread.h>], [
 413           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 414         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 415         AC_TRY_COMPILE([#include <pthread.h>], [
 416             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 417           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 418    fi
 419
 420    # We require a way to get the time.
 421    time_found=no
 422    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 423    if test "$time_found" = no; then
 424       AC_MSG_ERROR([no function found to get the time])
 425    fi
 426
 427    AC_CHECK_FUNCS(memmove)
 428
 429    # We require memcpy.
 430    memcpy_found=no
 431    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 432    if test "$memcpy_found" = no; then
 433       AC_MSG_ERROR([memcpy is required])
 434    fi
 435
 436    # Some library-finding code we stole from Tcl.
 437    #--------------------------------------------------------------------
 438    #    Check for the existence of the -lsocket and -lnsl libraries.
 439    #    The order here is important, so that they end up in the right
 440    #    order in the command line generated by make.  Here are some
 441    #    special considerations:
 442    #    1. Use "connect" and "accept" to check for -lsocket, and
 443    #       "gethostbyname" to check for -lnsl.
 444    #    2. Use each function name only once:  can't redo a check because
 445    #       autoconf caches the results of the last check and won't redo it.
 446    #    3. Use -lnsl and -lsocket only if they supply procedures that
 447    #       aren't already present in the normal libraries.  This is because
 448    #       IRIX 5.2 has libraries, but they aren't needed and they're
 449    #       bogus:  they goof up name resolution if used.
 450    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 451    #       To get around this problem, check for both libraries together
 452    #       if -lsocket doesn't work by itself.
 453    #--------------------------------------------------------------------
 454
 455    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 456     [gcj_cv_lib_sockets=
 457      gcj_checkBoth=0
 458      unset ac_cv_func_connect
 459      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 460      if test "$gcj_checkSocket" = 1; then
 461          unset ac_cv_func_connect
 462          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 463                       gcj_checkBoth=1)
 464      fi
 465      if test "$gcj_checkBoth" = 1; then
 466          gcj_oldLibs=$LIBS
 467          LIBS="$LIBS -lsocket -lnsl"
 468          unset ac_cv_func_accept
 469          AC_CHECK_FUNC(accept,
 470                        [gcj_checkNsl=0
 471                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 472          unset ac_cv_func_accept
 473          LIBS=$gcj_oldLibs
 474      fi
 475      unset ac_cv_func_gethostbyname
 476      gcj_oldLibs=$LIBS
 477      LIBS="$LIBS $gcj_cv_lib_sockets"
 478      AC_CHECK_FUNC(gethostbyname, ,
 479                    [AC_CHECK_LIB(nsl, main,
 480                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 481      unset ac_cv_func_gethostbyname
 482      LIBS=$gcj_oldLIBS
 483    ])
 484    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 485
 486    if test "$with_system_zlib" = yes; then
 487       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 488    else
 489       ZLIBSPEC=-lzgcj
 490    fi
 491
 492    # On Solaris, and maybe other architectures, the Boehm collector
 493    # requires -ldl.
 494    if test "$GC" = boehm; then
 495       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 496    fi
 497
 498    if test -d "$libgcj_basedir/../gcc/java"; then
 499       GCJ=
 500    else
 501       CANADIAN=yes
 502       NULL_TARGET=yes
 503       GCJ=gcj
 504    fi
 505 fi
 506
 507 ZLIBS=
 508 ZDEPS=
 509 ZINCS=
 510 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 511    # We include the path to the zlib build directory.
 512    # See Makefile.am to understand why.
 513    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 514    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 515    ZINCS='-I$(top_srcdir)/../zlib'
 516 else
 517    ZLIBS="$ZLIBSPEC"
 518 fi
 519 AC_SUBST(ZLIBS)
 520 AC_SUBST(ZDEPS)
 521 AC_SUBST(ZINCS)
 522 AC_SUBST(DIVIDESPEC)
 523
 524 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 525 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 526 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 527 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 528 AC_SUBST(EH_COMMON_INCLUDE)
 529
 530 # Determine gcj version number.
 531 if test "$GCJ" = ""; then
 532    if test -z "${with_multisubdir}"; then
 533       builddotdot=.
 534    else
 535 changequote(<<,>>)
 536       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 537 changequote([,])
 538    fi
 539    dir="`cd ${builddotdot}/../../gcc && pwd`"
 540    GCJ="$dir/gcj -B$dir/"
 541 fi
 542 changequote(<<,>>)
 543 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 544 changequote([,])
 545 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 546
 547 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 548 # we want to continue to support that version.
 549 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 550 cat > conftest.java << 'END'
 551 public class conftest { }
 552 END
 553 use_fuse=yes
 554 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 555    conftest.java > /dev/null 2>&1 \
 556    || use_fuse=no
 557 rm -f conftest.java
 558 if test "$use_fuse" = no; then
 559    DIVIDESPEC=
 560 fi
 561 AC_MSG_RESULT($use_fuse)
 562
 563 AC_SUBST(AM_RUNTESTFLAGS)
 564
 565 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 566 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 567 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 568 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 569 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 570 dnl for now.  If you change this, you also must update natFile.cc.
 571 AC_CHECK_HEADERS(dirent.h)
 572
 573 AC_CHECK_TYPE([ssize_t], [int])
 574
 575 AC_MSG_CHECKING([for in_addr_t])
 576 AC_TRY_COMPILE([#include <sys/types.h>
 577 #if STDC_HEADERS
 578 #include <stdlib.h>
 579 #include <stddef.h>
 580 #endif
 581 #if HAVE_NETINET_IN_H
 582 #include <netinet/in.h>
 583 #endif], [in_addr_t foo;],
 584   [AC_DEFINE([HAVE_IN_ADDR_T])
 585    AC_MSG_RESULT(yes)],
 586   [AC_MSG_RESULT(no)])
 587
 588 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 589 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 590   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 591    AC_MSG_RESULT(yes)],
 592   [AC_MSG_RESULT(no)])
 593
 594 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 595 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 596   [AC_DEFINE(HAVE_INET6)
 597    AC_MSG_RESULT(yes)],
 598   [AC_MSG_RESULT(no)])
 599
 600 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 601 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 602   [AC_DEFINE(HAVE_SOCKLEN_T)
 603    AC_MSG_RESULT(yes)],
 604   [AC_MSG_RESULT(no)])
 605
 606 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 607 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 608   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 609    AC_MSG_RESULT(yes)],
 610   [AC_MSG_RESULT(no)
 611    AC_MSG_CHECKING([for global timezone variable])
 612    dnl FIXME: we don't want a link check here because that won't work
 613    dnl when cross-compiling.  So instead we make an assumption that
 614    dnl the header file will mention timezone if it exists.
 615    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 616      [AC_DEFINE(HAVE_TIMEZONE)
 617       AC_MSG_RESULT(yes)],
 618      [AC_MSG_RESULT(no)])])
 619
 620 AC_FUNC_ALLOCA
 621
 622 AC_CHECK_PROGS(PERL, perl, false)
 623
 624 case "${host}" in
 625   i?86-*-linux*)
 626     SIGNAL_HANDLER=include/i386-signal.h
 627         ;;
 628   sparc-sun-solaris*)
 629     SIGNAL_HANDLER=include/sparc-signal.h
 630         ;;
 631   *)
 632     SIGNAL_HANDLER=include/default-signal.h
 633         ;;
 634 esac
 635
 636 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 637
 638 if test "${multilib}" = "yes"; then
 639   multilib_arg="--enable-multilib"
 640 else
 641   multilib_arg=
 642 fi
 643
 644 here=`pwd`
 645 AC_SUBST(here)
 646
 647 AC_OUTPUT(Makefile libgcj.spec gcj/Makefile include/Makefile testsuite/Makefile,
 648 [if test -n "$CONFIG_FILES"; then
 649   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 650 fi],
 651 srcdir=${srcdir}
 652 host=${host}
 653 target=${target}
 654 with_multisubdir=${with_multisubdir}
 655 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 656 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 657 libgcj_basedir=${libgcj_basedir}
 658 CC="${CC}"
 659 CXX="${CXX}"
 660 )