libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30
  31 dnl
  32 dnl Initialize basic configure bits.
  33 dnl
  34 dnl Substs:
  35 dnl  multi_basedir
  36 dnl
  37 AC_DEFUN([GLIBCXX_TOPREL_CONFIGURE], [
  38   # Sets up multi_basedir, which is srcdir/.. plus the usual
  39   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  40   AM_ENABLE_MULTILIB(, ..)
  41
  42   # The generated code is exactly the same, except that automake's looks in
  43   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  44   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  45   # know what they are or what the other differences might be (and they keep
  46   # changing anyhow).
  47   #
  48   # Looking in multi_basedir seems smarter, so actually execute that branch.
  49   if false; then
  50     # this is for automake
  51     AC_CONFIG_AUX_DIR(..)
  52   else
  53     # this is for autoconf
  54     AC_CONFIG_AUX_DIRS(${multi_basedir})
  55   fi
  56
  57   dnl XXX Turn this on.
  58   dnl AC_LANG_CPLUSPLUS
  59 ])
  60
  61
  62 dnl
  63 dnl Initialize the rest of the library configury.  At this point we have
  64 dnl variables like $host.
  65 dnl
  66 dnl Sets:
  67 dnl  gcc_version          (x.y.z format)
  68 dnl  SUBDIRS
  69 dnl Substs:
  70 dnl  glibcxx_builddir     (absolute path)
  71 dnl  glibcxx_srcdir       (absolute path)
  72 dnl  toplevel_srcdir      (absolute path)
  73 dnl  with_cross_host
  74 dnl  with_newlib
  75 dnl  with_target_subdir
  76 dnl plus
  77 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  78 dnl  - default settings for all AM_CONFITIONAL test variables
  79 dnl  - lots of tools, like CC and CXX
  80 dnl
  81 AC_DEFUN([GLIBCXX_CONFIGURE], [
  82   # Keep these sync'd with the list in Makefile.am.  The first provides an
  83   # expandable list at autoconf time; the second provides an expandable list
  84   # (i.e., shell variable) at configure time.
  85   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  86   SUBDIRS='glibcxx_SUBDIRS'
  87
  88   # These need to be absolute paths, yet at the same time need to
  89   # canonicalize only relative paths, because then amd will not unmount
  90   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  91   glibcxx_builddir=`${PWDCMD-pwd}`
  92   case $srcdir in
  93     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  94     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95   esac
  96   toplevel_srcdir=${glibcxx_srcdir}/..
  97   AC_SUBST(glibcxx_builddir)
  98   AC_SUBST(glibcxx_srcdir)
  99   AC_SUBST(toplevel_srcdir)
 100
 101   # We use these options to decide which functions to include.  They are
 102   # set from the top level.
 103   AC_ARG_WITH([target-subdir],
 104     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 105                    [configuring in a subdirectory]))
 106
 107   AC_ARG_WITH([cross-host],
 108     AC_HELP_STRING([--with-cross-host=HOST],
 109                    [configuring with a cross compiler]))
 110
 111   AC_ARG_WITH([newlib],
 112     AC_HELP_STRING([--with-newlib],
 113                    [assume newlib as a system C library]))
 114
 115   # We're almost certainly being configured before anything else which uses
 116   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 117   # we not cache the value of CXX that we "discover" here, because it's set
 118   # to something unique for us and libjava.  Other target libraries need to
 119   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 120   # process by sneakily renaming the cache variable.  This also lets us debug
 121   # the value of "our" CXX in postmortems.
 122   #
 123   # We must also force CXX to /not/ be a precious variable, otherwise the
 124   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 125   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 126   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 127   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 128   #
 129   # -fno-builtin must be present here so that a non-conflicting form of
 130   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 131
 132   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 133   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 134   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 135   save_CXXFLAGS="$CXXFLAGS"
 136   CXXFLAGS="$CXXFLAGS -fno-builtin"
 137   AC_PROG_CC
 138   AC_PROG_CXX
 139   CXXFLAGS="$save_CXXFLAGS"
 140   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141   AC_SUBST(CFLAGS)
 142   AC_SUBST(CXXFLAGS)
 143
 144   # For directory versioning (e.g., headers) and other variables.
 145   AC_MSG_CHECKING([for GCC version number])
 146   gcc_version=`$CXX -dumpversion`
 147   AC_MSG_RESULT($gcc_version)
 148
 149   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 150   # available).  Uncomment the next line to force a particular method.
 151   AC_PROG_LN_S
 152   #LN_S='cp -p'
 153
 154   AC_CHECK_TOOL(AS, as)
 155   AC_CHECK_TOOL(AR, ar)
 156   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 157
 158   AM_MAINTAINER_MODE
 159
 160   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 161   # which are themselves conditionally expanded.
 162   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 163   ## other macros from doing the same.  This should be automated.)  -pme
 164   need_libmath=no
 165   enable_wchar_t=no
 166   #enable_libstdcxx_debug=no
 167   #enable_libstdcxx_pch=no
 168   #enable_cheaders=c
 169   #c_compatibility=no
 170   #enable_abi_check=no
 171   #enable_symvers=no
 172   #enable_hosted_libstdcxx=yes
 173
 174   # Find platform-specific directories containing configuration info.
 175   # Also possibly modify flags used elsewhere, as needed by the platform.
 176   GLIBCXX_CHECK_HOST
 177 ])
 178
 179
 180 m4_include([linkage.m4])
 181 m4_include([../config/no-executables.m4])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Defines:
 190 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 191 dnl   new inlining code or the new system_header pragma will die on -Werror.
 192 dnl   Leave it out by default and use maint-mode to use it.
 193 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl   compiler supports it and the user has not requested debug mode.
 195 dnl
 196 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 197   # All these tests are for C++; save the language and the compiler flags.
 198   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 199   # found in GLIBCXX_CONFIGURE.
 200   AC_LANG_SAVE
 201   AC_LANG_CPLUSPLUS
 202   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 203   ac_save_CXXFLAGS="$CXXFLAGS"
 204
 205   # Check for maintainer-mode bits.
 206   if test x"$USE_MAINTAINER_MODE" = xno; then
 207     WERROR=''
 208   else
 209     WERROR='-Werror'
 210   fi
 211
 212   # Check for -ffunction-sections -fdata-sections
 213   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 214   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 215   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Defines:
 239 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 240 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 241 dnl  LD (as a side effect of testing)
 242 dnl Sets:
 243 dnl  with_gnu_ld
 244 dnl  glibcxx_gnu_ld_version (possibly)
 245 dnl
 246 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 247 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 248 dnl
 249 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 250   # If we're not using GNU ld, then there's no point in even trying these
 251   # tests.  Check for that first.  We should have already tested for gld
 252   # by now (in libtool), but require it now just to be safe...
 253   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 254   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 255   AC_REQUIRE([AC_PROG_LD])
 256   AC_REQUIRE([AC_PROG_AWK])
 257
 258   # The name set by libtool depends on the version of libtool.  Shame on us
 259   # for depending on an impl detail, but c'est la vie.  Older versions used
 260   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 261   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 262   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 263   # set (hence we're using an older libtool), then set it.
 264   if test x${with_gnu_ld+set} != xset; then
 265     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 266       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 267       with_gnu_ld=no
 268     else
 269       with_gnu_ld=$ac_cv_prog_gnu_ld
 270     fi
 271   fi
 272
 273   # Start by getting the version number.  I think the libtool test already
 274   # does some of this, but throws away the result.
 275   changequote(,)
 276   ldver=`$LD --version 2>/dev/null | head -1 | \
 277          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 278   changequote([,])
 279   glibcxx_gnu_ld_version=`echo $ldver | \
 280          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 281
 282   # Set --gc-sections.
 283   if test "$with_gnu_ld" = "notbroken"; then
 284     # GNU ld it is!  Joy and bunny rabbits!
 285
 286     # All these tests are for C++; save the language and the compiler flags.
 287     # Need to do this so that g++ won't try to link in libstdc++
 288     ac_test_CFLAGS="${CFLAGS+set}"
 289     ac_save_CFLAGS="$CFLAGS"
 290     CFLAGS='-x c++  -Wl,--gc-sections'
 291
 292     # Check for -Wl,--gc-sections
 293     # XXX This test is broken at the moment, as symbols required for linking
 294     # are now in libsupc++ (not built yet).  In addition, this test has
 295     # cored on solaris in the past.  In addition, --gc-sections doesn't
 296     # really work at the moment (keeps on discarding used sections, first
 297     # .eh_frame and now some of the glibc sections for iconv).
 298     # Bzzzzt.  Thanks for playing, maybe next time.
 299     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 300     AC_TRY_RUN([
 301      int main(void)
 302      {
 303        try { throw 1; }
 304        catch (...) { };
 305        return 0;
 306      }
 307     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 308     if test "$ac_test_CFLAGS" = set; then
 309       CFLAGS="$ac_save_CFLAGS"
 310     else
 311       # this is the suspicious part
 312       CFLAGS=''
 313     fi
 314     if test "$ac_sectionLDflags" = "yes"; then
 315       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 316     fi
 317     AC_MSG_RESULT($ac_sectionLDflags)
 318   fi
 319
 320   # Set linker optimization flags.
 321   if test x"$with_gnu_ld" = x"yes"; then
 322     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 323   fi
 324
 325   AC_SUBST(SECTION_LDFLAGS)
 326   AC_SUBST(OPT_LDFLAGS)
 327 ])
 328
 329
 330 dnl
 331 dnl Check to see if this target can enable the wchar_t parts.
 332 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 333 dnl must have been previously checked.)  By default, wide characters are
 334 dnl disabled.
 335 dnl
 336 dnl Defines:
 337 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 338 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 339 dnl
 340 AC_DEFUN([GLIBCXX_CHECK_WCHAR_T_SUPPORT], [
 341   # Test wchar.h for mbstate_t, which is needed for char_traits and
 342   # others even if wchar_t support is not on.
 343   AC_MSG_CHECKING([for mbstate_t])
 344   AC_TRY_COMPILE([#include <wchar.h>],
 345   [mbstate_t teststate;],
 346   have_mbstate_t=yes, have_mbstate_t=no)
 347   AC_MSG_RESULT($have_mbstate_t)
 348   if test x"$have_mbstate_t" = xyes; then
 349     AC_DEFINE(HAVE_MBSTATE_T)
 350   fi
 351
 352   # Sanity check for existence of ISO C99 headers for extended encoding.
 353   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 354   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 355
 356   # Only continue checking if the ISO C99 headers exist and support is on.
 357   if test x"$ac_has_wchar_h" = xyes &&
 358      test x"$ac_has_wctype_h" = xyes &&
 359      test x"$enable_c_mbchar" != xno; then
 360
 361     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 362     # numeric_limits can instantiate type_traits<wchar_t>
 363     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 364     AC_TRY_COMPILE([#include <wchar.h>],
 365     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 366     has_wchar_minmax=yes, has_wchar_minmax=no)
 367     AC_MSG_RESULT($has_wchar_minmax)
 368
 369     # Test wchar.h for WEOF, which is what we use to determine whether
 370     # to specialize for char_traits<wchar_t> or not.
 371     AC_MSG_CHECKING([for WEOF])
 372     AC_TRY_COMPILE([
 373       #include <wchar.h>
 374       #include <stddef.h>],
 375     [wint_t i = WEOF;],
 376     has_weof=yes, has_weof=no)
 377     AC_MSG_RESULT($has_weof)
 378
 379     # Tests for wide character functions used in char_traits<wchar_t>.
 380     ac_wfuncs=yes
 381     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 382     [],[ac_wfuncs=no])
 383
 384     # Checks for names injected into std:: by the c_std headers.
 385     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 386     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 387     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 388     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 389     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 390     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 391     [],[ac_wfuncs=no])
 392
 393     # Checks for wide character functions that are not required
 394     # for basic wchar_t support.  Don't disable support if they are missing.
 395     # Injection of these is wrapped with guard macros.
 396     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 397
 398     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 399     if test x"$has_weof" = xyes &&
 400        test x"$has_wchar_minmax" = xyes &&
 401        test x"$ac_wfuncs" = xyes;
 402     then
 403       ac_isoC99_wchar_t=yes
 404     else
 405       ac_isoC99_wchar_t=no
 406     fi
 407     AC_MSG_RESULT($ac_isoC99_wchar_t)
 408
 409     # Use iconv for wchar_t to char conversions. As such, check for
 410     # X/Open Portability Guide, version 2 features (XPG2).
 411     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 412     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 413
 414     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 415     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 416     ac_save_LIBS="$LIBS"
 417     LIBS="$LIBS $libiconv"
 418
 419     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 420     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 421
 422     LIBS="$ac_save_LIBS"
 423
 424     AC_MSG_CHECKING([for XPG2 wchar_t support])
 425     if test x"$ac_has_iconv_h" = xyes &&
 426        test x"$ac_has_langinfo_h" = xyes &&
 427        test x"$ac_XPG2funcs" = xyes;
 428     then
 429       ac_XPG2_wchar_t=yes
 430     else
 431       ac_XPG2_wchar_t=no
 432     fi
 433     AC_MSG_RESULT($ac_XPG2_wchar_t)
 434
 435     # At the moment, only enable wchar_t specializations if all the
 436     # above support is present.
 437     if test x"$ac_isoC99_wchar_t" = xyes &&
 438        test x"$ac_XPG2_wchar_t" = xyes;
 439     then
 440       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 441       enable_wchar_t=yes
 442     fi
 443   fi
 444   AC_MSG_CHECKING([for enabled wchar_t specializations])
 445   AC_MSG_RESULT($enable_wchar_t)
 446 ])
 447
 448
 449 dnl
 450 dnl Check for headers for, and arguments to, the setrlimit() function.
 451 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 452 dnl
 453 dnl Defines:
 454 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 455 dnl  various HAVE_MEMLIMIT_* for individual limit names
 456 dnl
 457 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 458   AC_TRY_COMPILE(
 459     [#include <unistd.h>
 460      #include <sys/time.h>
 461      #include <sys/resource.h>
 462     ],
 463     [ int f = RLIMIT_$1 ; ],
 464     [glibcxx_mresult=1], [glibcxx_mresult=0])
 465   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 466                      [Only used in build directory testsuite_hooks.h.])
 467 ])
 468
 469 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 470   setrlimit_have_headers=yes
 471   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 472                    [],
 473                    [setrlimit_have_headers=no])
 474   # If don't have the headers, then we can't run the tests now, and we
 475   # won't be seeing any of these during testsuite compilation.
 476   if test $setrlimit_have_headers = yes; then
 477     # Can't do these in a loop, else the resulting syntax is wrong.
 478     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 479     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 480     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 481     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 482
 483     # Check for rlimit, setrlimit.
 484     AC_CACHE_VAL(ac_setrlimit, [
 485       AC_TRY_COMPILE(
 486         [#include <unistd.h>
 487          #include <sys/time.h>
 488          #include <sys/resource.h>
 489         ],
 490         [struct rlimit r;
 491          setrlimit(0, &r);],
 492         [ac_setrlimit=yes], [ac_setrlimit=no])
 493     ])
 494   fi
 495
 496   AC_MSG_CHECKING([for testsuite memory limit support])
 497   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 498     ac_mem_limits=yes
 499     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 500   else
 501     ac_mem_limits=no
 502   fi
 503   AC_MSG_RESULT($ac_mem_limits)
 504 ])
 505
 506
 507 dnl
 508 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 509 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 510 dnl
 511 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 512   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 513     AC_TRY_LINK(
 514       [#include <sys/stat.h>],
 515       [struct stat buffer;
 516        fstat(0, &buffer);
 517        S_ISREG(buffer.st_mode);],
 518       [glibcxx_cv_S_ISREG=yes],
 519       [glibcxx_cv_S_ISREG=no])
 520   ])
 521   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 522     AC_TRY_LINK(
 523       [#include <sys/stat.h>],
 524       [struct stat buffer;
 525        fstat(0, &buffer);
 526        S_IFREG & buffer.st_mode;],
 527       [glibcxx_cv_S_IFREG=yes],
 528       [glibcxx_cv_S_IFREG=no])
 529   ])
 530   if test $glibcxx_cv_S_ISREG = yes; then
 531     AC_DEFINE(HAVE_S_ISREG)
 532   elif test $glibcxx_cv_S_IFREG = yes; then
 533     AC_DEFINE(HAVE_S_IFREG)
 534   fi
 535 ])
 536
 537
 538 dnl
 539 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 540 dnl
 541 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 542   AC_CACHE_VAL(glibcxx_cv_POLL, [
 543     AC_TRY_LINK(
 544       [#include <poll.h>],
 545       [struct pollfd pfd[1];
 546        pfd[0].events = POLLIN;
 547        poll(pfd, 1, 0);],
 548       [glibcxx_cv_POLL=yes],
 549       [glibcxx_cv_POLL=no])
 550   ])
 551   if test $glibcxx_cv_POLL = yes; then
 552     AC_DEFINE(HAVE_POLL)
 553   fi
 554 ])
 555
 556
 557 dnl
 558 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 559 dnl
 560 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 561   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 562     AC_TRY_LINK(
 563       [#include <sys/uio.h>],
 564       [struct iovec iov[2];
 565        writev(0, iov, 0);],
 566       [glibcxx_cv_WRITEV=yes],
 567       [glibcxx_cv_WRITEV=no])
 568   ])
 569   if test $glibcxx_cv_WRITEV = yes; then
 570     AC_DEFINE(HAVE_WRITEV)
 571   fi
 572 ])
 573
 574
 575 dnl
 576 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 577 dnl
 578 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 579   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 580     AC_TRY_COMPILE(
 581       [#include <stdint.h>],
 582       [int64_t var;],
 583       [glibcxx_cv_INT64_T=yes],
 584       [glibcxx_cv_INT64_T=no])
 585   ])
 586   if test $glibcxx_cv_INT64_T = yes; then
 587     AC_DEFINE(HAVE_INT64_T)
 588   fi
 589 ])
 590
 591
 592 dnl
 593 dnl Check whether LFS support is available.
 594 dnl
 595 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 596   AC_LANG_SAVE
 597   AC_LANG_CPLUSPLUS
 598   ac_save_CXXFLAGS="$CXXFLAGS"
 599   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 600   AC_CACHE_VAL(glibcxx_cv_LFS, [
 601     AC_TRY_LINK(
 602       [#include <unistd.h>
 603        #include <stdio.h>
 604       ],
 605       [FILE* fp;
 606        fopen64("t", "w");
 607        fseeko64(fp, 0, SEEK_CUR);
 608        ftello64(fp);
 609        lseek64(1, 0, SEEK_CUR);],
 610       [glibcxx_cv_LFS=yes],
 611       [glibcxx_cv_LFS=no])
 612   ])
 613   if test $glibcxx_cv_LFS = yes; then
 614     AC_DEFINE(_GLIBCXX_USE_LFS)
 615   fi
 616   CXXFLAGS="$ac_save_CXXFLAGS"
 617   AC_LANG_RESTORE
 618 ])
 619
 620
 621 dnl
 622 dnl Does any necessary configuration of the testsuite directory.  Generates
 623 dnl the testsuite_hooks.h header.
 624 dnl
 625 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 626 dnl
 627 dnl Sets:
 628 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 629 dnl Substs:
 630 dnl  baseline_dir
 631 dnl
 632 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 633   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 634     # Do checks for memory limit functions.
 635     GLIBCXX_CHECK_SETRLIMIT
 636
 637     # Look for setenv, so that extended locale tests can be performed.
 638     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 639
 640     if test $enable_symvers = no; then
 641       enable_abi_check=no
 642     else
 643       case "$host" in
 644         *-*-cygwin*)
 645           enable_abi_check=no ;;
 646         *)
 647           enable_abi_check=yes ;;
 648       esac
 649     fi
 650   else
 651     # Only build this as native, since automake does not understand
 652     # CXX_FOR_BUILD.
 653     enable_abi_check=no
 654   fi
 655
 656   # Export file names for ABI checking.
 657   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 658   AC_SUBST(baseline_dir)
 659
 660   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 661   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 662 ])
 663
 664
 665 dnl
 666 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 667 dnl
 668 dnl Substs:
 669 dnl  GLIBCXX_INCLUDES
 670 dnl  TOPLEVEL_INCLUDES
 671 dnl
 672 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 673   # Used for every C++ compile we perform.
 674   GLIBCXX_INCLUDES="\
 675 -I$glibcxx_builddir/include/$host_alias \
 676 -I$glibcxx_builddir/include \
 677 -I$glibcxx_srcdir/libsupc++"
 678
 679   # For Canadian crosses, pick this up too.
 680   if test $CANADIAN = yes; then
 681     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 682   fi
 683
 684   # Stuff in the actual top level.  Currently only used by libsupc++ to
 685   # get unwind* headers from the gcc dir.
 686   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 687   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 688
 689   # Now, export this to all the little Makefiles....
 690   AC_SUBST(GLIBCXX_INCLUDES)
 691   AC_SUBST(TOPLEVEL_INCLUDES)
 692 ])
 693
 694
 695 dnl
 696 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 697 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 698 dnl
 699 dnl Substs:
 700 dnl  OPTIMIZE_CXXFLAGS
 701 dnl  WARN_FLAGS
 702 dnl
 703 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 704   # Optimization flags that are probably a good idea for thrill-seekers. Just
 705   # uncomment the lines below and make, everything else is ready to go...
 706   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 707   OPTIMIZE_CXXFLAGS=
 708   AC_SUBST(OPTIMIZE_CXXFLAGS)
 709
 710   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 711   AC_SUBST(WARN_FLAGS)
 712 ])
 713
 714
 715 dnl
 716 dnl All installation directory information is determined here.
 717 dnl
 718 dnl Substs:
 719 dnl  gxx_install_dir
 720 dnl  glibcxx_prefixdir
 721 dnl  glibcxx_toolexecdir
 722 dnl  glibcxx_toolexeclibdir
 723 dnl
 724 dnl Assumes cross_compiling bits already done, and with_cross_host in
 725 dnl particular.
 726 dnl
 727 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 728   glibcxx_toolexecdir=no
 729   glibcxx_toolexeclibdir=no
 730   glibcxx_prefixdir=$prefix
 731
 732   AC_MSG_CHECKING([for gxx-include-dir])
 733   AC_ARG_WITH([gxx-include-dir],
 734     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 735                    [installation directory for include files]),
 736     [case "$withval" in
 737       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 738       no)  gxx_include_dir=no ;;
 739       *)   gxx_include_dir=$withval ;;
 740      esac],
 741     [gxx_include_dir=no])
 742   AC_MSG_RESULT($gxx_include_dir)
 743
 744   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 745   AC_ARG_ENABLE([version-specific-runtime-libs],
 746     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 747                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 748     [case "$enableval" in
 749       yes) version_specific_libs=yes ;;
 750       no)  version_specific_libs=no ;;
 751       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 752      esac],
 753     [version_specific_libs=no])
 754   AC_MSG_RESULT($version_specific_libs)
 755
 756   # Default case for install directory for include files.
 757   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 758     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 759   fi
 760
 761   # Version-specific runtime libs processing.
 762   if test $version_specific_libs = yes; then
 763     # Need the gcc compiler version to know where to install libraries
 764     # and header files if --enable-version-specific-runtime-libs option
 765     # is selected.  FIXME: these variables are misnamed, there are
 766     # no executables installed in _toolexecdir or _toolexeclibdir.
 767     if test x"$gxx_include_dir" = x"no"; then
 768       gxx_include_dir='${libdir}/gcc/${host_alias}/'$gcc_version/include/c++
 769     fi
 770     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 771     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 772   fi
 773
 774   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 775   # Install a library built with a cross compiler in tooldir, not libdir.
 776   if test x"$glibcxx_toolexecdir" = x"no"; then
 777     if test -n "$with_cross_host" &&
 778        test x"$with_cross_host" != x"no"; then
 779       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 780       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 781     else
 782       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 783       glibcxx_toolexeclibdir='${libdir}'
 784     fi
 785     multi_os_directory=`$CXX -print-multi-os-directory`
 786     case $multi_os_directory in
 787       .) ;; # Avoid trailing /.
 788       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 789     esac
 790   fi
 791
 792   AC_MSG_CHECKING([for install location])
 793   AC_MSG_RESULT($gxx_include_dir)
 794
 795   AC_SUBST(glibcxx_prefixdir)
 796   AC_SUBST(gxx_include_dir)
 797   AC_SUBST(glibcxx_toolexecdir)
 798   AC_SUBST(glibcxx_toolexeclibdir)
 799 ])
 800
 801
 802 dnl
 803 dnl GLIBCXX_ENABLE
 804 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 805 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 806 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 807 dnl
 808 dnl See docs/html/17_intro/configury.html#enable for documentation.
 809 dnl
 810 m4_define([GLIBCXX_ENABLE],[dnl
 811 m4_define([_g_switch],[--enable-$1])dnl
 812 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 813  AC_ARG_ENABLE($1,_g_help,
 814   m4_bmatch([$5],
 815    [^permit ],
 816      [[
 817       case "$enableval" in
 818        m4_bpatsubst([$5],[permit ])) ;;
 819        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 820           dnl Idea for future:  generate a URL pointing to
 821           dnl "onlinedocs/configopts.html#whatever"
 822       esac
 823      ]],
 824    [^$],
 825      [[
 826       case "$enableval" in
 827        yes|no) ;;
 828        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 829       esac
 830      ]],
 831    [[$5]]),
 832   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 833 m4_undefine([_g_switch])dnl
 834 m4_undefine([_g_help])dnl
 835 ])
 836
 837
 838 dnl
 839 dnl Check for ISO/IEC 9899:1999 "C99" support.
 840 dnl
 841 dnl --enable-c99 defines _GLIBCXX_USE_C99
 842 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 843 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 844 dnl       Where DEFAULT is either `yes' or `no'.
 845 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 846 dnl
 847 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 848   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 849
 850   AC_LANG_SAVE
 851   AC_LANG_CPLUSPLUS
 852
 853   # Check for the existence of <math.h> functions used if C99 is enabled.
 854   ac_c99_math=yes;
 855   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 856   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 857   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 858   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 860   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 861   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 862   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 863   AC_TRY_COMPILE([#include <math.h>],
 864                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 865   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 866   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 867   AC_TRY_COMPILE([#include <math.h>],
 868                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 869   AC_TRY_COMPILE([#include <math.h>],
 870                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 871   AC_MSG_RESULT($ac_c99_math)
 872
 873   if test x"$ac_c99_math" = x"yes"; then
 874     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 875   fi
 876
 877   # Check for the existence in <stdio.h> of vscanf, et. al.
 878   ac_c99_stdio=yes;
 879   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 880   AC_TRY_COMPILE([#include <stdio.h>],
 881                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 882   AC_TRY_COMPILE([#include <stdio.h>
 883                   #include <stdarg.h>
 884                   void foo(char* fmt, ...)
 885                   {va_list args; va_start(args, fmt);
 886                   vfscanf(stderr, "%i", args);}],
 887                   [],, [ac_c99_stdio=no])
 888   AC_TRY_COMPILE([#include <stdio.h>
 889                   #include <stdarg.h>
 890                   void foo(char* fmt, ...)
 891                   {va_list args; va_start(args, fmt);
 892                   vscanf("%i", args);}],
 893                   [],, [ac_c99_stdio=no])
 894   AC_TRY_COMPILE([#include <stdio.h>
 895                   #include <stdarg.h>
 896                   void foo(char* fmt, ...)
 897                   {va_list args; va_start(args, fmt);
 898                   vsnprintf(fmt, 0, "%i", args);}],
 899                   [],, [ac_c99_stdio=no])
 900   AC_TRY_COMPILE([#include <stdio.h>
 901                   #include <stdarg.h>
 902                   void foo(char* fmt, ...)
 903                   {va_list args; va_start(args, fmt);
 904                   vsscanf(fmt, "%i", args);}],
 905                   [],, [ac_c99_stdio=no])
 906   AC_MSG_RESULT($ac_c99_stdio)
 907
 908   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 909   ac_c99_stdlib=yes;
 910   AC_MSG_CHECKING([for lldiv_t declaration])
 911   AC_CACHE_VAL(ac_c99_lldiv_t, [
 912   AC_TRY_COMPILE([#include <stdlib.h>],
 913                    [ lldiv_t mydivt;],
 914                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 915   ])
 916   AC_MSG_RESULT($ac_c99_lldiv_t)
 917
 918   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 919   AC_TRY_COMPILE([#include <stdlib.h>],
 920                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 921   AC_TRY_COMPILE([#include <stdlib.h>],
 922                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 923   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 924   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 925   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 926   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 927   if test x"$ac_c99_lldiv_t" = x"no"; then
 928     ac_c99_stdlib=no;
 929   fi;
 930   AC_MSG_RESULT($ac_c99_stdlib)
 931
 932   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 933   # XXX the wchar.h checks should be rolled into the general C99 bits.
 934   ac_c99_wchar=yes;
 935   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 936   AC_TRY_COMPILE([#include <wchar.h>],
 937                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 938   AC_TRY_COMPILE([#include <wchar.h>],
 939                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 940   AC_TRY_COMPILE([#include <wchar.h>],
 941                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 942   AC_MSG_RESULT($ac_c99_wchar)
 943
 944   AC_MSG_CHECKING([for enabled ISO C99 support])
 945   if test x"$ac_c99_math" = x"no" ||
 946      test x"$ac_c99_stdio" = x"no" ||
 947      test x"$ac_c99_stdlib" = x"no" ||
 948      test x"$ac_c99_wchar" = x"no"; then
 949     enable_c99=no;
 950   fi;
 951   AC_MSG_RESULT($enable_c99)
 952
 953   if test x"$ac_99_math" = x"yes"; then
 954     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 955   fi
 956
 957   # Option parsed, now set things appropriately
 958   if test x"$enable_c99" = x"yes"; then
 959     AC_DEFINE(_GLIBCXX_USE_C99)
 960   fi
 961
 962   AC_LANG_RESTORE
 963 ])
 964
 965
 966 dnl
 967 dnl Check for what type of C headers to use.
 968 dnl
 969 dnl --enable-cheaders= [does stuff].
 970 dnl --disable-cheaders [does not do anything, really].
 971 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 972 dnl       Where DEFAULT is either `c' or `c_std'.
 973 dnl
 974 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
 975   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 976     [construct "C" headers for g++], [permit c|c_std])
 977   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 978
 979   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 980
 981   AC_SUBST(C_INCLUDE_DIR)
 982   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 983   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 984   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 985 ])
 986
 987
 988 dnl
 989 dnl Check for which locale library to use.  The choice is mapped to
 990 dnl a subdirectory of config/locale.
 991 dnl
 992 dnl Default is generic.
 993 dnl
 994 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
 995   AC_MSG_CHECKING([for C locale to use])
 996   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 997     [use MODEL for target locale package],
 998     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 999
1000   # If they didn't use this option switch, or if they specified --enable
1001   # with no specific model, we'll have to look for one.  If they
1002   # specified --disable (???), do likewise.
1003   if test $enable_clocale = no || test $enable_clocale = yes; then
1004      enable_clocale=auto
1005   fi
1006
1007   # Either a known package, or "auto"
1008   enable_clocale_flag=$enable_clocale
1009
1010   # Probe for locale support if no specific model is specified.
1011   # Default to "generic".
1012   if test $enable_clocale_flag = auto; then
1013     case x${target_os} in
1014       xlinux* | xgnu* | xkfreebsd*-gnu | xknetbsd*-gnu)
1015         AC_EGREP_CPP([_GLIBCXX_ok], [
1016         #include <features.h>
1017         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1018           _GLIBCXX_ok
1019         #endif
1020         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1021
1022         # Test for bugs early in glibc-2.2.x series
1023           if test x$enable_clocale_flag = xgnu; then
1024           AC_TRY_RUN([
1025           #define _GNU_SOURCE 1
1026           #include <locale.h>
1027           #include <string.h>
1028           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1029           extern __typeof(newlocale) __newlocale;
1030           extern __typeof(duplocale) __duplocale;
1031           extern __typeof(strcoll_l) __strcoll_l;
1032           #endif
1033           int main()
1034           {
1035               const char __one[] = "Äuglein Augmen";
1036               const char __two[] = "Äuglein";
1037               int i;
1038               int j;
1039               __locale_t        loc;
1040                __locale_t        loc_dup;
1041               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1042               loc_dup = __duplocale(loc);
1043               i = __strcoll_l(__one, __two, loc);
1044               j = __strcoll_l(__one, __two, loc_dup);
1045               return 0;
1046           }
1047           ],
1048           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1049           [enable_clocale_flag=generic])
1050           fi
1051
1052         # ... at some point put __strxfrm_l tests in as well.
1053         ;;
1054       *)
1055         enable_clocale_flag=generic
1056         ;;
1057     esac
1058   fi
1059
1060   # Deal with gettext issues.  Default to not using it (=no) until we detect
1061   # support for it later.  Let the user turn it off via --e/d, but let that
1062   # default to on for easier handling.
1063   USE_NLS=no
1064   AC_ARG_ENABLE(nls,
1065     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1066     [],
1067     [enable_nls=yes])
1068
1069   # Set configure bits for specified locale package
1070   case ${enable_clocale_flag} in
1071     generic)
1072       AC_MSG_RESULT(generic)
1073
1074       CLOCALE_H=config/locale/generic/c_locale.h
1075       CLOCALE_CC=config/locale/generic/c_locale.cc
1076       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1077       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1078       CCOLLATE_CC=config/locale/generic/collate_members.cc
1079       CCTYPE_CC=config/locale/generic/ctype_members.cc
1080       CMESSAGES_H=config/locale/generic/messages_members.h
1081       CMESSAGES_CC=config/locale/generic/messages_members.cc
1082       CMONEY_CC=config/locale/generic/monetary_members.cc
1083       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1084       CTIME_H=config/locale/generic/time_members.h
1085       CTIME_CC=config/locale/generic/time_members.cc
1086       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1087       ;;
1088     gnu)
1089       AC_MSG_RESULT(gnu)
1090
1091       # Declare intention to use gettext, and add support for specific
1092       # languages.
1093       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1094       ALL_LINGUAS="de fr"
1095
1096       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1097       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1098       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1099         USE_NLS=yes
1100       fi
1101       # Export the build objects.
1102       for ling in $ALL_LINGUAS; do \
1103         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1104         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1105       done
1106       AC_SUBST(glibcxx_MOFILES)
1107       AC_SUBST(glibcxx_POFILES)
1108
1109       CLOCALE_H=config/locale/gnu/c_locale.h
1110       CLOCALE_CC=config/locale/gnu/c_locale.cc
1111       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1112       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1113       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1114       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1115       CMESSAGES_H=config/locale/gnu/messages_members.h
1116       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1117       CMONEY_CC=config/locale/gnu/monetary_members.cc
1118       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1119       CTIME_H=config/locale/gnu/time_members.h
1120       CTIME_CC=config/locale/gnu/time_members.cc
1121       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1122       ;;
1123     ieee_1003.1-2001)
1124       AC_MSG_RESULT(IEEE 1003.1)
1125
1126       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1127       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1128       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1129       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1130       CCOLLATE_CC=config/locale/generic/collate_members.cc
1131       CCTYPE_CC=config/locale/generic/ctype_members.cc
1132       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1133       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1134       CMONEY_CC=config/locale/generic/monetary_members.cc
1135       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1136       CTIME_H=config/locale/generic/time_members.h
1137       CTIME_CC=config/locale/generic/time_members.cc
1138       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1139       ;;
1140   esac
1141
1142   # This is where the testsuite looks for locale catalogs, using the
1143   # -DLOCALEDIR define during testsuite compilation.
1144   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1145   AC_SUBST(glibcxx_localedir)
1146
1147   # A standalone libintl (e.g., GNU libintl) may be in use.
1148   if test $USE_NLS = yes; then
1149     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1150     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1151   fi
1152   if test $USE_NLS = yes; then
1153     AC_DEFINE(_GLIBCXX_USE_NLS)
1154   fi
1155
1156   AC_SUBST(USE_NLS)
1157   AC_SUBST(CLOCALE_H)
1158   AC_SUBST(CCODECVT_H)
1159   AC_SUBST(CMESSAGES_H)
1160   AC_SUBST(CCODECVT_CC)
1161   AC_SUBST(CCOLLATE_CC)
1162   AC_SUBST(CCTYPE_CC)
1163   AC_SUBST(CMESSAGES_CC)
1164   AC_SUBST(CMONEY_CC)
1165   AC_SUBST(CNUMERIC_CC)
1166   AC_SUBST(CTIME_H)
1167   AC_SUBST(CTIME_CC)
1168   AC_SUBST(CLOCALE_CC)
1169   AC_SUBST(CLOCALE_INTERNAL_H)
1170 ])
1171
1172
1173 dnl
1174 dnl Check for which std::allocator base class to use.  The choice is
1175 dnl mapped from a subdirectory of include/ext.
1176 dnl
1177 dnl Default is new.
1178 dnl
1179 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1180   AC_MSG_CHECKING([for std::allocator base class to use])
1181   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1182     [use KIND for target std::allocator base],
1183     [permit new|malloc|mt|bitmap|yes|no|auto])
1184   # If they didn't use this option switch, or if they specified --enable
1185   # with no specific model, we'll have to look for one.  If they
1186   # specified --disable (???), do likewise.
1187   if test $enable_libstdcxx_allocator = no || test $enable_libstdcxx_allocator = yes; then
1188      enable_libstdcxx_allocator=auto
1189   fi
1190
1191   # Either a known package, or "auto"
1192   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1193
1194   # Probe for host-specific support if no specific model is specified.
1195   # Default to "new".
1196   if test $enable_libstdcxx_allocator_flag = auto; then
1197     case ${target_os} in
1198       *)
1199         enable_libstdcxx_allocator_flag=new
1200         ;;
1201     esac
1202   fi
1203   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1204
1205
1206   # Set configure bits for specified locale package
1207   case ${enable_libstdcxx_allocator_flag} in
1208     bitmap)
1209       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1210       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1211       ;;
1212     malloc)
1213       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1214       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1215       ;;
1216     mt)
1217       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1218       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1219       ;;
1220     new)
1221       ALLOCATOR_H=config/allocator/new_allocator_base.h
1222       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1223       ;;
1224   esac
1225
1226   AC_SUBST(ALLOCATOR_H)
1227   AC_SUBST(ALLOCATOR_NAME)
1228 ])
1229
1230
1231 dnl
1232 dnl Check for whether the Boost-derived checks should be turned on.
1233 dnl
1234 dnl --enable-concept-checks turns them on.
1235 dnl --disable-concept-checks leaves them off.
1236 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1237 dnl       Where DEFAULT is either `yes' or `no'.
1238 dnl
1239 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1240   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1241   if test $enable_concept_checks = yes; then
1242     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1243   fi
1244 ])
1245
1246
1247 dnl
1248 dnl Check for which I/O library to use:  stdio, or something specific.
1249 dnl
1250 dnl Default is stdio.
1251 dnl
1252 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1253   AC_MSG_CHECKING([for underlying I/O to use])
1254   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1255     [use target-specific I/O package], [permit stdio])
1256
1257   # Now that libio has been removed, you can have any color you want as long
1258   # as it's black.  This is one big no-op until other packages are added, but
1259   # showing the framework never hurts.
1260   case ${enable_cstdio} in
1261     stdio)
1262       CSTDIO_H=config/io/c_io_stdio.h
1263       BASIC_FILE_H=config/io/basic_file_stdio.h
1264       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1265       AC_MSG_RESULT(stdio)
1266       ;;
1267   esac
1268
1269   AC_SUBST(CSTDIO_H)
1270   AC_SUBST(BASIC_FILE_H)
1271   AC_SUBST(BASIC_FILE_CC)
1272 ])
1273
1274
1275 dnl
1276 dnl Check for "unusual" flags to pass to the compiler while building.
1277 dnl
1278 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1279 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1280 dnl --disable-cxx-flags passes nothing.
1281 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1282 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1283 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1284 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1285 dnl       If "default flags" is an empty string, the effect is the same
1286 dnl       as --disable or --enable=no.
1287 dnl
1288 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1289   AC_MSG_CHECKING([for extra compiler flags for building])
1290   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1291     [pass compiler FLAGS when building library],
1292     [case "x$enable_cxx_flags" in
1293       xno | x)   enable_cxx_flags= ;;
1294       x-*)       ;;
1295       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1296      esac])
1297
1298   # Run through flags (either default or command-line) and set anything
1299   # extra (e.g., #defines) that must accompany particular g++ options.
1300   if test -n "$enable_cxx_flags"; then
1301     for f in $enable_cxx_flags; do
1302       case "$f" in
1303         -fhonor-std)  ;;
1304         -*)  ;;
1305         *)   # and we're trying to pass /what/ exactly?
1306              AC_MSG_ERROR([compiler flags start with a -]) ;;
1307       esac
1308     done
1309   fi
1310
1311   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1312   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1313   AC_SUBST(EXTRA_CXX_FLAGS)
1314 ])
1315
1316
1317 dnl
1318 dnl Check for wide character support.  Has the same effect as the option
1319 dnl in gcc's configure, but in a form that autoconf can mess with.
1320 dnl
1321 dnl --enable-c-mbchar requests all the wchar_t stuff.
1322 dnl --disable-c-mbchar doesn't.
1323 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1324 dnl       Where DEFAULT is either `yes' or `no'.
1325 dnl
1326 AC_DEFUN([GLIBCXX_ENABLE_C_MBCHAR], [
1327   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1328   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1329 ])
1330
1331
1332 dnl
1333 dnl Check to see if debugging libraries are to be built.
1334 dnl
1335 dnl --enable-libstdcxx-debug
1336 dnl builds a separate set of debugging libraries in addition to the
1337 dnl normal (shared, static) libstdc++ binaries.
1338 dnl
1339 dnl --disable-libstdcxx-debug
1340 dnl builds only one (non-debug) version of libstdc++.
1341 dnl
1342 dnl --enable-libstdcxx-debug-flags=FLAGS
1343 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1344 dnl
1345 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1346 dnl       Where DEFAULT is either `yes' or `no'.
1347 dnl
1348 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1349   AC_MSG_CHECKING([for additional debug build])
1350   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1351   AC_MSG_RESULT($enable_libstdcxx_debug)
1352   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1353 ])
1354
1355
1356 dnl
1357 dnl Check for explicit debug flags.
1358 dnl
1359 dnl --enable-libstdcxx-debug-flags='-O1'
1360 dnl is a general method for passing flags to be used when
1361 dnl building debug libraries with --enable-debug.
1362 dnl
1363 dnl --disable-libstdcxx-debug-flags does nothing.
1364 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1365 dnl       If "default flags" is an empty string, the effect is the same
1366 dnl       as --disable or --enable=no.
1367 dnl
1368 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1369   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1370     [pass compiler FLAGS when building debug library],
1371     [case "x$enable_libstdcxx_debug_flags" in
1372       xno | x)    enable_libstdcxx_debug_flags= ;;
1373       x-*)        ;;
1374       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1375      esac])
1376
1377   # Option parsed, now set things appropriately
1378   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1379   AC_SUBST(DEBUG_FLAGS)
1380
1381   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1382 ])
1383
1384
1385 dnl
1386 dnl Check if the user only wants a freestanding library implementation.
1387 dnl
1388 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1389 dnl installing only the headers required by [17.4.1.3] and the language
1390 dnl support library.  More than that will be built (to keep the Makefiles
1391 dnl conveniently clean), but not installed.
1392 dnl
1393 dnl Sets:
1394 dnl  is_hosted  (yes/no)
1395 dnl
1396 dnl Defines:
1397 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1398 dnl
1399 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1400   AC_ARG_ENABLE([hosted-libstdcxx],
1401     AC_HELP_STRING([--disable-hosted-libstdcxx],
1402                    [only build freestanding C++ runtime support]),,
1403     [enable_hosted_libstdcxx=yes])
1404   if test "$enable_hosted_libstdcxx" = no; then
1405     AC_MSG_NOTICE([Only freestanding libraries will be built])
1406     is_hosted=no
1407     hosted_define=0
1408     enable_abi_check=no
1409     enable_libstdcxx_pch=no
1410   else
1411     is_hosted=yes
1412     hosted_define=1
1413   fi
1414   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1415   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1416     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1417 ])
1418
1419
1420 dnl
1421 dnl Check for template specializations for the 'long long' type extension.
1422 dnl The result determines only whether 'long long' I/O is enabled; things
1423 dnl like numeric_limits<> specializations are always available.
1424 dnl
1425 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1426 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1427 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1428 dnl       Where DEFAULT is either `yes' or `no'.
1429 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1430 dnl
1431 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1432   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1433
1434   AC_LANG_SAVE
1435   AC_LANG_CPLUSPLUS
1436
1437   AC_MSG_CHECKING([for enabled long long I/O support])
1438   # iostreams require strtoll, strtoull to compile
1439   AC_TRY_COMPILE([#include <stdlib.h>],
1440                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1441   AC_TRY_COMPILE([#include <stdlib.h>],
1442                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1443
1444   # Option parsed, now set things appropriately
1445   if test $enable_long_long = yes; then
1446     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1447   fi
1448   AC_MSG_RESULT($enable_long_long)
1449
1450   AC_LANG_RESTORE
1451 ])
1452
1453
1454 dnl
1455 dnl Check to see if building and using a C++ precompiled header can be done.
1456 dnl
1457 dnl --enable-libstdcxx-pch=yes
1458 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1459 dnl may work, after some light-hearted attempts to puzzle out compiler
1460 dnl support, flip bits on in include/Makefile.am
1461 dnl
1462 dnl --disable-libstdcxx-pch
1463 dnl turns off attempts to use or build stdc++.h.gch.
1464 dnl
1465 dnl Substs:
1466 dnl  glibcxx_PCHFLAGS
1467 dnl
1468 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1469   AC_MSG_CHECKING([for enabled PCH])
1470   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1471   AC_MSG_RESULT([$enable_libstdcxx_pch])
1472
1473   if test $enable_libstdcxx_pch = yes; then
1474     AC_CACHE_CHECK([for compiler with PCH support],
1475       [glibcxx_cv_prog_CXX_pch],
1476       [ac_save_CXXFLAGS="$CXXFLAGS"
1477        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1478        AC_LANG_SAVE
1479        AC_LANG_CPLUSPLUS
1480        echo '#include <math.h>' > conftest.h
1481        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1482                           -o conftest.h.gch 1>&5 2>&1 &&
1483                 echo '#error "pch failed"' > conftest.h &&
1484           echo '#include "conftest.h"' > conftest.cc &&
1485                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1486        then
1487          glibcxx_cv_prog_CXX_pch=yes
1488        else
1489          glibcxx_cv_prog_CXX_pch=no
1490        fi
1491        rm -f conftest*
1492        CXXFLAGS=$ac_save_CXXFLAGS
1493        AC_LANG_RESTORE
1494       ])
1495     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1496   fi
1497
1498   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1499   if test $enable_libstdcxx_pch = yes; then
1500     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1501   else
1502     glibcxx_PCHFLAGS=""
1503   fi
1504   AC_SUBST(glibcxx_PCHFLAGS)
1505 ])
1506
1507
1508 dnl
1509 dnl Check for exception handling support.  If an explicit enable/disable
1510 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1511 dnl target may or may not support call frame exceptions.
1512 dnl
1513 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1514 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1515 dnl Neither one forces an attempt at detection.
1516 dnl
1517 dnl Defines:
1518 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1519 dnl
1520 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1521   AC_MSG_CHECKING([for exception model to use])
1522   AC_LANG_SAVE
1523   AC_LANG_CPLUSPLUS
1524   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1525     [force use of builtin_setjmp for exceptions],
1526     [permit yes|no|auto])
1527
1528   if test $enable_sjlj_exceptions = auto; then
1529     # Botheration.  Now we've got to detect the exception model.  Link tests
1530     # against libgcc.a are problematic since we've not been given proper -L
1531     # bits for single-tree newlib and libgloss.
1532     #
1533     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1534     cat > conftest.$ac_ext << EOF
1535 [#]line __oline__ "configure"
1536 struct S { ~S(); };
1537 void bar();
1538 void foo()
1539 {
1540   S s;
1541   bar();
1542 }
1543 EOF
1544     old_CXXFLAGS="$CXXFLAGS"
1545     CXXFLAGS=-S
1546     if AC_TRY_EVAL(ac_compile); then
1547       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1548         enable_sjlj_exceptions=yes
1549       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1550         enable_sjlj_exceptions=no
1551       fi
1552     fi
1553     CXXFLAGS="$old_CXXFLAGS"
1554     rm -f conftest*
1555   fi
1556
1557   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1558   # to two different models.
1559   case $enable_sjlj_exceptions in
1560     yes)
1561       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1562         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1563       ac_exception_model_name=sjlj
1564       ;;
1565     no)
1566       ac_exception_model_name="call frame"
1567       ;;
1568     *)
1569       AC_MSG_ERROR([unable to detect exception model])
1570       ;;
1571   esac
1572  AC_LANG_RESTORE
1573  AC_MSG_RESULT($ac_exception_model_name)
1574 ])
1575
1576
1577 dnl
1578 dnl Add version tags to symbols in shared library (or not), additionally
1579 dnl marking other symbols as private/local (or not).
1580 dnl
1581 dnl --enable-symvers=style adds a version script to the linker call when
1582 dnl       creating the shared library.  The choice of version script is
1583 dnl       controlled by 'style'.
1584 dnl --disable-symvers does not.
1585 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1586 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1587 dnl       choose a default style based on linker characteristics.  Passing
1588 dnl       'no' disables versioning.
1589 dnl
1590 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1591
1592 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1593   [enables symbol versioning of the shared library],
1594   [permit yes|no|gnu])
1595
1596 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1597 # don't know enough about $LD to do tricks...
1598 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1599 # FIXME  The following test is too strict, in theory.
1600 if test $enable_shared = no ||
1601         test "x$LD" = x ||
1602         test x$glibcxx_gnu_ld_version = x; then
1603   enable_symvers=no
1604 fi
1605
1606 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1607 if test $enable_symvers != no; then
1608   AC_MSG_CHECKING([for shared libgcc])
1609   ac_save_CFLAGS="$CFLAGS"
1610   CFLAGS=' -lgcc_s'
1611   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1612   CFLAGS="$ac_save_CFLAGS"
1613   AC_MSG_RESULT($glibcxx_shared_libgcc)
1614 fi
1615
1616 # For GNU ld, we need at least this version.  The format is described in
1617 # GLIBCXX_CHECK_LINKER_FEATURES above.
1618 glibcxx_min_gnu_ld_version=21400
1619 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1620
1621 # Check to see if unspecified "yes" value can win, given results above.
1622 # Change "yes" into either "no" or a style name.
1623 if test $enable_symvers = yes; then
1624   if test $with_gnu_ld = yes &&
1625      test $glibcxx_shared_libgcc = yes;
1626   then
1627     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1628       enable_symvers=gnu
1629     else
1630       # The right tools, the right setup, but too old.  Fallbacks?
1631       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1632       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1633       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1634       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1635       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1636         # Globbing fix is present, proper block support is not.
1637         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1638         dnl enable_symvers=???
1639         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1640         enable_symvers=no
1641       else
1642         # 2.11 or older.
1643         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1644         enable_symvers=no
1645       fi
1646     fi
1647   else
1648     # just fail for now
1649     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1650     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1651     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1652     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1653     enable_symvers=no
1654   fi
1655 fi
1656
1657 # Everything parsed; figure out what file to use.
1658 case $enable_symvers in
1659   no)
1660     SYMVER_MAP=config/linker-map.dummy
1661     ;;
1662   gnu)
1663     SYMVER_MAP=config/linker-map.gnu
1664     AC_DEFINE(_GLIBCXX_SYMVER)
1665     ;;
1666 esac
1667
1668 AC_SUBST(SYMVER_MAP)
1669 AC_SUBST(port_specific_symbol_files)
1670 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1671 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1672 ])
1673
1674
1675 dnl
1676 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1677 dnl We must stage the required headers so that they will be installed
1678 dnl with the library (unlike libgcc, the STL implementation is provided
1679 dnl solely within headers).  Since we must not inject random user-space
1680 dnl macro names into user-provided C++ code, we first stage into <file>-in
1681 dnl and process to <file> with an output command.  The reason for a two-
1682 dnl stage process here is to correctly handle $srcdir!=$objdir without
1683 dnl having to write complex code (the sed commands to clean the macro
1684 dnl namespace are complex and fragile enough as it is).  We must also
1685 dnl add a relative path so that -I- is supported properly.
1686 dnl
1687 dnl Substs:
1688 dnl  glibcxx_thread_h
1689 dnl
1690 dnl Defines:
1691 dnl  HAVE_GTHR_DEFAULT
1692 dnl
1693 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1694   AC_MSG_CHECKING([for thread model used by GCC])
1695   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1696   AC_MSG_RESULT([$target_thread_file])
1697
1698   if test $target_thread_file != single; then
1699     AC_DEFINE(HAVE_GTHR_DEFAULT)
1700   fi
1701
1702   glibcxx_thread_h=gthr-$target_thread_file.h
1703   AC_SUBST(glibcxx_thread_h)
1704 ])
1705
1706
1707 # Check whether LC_MESSAGES is available in <locale.h>.
1708 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1709 #
1710 # This file file be copied and used freely without restrictions.  It can
1711 # be used in projects which are not available under the GNU Public License
1712 # but which still want to provide support for the GNU gettext functionality.
1713 # Please note that the actual code is *not* freely available.
1714
1715 # serial 1
1716 AC_DEFUN([AC_LC_MESSAGES], [
1717   AC_CHECK_HEADER(locale.h, [
1718     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1719       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1720        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1721     if test $ac_cv_val_LC_MESSAGES = yes; then
1722       AC_DEFINE(HAVE_LC_MESSAGES)
1723     fi
1724   ])
1725 ])
1726
1727
1728 sinclude([../libtool.m4])
1729 dnl The lines below arrange for aclocal not to bring an installed
1730 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1731 dnl add a definition of LIBTOOL to Makefile.in.
1732 ifelse(,,,[AC_SUBST(LIBTOOL)
1733 AC_DEFUN([AM_PROG_LIBTOOL])
1734 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1735 AC_DEFUN([AC_PROG_LD])
1736 ])
1737
1738 dnl vim:et:ts=2:sw=2