libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  SUBDIRS
  36 dnl Substs:
  37 dnl  glibcxx_builddir     (absolute path)
  38 dnl  glibcxx_srcdir       (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_srcdir=${glibcxx_srcdir}/..
  64   AC_SUBST(glibcxx_builddir)
  65   AC_SUBST(glibcxx_srcdir)
  66   AC_SUBST(toplevel_srcdir)
  67
  68   # We use these options to decide which functions to include.  They are
  69   # set from the top level.
  70   AC_ARG_WITH([target-subdir],
  71     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  72                    [configuring in a subdirectory]))
  73
  74   AC_ARG_WITH([cross-host],
  75     AC_HELP_STRING([--with-cross-host=HOST],
  76                    [configuring with a cross compiler]))
  77
  78   AC_ARG_WITH([newlib],
  79     AC_HELP_STRING([--with-newlib],
  80                    [assume newlib as a system C library]))
  81
  82   # We're almost certainly being configured before anything else which uses
  83   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  84   # we not cache the value of CXX that we "discover" here, because it's set
  85   # to something unique for us and libjava.  Other target libraries need to
  86   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  87   # process by sneakily renaming the cache variable.  This also lets us debug
  88   # the value of "our" CXX in postmortems.
  89   #
  90   # We must also force CXX to /not/ be a precious variable, otherwise the
  91   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  92   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  93   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  94   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  95   #
  96   # -fno-builtin must be present here so that a non-conflicting form of
  97   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  98
  99   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 100   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 101   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 102   save_CXXFLAGS="$CXXFLAGS"
 103   CXXFLAGS="$CXXFLAGS -fno-builtin"
 104   AC_PROG_CC
 105   AC_PROG_CXX
 106   CXXFLAGS="$save_CXXFLAGS"
 107   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108   AC_SUBST(CFLAGS)
 109   AC_SUBST(CXXFLAGS)
 110
 111   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 112   # available).  Uncomment the next line to force a particular method.
 113   AC_PROG_LN_S
 114   #LN_S='cp -p'
 115
 116   AC_CHECK_TOOL(AS, as)
 117   AC_CHECK_TOOL(AR, ar)
 118   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 119
 120   AM_MAINTAINER_MODE
 121
 122   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 123   # which are themselves conditionally expanded.
 124   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 125   ## other macros from doing the same.  This should be automated.)  -pme
 126   need_libmath=no
 127
 128   # Find platform-specific directories containing configuration info.
 129   # Also possibly modify flags used elsewhere, as needed by the platform.
 130   GLIBCXX_CHECK_HOST
 131 ])
 132
 133
 134 dnl
 135 dnl Tests for newer compiler features, or features that are present in newer
 136 dnl compiler versions but not older compiler versions still in use, should
 137 dnl be placed here.
 138 dnl
 139 dnl Defines:
 140 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 141 dnl   new inlining code or the new system_header pragma will die on -Werror.
 142 dnl   Leave it out by default and use maint-mode to use it.
 143 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 144 dnl   compiler supports it and the user has not requested debug mode.
 145 dnl
 146 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 147   # All these tests are for C++; save the language and the compiler flags.
 148   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 149   # found in GLIBCXX_CONFIGURE.
 150   AC_LANG_SAVE
 151   AC_LANG_CPLUSPLUS
 152   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 153   ac_save_CXXFLAGS="$CXXFLAGS"
 154
 155   # Check for maintainer-mode bits.
 156   if test x"$USE_MAINTAINER_MODE" = xno; then
 157     WERROR=''
 158   else
 159     WERROR='-Werror'
 160   fi
 161
 162   # Check for -ffunction-sections -fdata-sections
 163   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 164   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 165   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 166   if test "$ac_test_CXXFLAGS" = set; then
 167     CXXFLAGS="$ac_save_CXXFLAGS"
 168   else
 169     # this is the suspicious part
 170     CXXFLAGS=''
 171   fi
 172   if test x"$ac_fdsections" = x"yes"; then
 173     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 174   fi
 175   AC_MSG_RESULT($ac_fdsections)
 176
 177   AC_LANG_RESTORE
 178   AC_SUBST(WERROR)
 179   AC_SUBST(SECTION_FLAGS)
 180 ])
 181
 182
 183 dnl
 184 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 185 dnl the native linker is in use, all variables will be defined to something
 186 dnl safe (like an empty string).
 187 dnl
 188 dnl Defines:
 189 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 190 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 191 dnl  LD (as a side effect of testing)
 192 dnl Sets:
 193 dnl  with_gnu_ld
 194 dnl  glibcxx_gnu_ld_version (possibly)
 195 dnl
 196 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 197 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 198 dnl
 199 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 200   # If we're not using GNU ld, then there's no point in even trying these
 201   # tests.  Check for that first.  We should have already tested for gld
 202   # by now (in libtool), but require it now just to be safe...
 203   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 204   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 205   AC_REQUIRE([AC_PROG_LD])
 206   AC_REQUIRE([AC_PROG_AWK])
 207
 208   # The name set by libtool depends on the version of libtool.  Shame on us
 209   # for depending on an impl detail, but c'est la vie.  Older versions used
 210   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 211   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 212   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 213   # set (hence we're using an older libtool), then set it.
 214   if test x${with_gnu_ld+set} != xset; then
 215     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 216       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 217       with_gnu_ld=no
 218     else
 219       with_gnu_ld=$ac_cv_prog_gnu_ld
 220     fi
 221   fi
 222
 223   # Start by getting the version number.  I think the libtool test already
 224   # does some of this, but throws away the result.
 225   AC_MSG_CHECKING([for ld version])
 226   changequote(,)
 227   ldver=`$LD --version 2>/dev/null | head -1 | \
 228          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 229   changequote([,])
 230   glibcxx_gnu_ld_version=`echo $ldver | \
 231          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 232   AC_MSG_RESULT($glibcxx_gnu_ld_version)
 233
 234   # Set --gc-sections.
 235   glibcxx_gcsections_min_ld=21602
 236   if test x"$with_gnu_ld" = x"yes" &&
 237         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 238
 239     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 240     # NB: This flag only works reliably after 2.16.1. Configure tests
 241     # for this are difficult, so hard wire a value that should work.
 242
 243     # All these tests are for C++, but run with the "C" compiler driver.
 244     # Need to do this so that g++ won't try to link in libstdc++/libsupc++.
 245     ac_test_CFLAGS="${CFLAGS+set}"
 246     ac_save_CFLAGS="$CFLAGS"
 247     CFLAGS='-x c++ -Wl,--gc-sections'
 248
 249     # Check for -Wl,--gc-sections
 250     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 251     AC_TRY_LINK([ int one(void) { return 1; }
 252      int two(void) { return 2; }
 253         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 254     if test "$ac_gcsections" = "yes"; then
 255       rm -f conftest.c
 256       touch conftest.c
 257       if $CC -c conftest.c; then
 258         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 259            grep "Warning: gc-sections option ignored" > /dev/null; then
 260           ac_gcsections=no
 261         fi
 262       fi
 263       rm -f conftest.c conftest.o conftest
 264     fi
 265     if test "$ac_gcsections" = "yes"; then
 266       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 267     fi
 268     AC_MSG_RESULT($ac_gcsections)
 269
 270     if test "$ac_test_CFLAGS" = set; then
 271       CFLAGS="$ac_save_CFLAGS"
 272     else
 273       # this is the suspicious part
 274       CFLAGS=''
 275     fi
 276   fi
 277
 278   # Set -z,relro.
 279   # Note this is only for shared objects.
 280   ac_ld_relro=no
 281   if test x"$with_gnu_ld" = x"yes"; then
 282     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 283     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 284     if test -n "$cxx_z_relo"; then
 285       OPT_LDFLAGS="-Wl,-z,relro"
 286       ac_ld_relro=yes
 287     fi
 288     AC_MSG_RESULT($ac_ld_relro)
 289   fi
 290
 291   # Set linker optimization flags.
 292   if test x"$with_gnu_ld" = x"yes"; then
 293     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 294   fi
 295
 296   AC_SUBST(SECTION_LDFLAGS)
 297   AC_SUBST(OPT_LDFLAGS)
 298 ])
 299
 300
 301 dnl
 302 dnl Check to see if this target can enable the iconv specializations.
 303 dnl If --disable-c-mbchar was given, no wchar_t specialization is enabled.
 304 dnl (This must have been previously checked, along with the rest of C99
 305 dnl support.) By default, iconv support is disabled.
 306 dnl
 307 dnl Defines:
 308 dnl  _GLIBCXX_USE_ICONV if all the bits are found.
 309 dnl Substs:
 310 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 311 dnl
 312 AC_DEFUN([GLIBCXX_CHECK_ICONV_SUPPORT], [
 313
 314   enable_iconv=no
 315   # Only continue checking if the ISO C99 headers exist and support is on.
 316   if test x"$enable_wchar_t" = xyes; then
 317
 318     # Use iconv for wchar_t to char conversions. As such, check for
 319     # X/Open Portability Guide, version 2 features (XPG2).
 320     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 321     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 322
 323     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 324     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 325     ac_save_LIBS="$LIBS"
 326     LIBS="$LIBS $LIBICONV"
 327     AC_SUBST(LIBICONV)
 328
 329     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 330     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 331
 332     LIBS="$ac_save_LIBS"
 333
 334     if test x"$ac_has_iconv_h" = xyes &&
 335        test x"$ac_has_langinfo_h" = xyes &&
 336        test x"$ac_XPG2funcs" = xyes;
 337     then
 338       AC_DEFINE([_GLIBCXX_USE_ICONV],1,
 339                 [Define if iconv and related functions exist and are usable.])
 340       enable_iconv=yes
 341     fi
 342   fi
 343   AC_MSG_CHECKING([for enabled iconv specializations])
 344   AC_MSG_RESULT($enable_iconv)
 345 ])
 346
 347
 348 dnl
 349 dnl Check for headers for, and arguments to, the setrlimit() function.
 350 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 351 dnl
 352 dnl Defines:
 353 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 354 dnl  various HAVE_LIMIT_* for individual limit names
 355 dnl
 356 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 357   AC_MSG_CHECKING([for RLIMIT_$1])
 358   AC_TRY_COMPILE(
 359     [#include <unistd.h>
 360      #include <sys/time.h>
 361      #include <sys/resource.h>
 362     ],
 363     [ int f = RLIMIT_$1 ; ],
 364     [glibcxx_mresult=1], [glibcxx_mresult=0])
 365   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 366                      [Only used in build directory testsuite_hooks.h.])
 367   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 368   AC_MSG_RESULT($res)
 369 ])
 370
 371 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 372   setrlimit_have_headers=yes
 373   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 374                    [],
 375                    [setrlimit_have_headers=no])
 376   # If don't have the headers, then we can't run the tests now, and we
 377   # won't be seeing any of these during testsuite compilation.
 378   if test $setrlimit_have_headers = yes; then
 379     # Can't do these in a loop, else the resulting syntax is wrong.
 380     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 381     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 382     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 383     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 384     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 385
 386     # Check for rlimit, setrlimit.
 387     AC_CACHE_VAL(ac_setrlimit, [
 388       AC_TRY_COMPILE(
 389         [#include <unistd.h>
 390          #include <sys/time.h>
 391          #include <sys/resource.h>
 392         ],
 393         [struct rlimit r;
 394          setrlimit(0, &r);],
 395         [ac_setrlimit=yes], [ac_setrlimit=no])
 396     ])
 397   fi
 398
 399   AC_MSG_CHECKING([for testsuite resource limits support])
 400   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 401     ac_res_limits=yes
 402     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 403               [Define if using setrlimit to set resource limits during
 404               "make check"])
 405   else
 406     ac_res_limits=no
 407   fi
 408   AC_MSG_RESULT($ac_res_limits)
 409 ])
 410
 411
 412 dnl
 413 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 414 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 415 dnl
 416 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 417   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 418   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 419     AC_TRY_LINK(
 420       [#include <sys/stat.h>],
 421       [struct stat buffer;
 422        fstat(0, &buffer);
 423        S_ISREG(buffer.st_mode);],
 424       [glibcxx_cv_S_ISREG=yes],
 425       [glibcxx_cv_S_ISREG=no])
 426   ])
 427   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 428     AC_TRY_LINK(
 429       [#include <sys/stat.h>],
 430       [struct stat buffer;
 431        fstat(0, &buffer);
 432        S_IFREG & buffer.st_mode;],
 433       [glibcxx_cv_S_IFREG=yes],
 434       [glibcxx_cv_S_IFREG=no])
 435   ])
 436   res=no
 437   if test $glibcxx_cv_S_ISREG = yes; then
 438     AC_DEFINE(HAVE_S_ISREG, 1,
 439               [Define if S_IFREG is available in <sys/stat.h>.])
 440     res=S_ISREG
 441   elif test $glibcxx_cv_S_IFREG = yes; then
 442     AC_DEFINE(HAVE_S_IFREG, 1,
 443               [Define if S_IFREG is available in <sys/stat.h>.])
 444     res=S_IFREG
 445   fi
 446   AC_MSG_RESULT($res)
 447 ])
 448
 449
 450 dnl
 451 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 452 dnl
 453 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 454   AC_MSG_CHECKING([for poll])
 455   AC_CACHE_VAL(glibcxx_cv_POLL, [
 456     AC_TRY_LINK(
 457       [#include <poll.h>],
 458       [struct pollfd pfd[1];
 459        pfd[0].events = POLLIN;
 460        poll(pfd, 1, 0);],
 461       [glibcxx_cv_POLL=yes],
 462       [glibcxx_cv_POLL=no])
 463   ])
 464   if test $glibcxx_cv_POLL = yes; then
 465     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 466   fi
 467   AC_MSG_RESULT($glibcxx_cv_POLL)
 468 ])
 469
 470
 471 dnl
 472 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 473 dnl
 474 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 475   AC_MSG_CHECKING([for writev])
 476   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 477     AC_TRY_LINK(
 478       [#include <sys/uio.h>],
 479       [struct iovec iov[2];
 480        writev(0, iov, 0);],
 481       [glibcxx_cv_WRITEV=yes],
 482       [glibcxx_cv_WRITEV=no])
 483   ])
 484   if test $glibcxx_cv_WRITEV = yes; then
 485     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 486   fi
 487   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 488 ])
 489
 490
 491 dnl
 492 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 493 dnl
 494 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 495   AC_MSG_CHECKING([for int64_t])
 496   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 497     AC_TRY_COMPILE(
 498       [#include <stdint.h>],
 499       [int64_t var;],
 500       [glibcxx_cv_INT64_T=yes],
 501       [glibcxx_cv_INT64_T=no])
 502   ])
 503   if test $glibcxx_cv_INT64_T = yes; then
 504     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 505   fi
 506   AC_MSG_RESULT($glibcxx_cv_INT64_T)
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether LFS support is available.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 514   AC_LANG_SAVE
 515   AC_LANG_CPLUSPLUS
 516   ac_save_CXXFLAGS="$CXXFLAGS"
 517   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 518   AC_MSG_CHECKING([for LFS support])
 519   AC_CACHE_VAL(glibcxx_cv_LFS, [
 520     AC_TRY_LINK(
 521       [#include <unistd.h>
 522        #include <stdio.h>
 523        #include <sys/stat.h>
 524       ],
 525       [FILE* fp;
 526        fopen64("t", "w");
 527        fseeko64(fp, 0, SEEK_CUR);
 528        ftello64(fp);
 529        lseek64(1, 0, SEEK_CUR);
 530        struct stat64 buf;
 531        fstat64(1, &buf);],
 532       [glibcxx_cv_LFS=yes],
 533       [glibcxx_cv_LFS=no])
 534   ])
 535   if test $glibcxx_cv_LFS = yes; then
 536     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 537   fi
 538   AC_MSG_RESULT($glibcxx_cv_LFS)
 539   CXXFLAGS="$ac_save_CXXFLAGS"
 540   AC_LANG_RESTORE
 541 ])
 542
 543
 544 dnl
 545 dnl Check for whether a fully dynamic basic_string implementation should
 546 dnl be turned on, that does not put empty objects in per-process static
 547 dnl memory (mostly useful together with shared memory allocators, see PR
 548 dnl libstdc++/16612 for details).
 549 dnl
 550 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 551 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 552 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 553 dnl       Where DEFAULT is either `yes' or `no'.
 554 dnl
 555 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 556   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 557   if test $enable_fully_dynamic_string = yes; then
 558     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING, 1,
 559               [Define if a fully dynamic basic_string is wanted.])
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Does any necessary configuration of the testsuite directory.  Generates
 566 dnl the testsuite_hooks.h header.
 567 dnl
 568 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 569 dnl
 570 dnl Sets:
 571 dnl  enable_abi_check
 572 dnl  GLIBCXX_TEST_WCHAR_T
 573 dnl  GLIBCXX_TEST_THREAD
 574 dnl Substs:
 575 dnl  baseline_dir
 576 dnl
 577 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 578   if $GLIBCXX_IS_NATIVE ; then
 579     # Do checks for resource limit functions.
 580     GLIBCXX_CHECK_SETRLIMIT
 581
 582     # Look for setenv, so that extended locale tests can be performed.
 583     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 584   fi
 585
 586   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 587      test $enable_symvers != no; then
 588     case "$host" in
 589       *-*-cygwin*)
 590         enable_abi_check=no ;;
 591       *)
 592         enable_abi_check=yes ;;
 593     esac
 594   else
 595     # Only build this as native, since automake does not understand
 596     # CXX_FOR_BUILD.
 597     enable_abi_check=no
 598   fi
 599
 600   # Export file names for ABI checking.
 601   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}\$(MULTISUBDIR)"
 602   AC_SUBST(baseline_dir)
 603 ])
 604
 605
 606 dnl
 607 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 608 dnl
 609 dnl Substs:
 610 dnl  GLIBCXX_INCLUDES
 611 dnl  TOPLEVEL_INCLUDES
 612 dnl
 613 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 614   # Used for every C++ compile we perform.
 615   GLIBCXX_INCLUDES="\
 616 -I$glibcxx_builddir/include/$host_alias \
 617 -I$glibcxx_builddir/include \
 618 -I$glibcxx_srcdir/libsupc++"
 619
 620   # For Canadian crosses, pick this up too.
 621   if test $CANADIAN = yes; then
 622     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 623   fi
 624
 625   # Stuff in the actual top level.  Currently only used by libsupc++ to
 626   # get unwind* headers from the gcc dir.
 627   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 628   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 629
 630   # Now, export this to all the little Makefiles....
 631   AC_SUBST(GLIBCXX_INCLUDES)
 632   AC_SUBST(TOPLEVEL_INCLUDES)
 633 ])
 634
 635
 636 dnl
 637 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 638 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 639 dnl
 640 dnl Substs:
 641 dnl  OPTIMIZE_CXXFLAGS
 642 dnl  WARN_FLAGS
 643 dnl
 644 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 645   # Optimization flags that are probably a good idea for thrill-seekers. Just
 646   # uncomment the lines below and make, everything else is ready to go...
 647   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 648   OPTIMIZE_CXXFLAGS=
 649   AC_SUBST(OPTIMIZE_CXXFLAGS)
 650
 651   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 652   AC_SUBST(WARN_FLAGS)
 653 ])
 654
 655
 656 dnl
 657 dnl All installation directory information is determined here.
 658 dnl
 659 dnl Substs:
 660 dnl  gxx_install_dir
 661 dnl  glibcxx_prefixdir
 662 dnl  glibcxx_toolexecdir
 663 dnl  glibcxx_toolexeclibdir
 664 dnl
 665 dnl Assumes cross_compiling bits already done, and with_cross_host in
 666 dnl particular.
 667 dnl
 668 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 669   glibcxx_toolexecdir=no
 670   glibcxx_toolexeclibdir=no
 671   glibcxx_prefixdir=$prefix
 672
 673   AC_MSG_CHECKING([for gxx-include-dir])
 674   AC_ARG_WITH([gxx-include-dir],
 675     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 676                    [installation directory for include files]),
 677     [case "$withval" in
 678       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 679       no)  gxx_include_dir=no ;;
 680       *)   gxx_include_dir=$withval ;;
 681      esac],
 682     [gxx_include_dir=no])
 683   AC_MSG_RESULT($gxx_include_dir)
 684
 685   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 686   AC_ARG_ENABLE([version-specific-runtime-libs],
 687     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 688                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 689     [case "$enableval" in
 690       yes) version_specific_libs=yes ;;
 691       no)  version_specific_libs=no ;;
 692       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 693      esac],
 694     [version_specific_libs=no])
 695   AC_MSG_RESULT($version_specific_libs)
 696
 697   # Default case for install directory for include files.
 698   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 699     gxx_include_dir='${prefix}/include/c++/${gcc_version}'
 700   fi
 701
 702   # Version-specific runtime libs processing.
 703   if test $version_specific_libs = yes; then
 704     # Need the gcc compiler version to know where to install libraries
 705     # and header files if --enable-version-specific-runtime-libs option
 706     # is selected.  FIXME: these variables are misnamed, there are
 707     # no executables installed in _toolexecdir or _toolexeclibdir.
 708     if test x"$gxx_include_dir" = x"no"; then
 709       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 710     fi
 711     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 712     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 713   fi
 714
 715   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 716   # Install a library built with a cross compiler in tooldir, not libdir.
 717   if test x"$glibcxx_toolexecdir" = x"no"; then
 718     if test -n "$with_cross_host" &&
 719        test x"$with_cross_host" != x"no"; then
 720       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 721       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 722     else
 723       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 724       glibcxx_toolexeclibdir='${libdir}'
 725     fi
 726     multi_os_directory=`$CXX -print-multi-os-directory`
 727     case $multi_os_directory in
 728       .) ;; # Avoid trailing /.
 729       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 730     esac
 731   fi
 732
 733   AC_MSG_CHECKING([for install location])
 734   AC_MSG_RESULT($gxx_include_dir)
 735
 736   AC_SUBST(glibcxx_prefixdir)
 737   AC_SUBST(gxx_include_dir)
 738   AC_SUBST(glibcxx_toolexecdir)
 739   AC_SUBST(glibcxx_toolexeclibdir)
 740 ])
 741
 742
 743 dnl
 744 dnl GLIBCXX_ENABLE
 745 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 746 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 747 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 748 dnl
 749 dnl See docs/html/17_intro/configury.html#enable for documentation.
 750 dnl
 751 m4_define([GLIBCXX_ENABLE],[dnl
 752 m4_define([_g_switch],[--enable-$1])dnl
 753 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 754  AC_ARG_ENABLE($1,_g_help,
 755   m4_bmatch([$5],
 756    [^permit ],
 757      [[
 758       case "$enableval" in
 759        m4_bpatsubst([$5],[permit ])) ;;
 760        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 761           dnl Idea for future:  generate a URL pointing to
 762           dnl "onlinedocs/configopts.html#whatever"
 763       esac
 764      ]],
 765    [^$],
 766      [[
 767       case "$enableval" in
 768        yes|no) ;;
 769        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 770       esac
 771      ]],
 772    [[$5]]),
 773   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 774 m4_undefine([_g_switch])dnl
 775 m4_undefine([_g_help])dnl
 776 ])
 777
 778
 779 dnl
 780 dnl Check for ISO/IEC 9899:1999 "C99" support.
 781 dnl
 782 dnl --enable-c99 defines _GLIBCXX_USE_C99
 783 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 784 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 785 dnl       Where DEFAULT is either `yes' or `no'.
 786 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 787 dnl
 788 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 789   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 790
 791   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos
 792   # even if C99 support is turned off.
 793   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 794   AC_MSG_CHECKING([for mbstate_t])
 795   AC_TRY_COMPILE([#include <wchar.h>],
 796   [mbstate_t teststate;],
 797   have_mbstate_t=yes, have_mbstate_t=no)
 798   AC_MSG_RESULT($have_mbstate_t)
 799   if test x"$have_mbstate_t" = xyes; then
 800     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 801   fi
 802
 803   if test x"$enable_c99" = x"yes"; then
 804
 805   AC_LANG_SAVE
 806   AC_LANG_CPLUSPLUS
 807
 808   # Check for the existence of <math.h> functions used if C99 is enabled.
 809   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 810   AC_CACHE_VAL(ac_c99_math, [
 811   AC_TRY_COMPILE([#include <math.h>],
 812                  [fpclassify(0.0);
 813                   isfinite(0.0);
 814                   isinf(0.0);
 815                   isnan(0.0);
 816                   isnormal(0.0);
 817                   signbit(0.0);
 818                   isgreater(0.0,0.0);
 819                   isgreaterequal(0.0,0.0);
 820                   isless(0.0,0.0);
 821                   islessequal(0.0,0.0);
 822                   islessgreater(0.0,0.0);
 823                   islessgreater(0.0,0.0);
 824                   isunordered(0.0,0.0);
 825                  ],[ac_c99_math=yes], [ac_c99_math=no])
 826   ])
 827   AC_MSG_RESULT($ac_c99_math)
 828   if test x"$ac_c99_math" = x"yes"; then
 829     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 830               [Define if C99 functions or macros in <math.h> should be imported
 831               in <cmath> in namespace std.])
 832   fi
 833
 834   # Check for the existence of <complex.h> complex math functions.
 835   # This is necessary even though libstdc++ uses the builtin versions
 836   # of these functions, because if the builtin cannot be used, a reference
 837   # to the library function is emitted.
 838   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 839   ac_c99_complex=no;
 840   if test x"$ac_has_complex_h" = x"yes"; then
 841     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 842     AC_TRY_COMPILE([#include <complex.h>],
 843                    [typedef __complex__ float float_type; float_type tmpf;
 844                     cabsf(tmpf);
 845                     cargf(tmpf);
 846                     ccosf(tmpf);
 847                     ccoshf(tmpf);
 848                     cexpf(tmpf);
 849                     clogf(tmpf);
 850                     csinf(tmpf);
 851                     csinhf(tmpf);
 852                     csqrtf(tmpf);
 853                     ctanf(tmpf);
 854                     ctanhf(tmpf);
 855                     cpowf(tmpf, tmpf);
 856                     typedef __complex__ double double_type; double_type tmpd;
 857                     cabs(tmpd);
 858                     carg(tmpd);
 859                     ccos(tmpd);
 860                     ccosh(tmpd);
 861                     cexp(tmpd);
 862                     clog(tmpd);
 863                     csin(tmpd);
 864                     csinh(tmpd);
 865                     csqrt(tmpd);
 866                     ctan(tmpd);
 867                     ctanh(tmpd);
 868                     cpow(tmpd, tmpd);
 869                     typedef __complex__ long double ld_type; ld_type tmpld;
 870                     cabsl(tmpld);
 871                     cargl(tmpld);
 872                     ccosl(tmpld);
 873                     ccoshl(tmpld);
 874                     cexpl(tmpld);
 875                     clogl(tmpld);
 876                     csinl(tmpld);
 877                     csinhl(tmpld);
 878                     csqrtl(tmpld);
 879                     ctanl(tmpld);
 880                     ctanhl(tmpld);
 881                     cpowl(tmpld, tmpld);
 882                    ],[ac_c99_complex=yes], [ac_c99_complex=no])
 883   fi
 884   AC_MSG_RESULT($ac_c99_complex)
 885   if test x"$ac_c99_complex" = x"yes"; then
 886     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 887               [Define if C99 functions in <complex.h> should be used in
 888               <complex>. Using compiler builtins for these functions requires
 889               corresponding C99 library functions to be present.])
 890   fi
 891
 892   # Check for the existence in <stdio.h> of vscanf, et. al.
 893   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 894   AC_CACHE_VAL(ac_c99_stdio, [
 895   AC_TRY_COMPILE([#include <stdio.h>
 896                   #include <stdarg.h>
 897                   void foo(char* fmt, ...)
 898                   {
 899                     va_list args; va_start(args, fmt);
 900                     vfscanf(stderr, "%i", args);
 901                     vscanf("%i", args);
 902                     vsnprintf(fmt, 0, "%i", args);
 903                     vsscanf(fmt, "%i", args);
 904                   }],
 905                  [snprintf("12", 0, "%i");],
 906                  [ac_c99_stdio=yes], [ac_c99_stdio=no])
 907   ])
 908   AC_MSG_RESULT($ac_c99_stdio)
 909
 910   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 911   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 912   AC_CACHE_VAL(ac_c99_stdlib, [
 913   AC_TRY_COMPILE([#include <stdlib.h>],
 914                  [char* tmp;
 915                   strtof("gnu", &tmp);
 916                   strtold("gnu", &tmp);
 917                   strtoll("gnu", &tmp, 10);
 918                   strtoull("gnu", &tmp, 10);
 919                   llabs(10);
 920                   lldiv(10,1);
 921                   atoll("10");
 922                   _Exit(0);
 923                   lldiv_t mydivt;],[ac_c99_stdlib=yes], [ac_c99_stdlib=no])
 924   ])
 925   AC_MSG_RESULT($ac_c99_stdlib)
 926
 927   # Check for the existence in <wchar.h> of wcstoull, WEOF, etc.
 928   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 929   ac_c99_wchar=no;
 930   if test x"$ac_has_wchar_h" = xyes &&
 931      test x"$ac_has_wctype_h" = xyes; then
 932     AC_TRY_COMPILE([#include <wchar.h>
 933                     #include <stddef.h>
 934                     wint_t i;
 935                     long l = WEOF;
 936                     long j = WCHAR_MIN;
 937                     long k = WCHAR_MAX;
 938                     namespace test
 939                     {
 940                       using ::btowc;
 941                       using ::fgetwc;
 942                       using ::fgetws;
 943                       using ::fputwc;
 944                       using ::fputws;
 945                       using ::fwide;
 946                       using ::fwprintf;
 947                       using ::fwscanf;
 948                       using ::getwc;
 949                       using ::getwchar;
 950                       using ::mbrlen;
 951                       using ::mbrtowc;
 952                       using ::mbsinit;
 953                       using ::mbsrtowcs;
 954                       using ::putwc;
 955                       using ::putwchar;
 956                       using ::swprintf;
 957                       using ::swscanf;
 958                       using ::ungetwc;
 959                       using ::vfwprintf;
 960                       using ::vswprintf;
 961                       using ::vwprintf;
 962                       using ::wcrtomb;
 963                       using ::wcscat;
 964                       using ::wcschr;
 965                       using ::wcscmp;
 966                       using ::wcscoll;
 967                       using ::wcscpy;
 968                       using ::wcscspn;
 969                       using ::wcsftime;
 970                       using ::wcslen;
 971                       using ::wcsncat;
 972                       using ::wcsncmp;
 973                       using ::wcsncpy;
 974                       using ::wcspbrk;
 975                       using ::wcsrchr;
 976                       using ::wcsrtombs;
 977                       using ::wcsspn;
 978                       using ::wcsstr;
 979                       using ::wcstod;
 980                       using ::wcstok;
 981                       using ::wcstol;
 982                       using ::wcstold;
 983                       using ::wcstoll;
 984                       using ::wcstoul;
 985                       using ::wcstoull;
 986                       using ::wcsxfrm;
 987                       using ::wctob;
 988                       using ::wmemchr;
 989                       using ::wmemcmp;
 990                       using ::wmemcpy;
 991                       using ::wmemmove;
 992                       using ::wmemset;
 993                       using ::wprintf;
 994                       using ::wscanf;
 995                     }
 996                    ],[],[ac_c99_wchar=yes], [ac_c99_wchar=no])
 997
 998     # Checks for wide character functions that may not be present.
 999     # Injection of these is wrapped with guard macros.
1000     # NB: only put functions here, instead of immediately above, if
1001     # absolutely necessary.
1002     AC_TRY_COMPILE([#include <wchar.h>
1003                     namespace test { using ::vfwscanf; } ], [],
1004                    [AC_DEFINE(HAVE_VFWSCANF,1,
1005                         [Defined if vfwscanf exists.])],[])
1006
1007     AC_TRY_COMPILE([#include <wchar.h>
1008                     namespace test { using ::vswscanf; } ], [],
1009                    [AC_DEFINE(HAVE_VSWSCANF,1,
1010                         [Defined if vswscanf exists.])],[])
1011
1012     AC_TRY_COMPILE([#include <wchar.h>
1013                     namespace test { using ::vwscanf; } ], [],
1014                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1015
1016     AC_TRY_COMPILE([#include <wchar.h>
1017                     namespace test { using ::wcstof; } ], [],
1018                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1019
1020     AC_TRY_COMPILE([#include <wctype.h>],
1021                    [ wint_t t; int i = iswblank(t);],
1022                    [AC_DEFINE(HAVE_ISWBLANK,1,
1023                         [Defined if iswblank exists.])],[])
1024
1025     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1026     AC_MSG_RESULT($ac_c99_wchar)
1027   fi
1028
1029   # Option parsed, now set things appropriately.
1030   if test x"$ac_c99_math" = x"no" ||
1031      test x"$ac_c99_complex" = x"no" ||
1032      test x"$ac_c99_stdio" = x"no" ||
1033      test x"$ac_c99_stdlib" = x"no" ||
1034      test x"$ac_c99_wchar" = x"no"; then
1035     enable_c99=no;
1036   else
1037     AC_DEFINE(_GLIBCXX_USE_C99, 1,
1038     [Define if C99 functions or macros from <wchar.h>, <math.h>,
1039     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1040   fi
1041
1042   AC_LANG_RESTORE
1043   fi
1044
1045   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1046   AC_MSG_RESULT($enable_c99)
1047 ])
1048
1049
1050 dnl
1051 dnl Check for what type of C headers to use.
1052 dnl
1053 dnl --enable-cheaders= [does stuff].
1054 dnl --disable-cheaders [does not do anything, really].
1055 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1056 dnl       Where DEFAULT is either `c' or `c_std'.
1057 dnl
1058 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1059   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1060     [construct "C" headers for g++], [permit c|c_std])
1061   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1062
1063   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1064
1065   AC_SUBST(C_INCLUDE_DIR)
1066   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1067   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1068   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1069 ])
1070
1071
1072 dnl
1073 dnl Check for which locale library to use.  The choice is mapped to
1074 dnl a subdirectory of config/locale.
1075 dnl
1076 dnl Default is generic.
1077 dnl
1078 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1079   AC_MSG_CHECKING([for C locale to use])
1080   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1081     [use MODEL for target locale package],
1082     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1083
1084   # If they didn't use this option switch, or if they specified --enable
1085   # with no specific model, we'll have to look for one.  If they
1086   # specified --disable (???), do likewise.
1087   if test $enable_clocale = no || test $enable_clocale = yes; then
1088      enable_clocale=auto
1089   fi
1090
1091   # Either a known package, or "auto"
1092   enable_clocale_flag=$enable_clocale
1093
1094   # Probe for locale support if no specific model is specified.
1095   # Default to "generic".
1096   if test $enable_clocale_flag = auto; then
1097     case ${target_os} in
1098       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1099         AC_EGREP_CPP([_GLIBCXX_ok], [
1100         #include <features.h>
1101         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1102           _GLIBCXX_ok
1103         #endif
1104         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1105
1106         # Test for bugs early in glibc-2.2.x series
1107           if test $enable_clocale_flag = gnu; then
1108           AC_TRY_RUN([
1109           #define _GNU_SOURCE 1
1110           #include <locale.h>
1111           #include <string.h>
1112           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1113           extern __typeof(newlocale) __newlocale;
1114           extern __typeof(duplocale) __duplocale;
1115           extern __typeof(strcoll_l) __strcoll_l;
1116           #endif
1117           int main()
1118           {
1119               const char __one[] = "Äuglein Augmen";
1120               const char __two[] = "Äuglein";
1121               int i;
1122               int j;
1123               __locale_t        loc;
1124                __locale_t        loc_dup;
1125               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1126               loc_dup = __duplocale(loc);
1127               i = __strcoll_l(__one, __two, loc);
1128               j = __strcoll_l(__one, __two, loc_dup);
1129               return 0;
1130           }
1131           ],
1132           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1133           [enable_clocale_flag=generic])
1134           fi
1135
1136         # ... at some point put __strxfrm_l tests in as well.
1137         ;;
1138       darwin* | freebsd*)
1139         enable_clocale_flag=darwin
1140         ;;
1141       *)
1142         enable_clocale_flag=generic
1143         ;;
1144     esac
1145   fi
1146
1147   # Deal with gettext issues.  Default to not using it (=no) until we detect
1148   # support for it later.  Let the user turn it off via --e/d, but let that
1149   # default to on for easier handling.
1150   USE_NLS=no
1151   AC_ARG_ENABLE(nls,
1152     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1153     [],
1154     [enable_nls=yes])
1155
1156   # Set configure bits for specified locale package
1157   case ${enable_clocale_flag} in
1158     generic)
1159       AC_MSG_RESULT(generic)
1160
1161       CLOCALE_H=config/locale/generic/c_locale.h
1162       CLOCALE_CC=config/locale/generic/c_locale.cc
1163       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1164       CCOLLATE_CC=config/locale/generic/collate_members.cc
1165       CCTYPE_CC=config/locale/generic/ctype_members.cc
1166       CMESSAGES_H=config/locale/generic/messages_members.h
1167       CMESSAGES_CC=config/locale/generic/messages_members.cc
1168       CMONEY_CC=config/locale/generic/monetary_members.cc
1169       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1170       CTIME_H=config/locale/generic/time_members.h
1171       CTIME_CC=config/locale/generic/time_members.cc
1172       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1173       ;;
1174     darwin)
1175       AC_MSG_RESULT(darwin or freebsd)
1176
1177       CLOCALE_H=config/locale/generic/c_locale.h
1178       CLOCALE_CC=config/locale/generic/c_locale.cc
1179       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1180       CCOLLATE_CC=config/locale/generic/collate_members.cc
1181       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1182       CMESSAGES_H=config/locale/generic/messages_members.h
1183       CMESSAGES_CC=config/locale/generic/messages_members.cc
1184       CMONEY_CC=config/locale/generic/monetary_members.cc
1185       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1186       CTIME_H=config/locale/generic/time_members.h
1187       CTIME_CC=config/locale/generic/time_members.cc
1188       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1189       ;;
1190
1191     gnu)
1192       AC_MSG_RESULT(gnu)
1193
1194       # Declare intention to use gettext, and add support for specific
1195       # languages.
1196       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1197       ALL_LINGUAS="de fr"
1198
1199       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1200       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1201       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1202         USE_NLS=yes
1203       fi
1204       # Export the build objects.
1205       for ling in $ALL_LINGUAS; do \
1206         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1207         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1208       done
1209       AC_SUBST(glibcxx_MOFILES)
1210       AC_SUBST(glibcxx_POFILES)
1211
1212       CLOCALE_H=config/locale/gnu/c_locale.h
1213       CLOCALE_CC=config/locale/gnu/c_locale.cc
1214       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1215       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1216       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1217       CMESSAGES_H=config/locale/gnu/messages_members.h
1218       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1219       CMONEY_CC=config/locale/gnu/monetary_members.cc
1220       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1221       CTIME_H=config/locale/gnu/time_members.h
1222       CTIME_CC=config/locale/gnu/time_members.cc
1223       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1224       ;;
1225     ieee_1003.1-2001)
1226       AC_MSG_RESULT(IEEE 1003.1)
1227
1228       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1229       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1230       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1231       CCOLLATE_CC=config/locale/generic/collate_members.cc
1232       CCTYPE_CC=config/locale/generic/ctype_members.cc
1233       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1234       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1235       CMONEY_CC=config/locale/generic/monetary_members.cc
1236       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1237       CTIME_H=config/locale/generic/time_members.h
1238       CTIME_CC=config/locale/generic/time_members.cc
1239       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1240       ;;
1241   esac
1242
1243   # This is where the testsuite looks for locale catalogs, using the
1244   # -DLOCALEDIR define during testsuite compilation.
1245   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1246   AC_SUBST(glibcxx_localedir)
1247
1248   # A standalone libintl (e.g., GNU libintl) may be in use.
1249   if test $USE_NLS = yes; then
1250     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1251     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1252   fi
1253   if test $USE_NLS = yes; then
1254     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
1255               [Define if NLS translations are to be used.])
1256   fi
1257
1258   AC_SUBST(USE_NLS)
1259   AC_SUBST(CLOCALE_H)
1260   AC_SUBST(CMESSAGES_H)
1261   AC_SUBST(CCODECVT_CC)
1262   AC_SUBST(CCOLLATE_CC)
1263   AC_SUBST(CCTYPE_CC)
1264   AC_SUBST(CMESSAGES_CC)
1265   AC_SUBST(CMONEY_CC)
1266   AC_SUBST(CNUMERIC_CC)
1267   AC_SUBST(CTIME_H)
1268   AC_SUBST(CTIME_CC)
1269   AC_SUBST(CLOCALE_CC)
1270   AC_SUBST(CLOCALE_INTERNAL_H)
1271 ])
1272
1273
1274 dnl
1275 dnl Check for which std::allocator base class to use.  The choice is
1276 dnl mapped from a subdirectory of include/ext.
1277 dnl
1278 dnl Default is new.
1279 dnl
1280 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1281   AC_MSG_CHECKING([for std::allocator base class])
1282   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1283     [use KIND for target std::allocator base],
1284     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1285
1286   # If they didn't use this option switch, or if they specified --enable
1287   # with no specific model, we'll have to look for one.  If they
1288   # specified --disable (???), do likewise.
1289   if test $enable_libstdcxx_allocator = no ||
1290      test $enable_libstdcxx_allocator = yes;
1291   then
1292      enable_libstdcxx_allocator=auto
1293   fi
1294
1295   # Either a known package, or "auto". Auto implies the default choice
1296   # for a particular platform.
1297   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1298
1299   # Probe for host-specific support if no specific model is specified.
1300   # Default to "new".
1301   if test $enable_libstdcxx_allocator_flag = auto; then
1302     case ${target_os} in
1303       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1304         enable_libstdcxx_allocator_flag=new
1305         ;;
1306       *)
1307         enable_libstdcxx_allocator_flag=new
1308         ;;
1309     esac
1310   fi
1311   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1312
1313
1314   # Set configure bits for specified locale package
1315   case ${enable_libstdcxx_allocator_flag} in
1316     bitmap)
1317       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1318       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1319       ;;
1320     malloc)
1321       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1322       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1323       ;;
1324     mt)
1325       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1326       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1327       ;;
1328     new)
1329       ALLOCATOR_H=config/allocator/new_allocator_base.h
1330       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1331       ;;
1332     pool)
1333       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1334       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1335       ;;
1336   esac
1337
1338   AC_SUBST(ALLOCATOR_H)
1339   AC_SUBST(ALLOCATOR_NAME)
1340 ])
1341
1342
1343 dnl
1344 dnl Check for whether the Boost-derived checks should be turned on.
1345 dnl
1346 dnl --enable-concept-checks turns them on.
1347 dnl --disable-concept-checks leaves them off.
1348 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1349 dnl       Where DEFAULT is either `yes' or `no'.
1350 dnl
1351 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1352   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1353   if test $enable_concept_checks = yes; then
1354     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
1355               [Define to use concept checking code from the boost libraries.])
1356   fi
1357 ])
1358
1359
1360 dnl
1361 dnl Check for which I/O library to use:  stdio, or something specific.
1362 dnl
1363 dnl Default is stdio.
1364 dnl
1365 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1366   AC_MSG_CHECKING([for underlying I/O to use])
1367   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1368     [use target-specific I/O package], [permit stdio])
1369
1370   # Now that libio has been removed, you can have any color you want as long
1371   # as it's black.  This is one big no-op until other packages are added, but
1372   # showing the framework never hurts.
1373   case ${enable_cstdio} in
1374     stdio)
1375       CSTDIO_H=config/io/c_io_stdio.h
1376       BASIC_FILE_H=config/io/basic_file_stdio.h
1377       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1378       AC_MSG_RESULT(stdio)
1379       ;;
1380   esac
1381
1382   AC_SUBST(CSTDIO_H)
1383   AC_SUBST(BASIC_FILE_H)
1384   AC_SUBST(BASIC_FILE_CC)
1385 ])
1386
1387
1388 dnl
1389 dnl Check for "unusual" flags to pass to the compiler while building.
1390 dnl
1391 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1392 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1393 dnl --disable-cxx-flags passes nothing.
1394 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1395 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1396 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1397 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1398 dnl       If "default flags" is an empty string, the effect is the same
1399 dnl       as --disable or --enable=no.
1400 dnl
1401 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1402   AC_MSG_CHECKING([for extra compiler flags for building])
1403   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1404     [pass compiler FLAGS when building library],
1405     [case "x$enable_cxx_flags" in
1406       xno | x)   enable_cxx_flags= ;;
1407       x-*)       ;;
1408       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1409      esac])
1410
1411   # Run through flags (either default or command-line) and set anything
1412   # extra (e.g., #defines) that must accompany particular g++ options.
1413   if test -n "$enable_cxx_flags"; then
1414     for f in $enable_cxx_flags; do
1415       case "$f" in
1416         -fhonor-std)  ;;
1417         -*)  ;;
1418         *)   # and we're trying to pass /what/ exactly?
1419              AC_MSG_ERROR([compiler flags start with a -]) ;;
1420       esac
1421     done
1422   fi
1423
1424   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1425   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1426   AC_SUBST(EXTRA_CXX_FLAGS)
1427 ])
1428
1429
1430 dnl
1431 dnl Check to see if debugging libraries are to be built.
1432 dnl
1433 dnl --enable-libstdcxx-debug
1434 dnl builds a separate set of debugging libraries in addition to the
1435 dnl normal (shared, static) libstdc++ binaries.
1436 dnl
1437 dnl --disable-libstdcxx-debug
1438 dnl builds only one (non-debug) version of libstdc++.
1439 dnl
1440 dnl --enable-libstdcxx-debug-flags=FLAGS
1441 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1442 dnl
1443 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1444 dnl       Where DEFAULT is either `yes' or `no'.
1445 dnl
1446 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1447   AC_MSG_CHECKING([for additional debug build])
1448   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1449   AC_MSG_RESULT($enable_libstdcxx_debug)
1450   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1451 ])
1452
1453
1454 dnl
1455 dnl Check for explicit debug flags.
1456 dnl
1457 dnl --enable-libstdcxx-debug-flags='-O1'
1458 dnl is a general method for passing flags to be used when
1459 dnl building debug libraries with --enable-debug.
1460 dnl
1461 dnl --disable-libstdcxx-debug-flags does nothing.
1462 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1463 dnl       If "default flags" is an empty string, the effect is the same
1464 dnl       as --disable or --enable=no.
1465 dnl
1466 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1467   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1468     [pass compiler FLAGS when building debug library],
1469     [case "x$enable_libstdcxx_debug_flags" in
1470       xno | x)    enable_libstdcxx_debug_flags= ;;
1471       x-*)        ;;
1472       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1473      esac])
1474
1475   # Option parsed, now set things appropriately
1476   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1477   AC_SUBST(DEBUG_FLAGS)
1478
1479   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1480 ])
1481
1482
1483 dnl
1484 dnl Check if the user only wants a freestanding library implementation.
1485 dnl
1486 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1487 dnl installing only the headers required by [17.4.1.3] and the language
1488 dnl support library.  More than that will be built (to keep the Makefiles
1489 dnl conveniently clean), but not installed.
1490 dnl
1491 dnl Sets:
1492 dnl  is_hosted  (yes/no)
1493 dnl
1494 dnl Defines:
1495 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1496 dnl
1497 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1498   AC_ARG_ENABLE([hosted-libstdcxx],
1499     AC_HELP_STRING([--disable-hosted-libstdcxx],
1500                    [only build freestanding C++ runtime support]),,
1501     [case "$host" in
1502         arm*-*-symbianelf*)
1503             enable_hosted_libstdcxx=no
1504             ;;
1505         *)
1506             enable_hosted_libstdcxx=yes
1507             ;;
1508      esac])
1509   if test "$enable_hosted_libstdcxx" = no; then
1510     AC_MSG_NOTICE([Only freestanding libraries will be built])
1511     is_hosted=no
1512     hosted_define=0
1513     enable_abi_check=no
1514     enable_libstdcxx_pch=no
1515   else
1516     is_hosted=yes
1517     hosted_define=1
1518   fi
1519   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1520   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1521     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1522 ])
1523
1524
1525 dnl
1526 dnl Check for template specializations for the 'long long' type.
1527 dnl The result determines only whether 'long long' I/O is enabled; things
1528 dnl like numeric_limits<> specializations are always available.
1529 dnl
1530 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1531 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1532 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1533 dnl       Where DEFAULT is either `yes' or `no'.
1534 dnl
1535 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1536   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
1537   if test $enable_long_long = yes; then
1538     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
1539               [Define if code specialized for long long should be used.])
1540   fi
1541   AC_MSG_CHECKING([for enabled long long specializations])
1542   AC_MSG_RESULT([$enable_long_long])
1543 ])
1544
1545
1546 dnl
1547 dnl Check for template specializations for the 'wchar_t' type.
1548 dnl
1549 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
1550 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
1551 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
1552 dnl       Where DEFAULT is either `yes' or `no'.
1553 dnl
1554 dnl Necessary support (probed along with C99 support) must also be present.
1555 dnl
1556 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
1557   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
1558   if test x"$ac_c99_wchar" = x"yes" && test x"$enable_wchar_t" = x"yes"; then
1559     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
1560               [Define if code specialized for wchar_t should be used.])
1561   fi
1562   AC_MSG_CHECKING([for enabled wchar_t specializations])
1563   AC_MSG_RESULT([$enable_wchar_t])
1564 ])
1565
1566
1567 dnl
1568 dnl Check to see if building and using a C++ precompiled header can be done.
1569 dnl
1570 dnl --enable-libstdcxx-pch=yes
1571 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1572 dnl may work, after some light-hearted attempts to puzzle out compiler
1573 dnl support, flip bits on in include/Makefile.am
1574 dnl
1575 dnl --disable-libstdcxx-pch
1576 dnl turns off attempts to use or build stdc++.h.gch.
1577 dnl
1578 dnl Substs:
1579 dnl  glibcxx_PCHFLAGS
1580 dnl
1581 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1582   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1583   if test $enable_libstdcxx_pch = yes; then
1584     AC_CACHE_CHECK([for compiler with PCH support],
1585       [glibcxx_cv_prog_CXX_pch],
1586       [ac_save_CXXFLAGS="$CXXFLAGS"
1587        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1588        AC_LANG_SAVE
1589        AC_LANG_CPLUSPLUS
1590        echo '#include <math.h>' > conftest.h
1591        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1592                           -o conftest.h.gch 1>&5 2>&1 &&
1593                 echo '#error "pch failed"' > conftest.h &&
1594           echo '#include "conftest.h"' > conftest.cc &&
1595                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1596        then
1597          glibcxx_cv_prog_CXX_pch=yes
1598        else
1599          glibcxx_cv_prog_CXX_pch=no
1600        fi
1601        rm -f conftest*
1602        CXXFLAGS=$ac_save_CXXFLAGS
1603        AC_LANG_RESTORE
1604       ])
1605     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1606   fi
1607
1608   AC_MSG_CHECKING([for enabled PCH])
1609   AC_MSG_RESULT([$enable_libstdcxx_pch])
1610
1611   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1612   if test $enable_libstdcxx_pch = yes; then
1613     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1614   else
1615     glibcxx_PCHFLAGS=""
1616   fi
1617   AC_SUBST(glibcxx_PCHFLAGS)
1618 ])
1619
1620
1621 dnl
1622 dnl Check for exception handling support.  If an explicit enable/disable
1623 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1624 dnl target may or may not support call frame exceptions.
1625 dnl
1626 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1627 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1628 dnl Neither one forces an attempt at detection.
1629 dnl
1630 dnl Defines:
1631 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1632 dnl
1633 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1634   AC_MSG_CHECKING([for exception model to use])
1635   AC_LANG_SAVE
1636   AC_LANG_CPLUSPLUS
1637   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1638     [force use of builtin_setjmp for exceptions],
1639     [permit yes|no|auto])
1640
1641   if test $enable_sjlj_exceptions = auto; then
1642     # Botheration.  Now we've got to detect the exception model.  Link tests
1643     # against libgcc.a are problematic since we've not been given proper -L
1644     # bits for single-tree newlib and libgloss.
1645     #
1646     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1647     cat > conftest.$ac_ext << EOF
1648 [#]line __oline__ "configure"
1649 struct S { ~S(); };
1650 void bar();
1651 void foo()
1652 {
1653   S s;
1654   bar();
1655 }
1656 EOF
1657     old_CXXFLAGS="$CXXFLAGS"
1658     CXXFLAGS=-S
1659     if AC_TRY_EVAL(ac_compile); then
1660       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1661         enable_sjlj_exceptions=yes
1662       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1663         enable_sjlj_exceptions=no
1664       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
1665         enable_sjlj_exceptions=no
1666       fi
1667     fi
1668     CXXFLAGS="$old_CXXFLAGS"
1669     rm -f conftest*
1670   fi
1671
1672   # This is a tad weird, for hysterical raisins.  We have to map
1673   # enable/disable to two different models.
1674   case $enable_sjlj_exceptions in
1675     yes)
1676       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1677         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1678       ac_exception_model_name=sjlj
1679       ;;
1680     no)
1681       ac_exception_model_name="call frame"
1682       ;;
1683     *)
1684       AC_MSG_ERROR([unable to detect exception model])
1685       ;;
1686   esac
1687  AC_LANG_RESTORE
1688  AC_MSG_RESULT($ac_exception_model_name)
1689 ])
1690
1691
1692 dnl
1693 dnl Add version tags to symbols in shared library (or not), additionally
1694 dnl marking other symbols as private/local (or not).
1695 dnl
1696 dnl --enable-symvers=style adds a version script to the linker call when
1697 dnl       creating the shared library.  The choice of version script is
1698 dnl       controlled by 'style'.
1699 dnl --disable-symvers does not.
1700 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1701 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1702 dnl       choose a default style based on linker characteristics.  Passing
1703 dnl       'no' disables versioning.
1704 dnl
1705 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1706
1707 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1708   [enables symbol versioning of the shared library],
1709   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export])
1710
1711 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1712 # don't know enough about $LD to do tricks...
1713 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1714
1715 # Turn a 'yes' into a suitable default.
1716 if test x$enable_symvers = xyes ; then
1717   if test $enable_shared = no || test "x$LD" = x ; then
1718     enable_symvers=no
1719   else
1720     if test $with_gnu_ld = yes ; then
1721       enable_symvers=gnu
1722     else
1723       case ${target_os} in
1724         darwin*)
1725           enable_symvers=darwin ;;
1726         *)
1727           enable_symvers=no ;;
1728       esac
1729     fi
1730   fi
1731 fi
1732
1733 # Check to see if 'darwin' or 'darwin-export' can win.
1734 if test x$enable_symvers = xdarwin-export ; then
1735     enable_symvers=darwin
1736 fi
1737
1738 # Check to see if 'gnu' can win.
1739 if test $enable_symvers = gnu || test $enable_symvers = gnu-versioned-namespace; then
1740   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1741   AC_MSG_CHECKING([for shared libgcc])
1742   ac_save_CFLAGS="$CFLAGS"
1743   CFLAGS=' -lgcc_s'
1744   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1745   CFLAGS="$ac_save_CFLAGS"
1746   if test $glibcxx_shared_libgcc = no; then
1747     cat > conftest.c <<EOF
1748 int main (void) { return 0; }
1749 EOF
1750 changequote(,)dnl
1751     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1752                              -shared -shared-libgcc -o conftest.so \
1753                              conftest.c -v 2>&1 >/dev/null \
1754                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1755 changequote([,])dnl
1756     rm -f conftest.c conftest.so
1757     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1758       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1759       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1760       CFLAGS="$ac_save_CFLAGS"
1761     fi
1762   fi
1763   AC_MSG_RESULT($glibcxx_shared_libgcc)
1764
1765   # For GNU ld, we need at least this version.  The format is described in
1766   # GLIBCXX_CHECK_LINKER_FEATURES above.
1767   glibcxx_min_gnu_ld_version=21400
1768
1769   # If no shared libgcc, can't win.
1770   if test $glibcxx_shared_libgcc != yes; then
1771       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
1772       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
1773       AC_MSG_WARN([=== Symbol versioning will be disabled.])
1774       enable_symvers=no
1775   elif test $with_gnu_ld != yes ; then
1776     # just fail for now
1777     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
1778     AC_MSG_WARN([=== you are not using the GNU linker.])
1779     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1780     enable_symvers=no
1781   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
1782     # The right tools, the right setup, but too old.  Fallbacks?
1783     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1784     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1785     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1786     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1787     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1788     enable_symvers=no
1789   fi
1790 fi
1791
1792 # Everything parsed; figure out what file to use.
1793 case $enable_symvers in
1794   no)
1795     SYMVER_FILE=config/abi/pre/none.ver
1796     ;;
1797   gnu)
1798     SYMVER_FILE=config/abi/pre/gnu.ver
1799     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
1800               [Define to use GNU versioning in the shared library.])
1801     ;;
1802   gnu-versioned-namespace)
1803     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
1804     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
1805               [Define to use GNU namespace versioning in the shared library.])
1806     ;;
1807   darwin)
1808     SYMVER_FILE=config/abi/pre/gnu.ver
1809     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
1810               [Define to use darwin versioning in the shared library.])
1811     ;;
1812 esac
1813
1814 if test x$enable_symvers != xno ; then
1815   AC_DEFINE(_GLIBCXX_SYMVER, 1,
1816          [Define to use symbol versioning in the shared library.])
1817 fi
1818
1819 AC_SUBST(SYMVER_FILE)
1820 AC_SUBST(port_specific_symbol_files)
1821 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
1822 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
1823 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
1824 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
1825 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1826
1827 # Now, set up compatibility support, if any.
1828 # In addition, need this to deal with std::size_t mangling in
1829 # src/compatibility.cc.  In a perfect world, could use
1830 # typeid(std::size_t).name()[0] to do direct substitution.
1831 AC_MSG_CHECKING([for size_t as unsigned int])
1832 ac_save_CFLAGS="$CFLAGS"
1833 CFLAGS="-Werror"
1834 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
1835                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
1836 CFLAGS=$ac_save_CFLAGS
1837 if test "$glibcxx_size_t_is_i" = yes; then
1838   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
1839 fi
1840 AC_MSG_RESULT([$glibcxx_size_t_is_i])
1841
1842 AC_MSG_CHECKING([for ptrdiff_t as int])
1843 ac_save_CFLAGS="$CFLAGS"
1844 CFLAGS="-Werror"
1845 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
1846                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
1847 CFLAGS=$ac_save_CFLAGS
1848 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
1849   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
1850 fi
1851 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
1852 ])
1853
1854
1855 dnl
1856 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1857 dnl We must stage the required headers so that they will be installed
1858 dnl with the library (unlike libgcc, the STL implementation is provided
1859 dnl solely within headers).  Since we must not inject random user-space
1860 dnl macro names into user-provided C++ code, we first stage into <file>-in
1861 dnl and process to <file> with an output command.  The reason for a two-
1862 dnl stage process here is to correctly handle $srcdir!=$objdir without
1863 dnl having to write complex code (the sed commands to clean the macro
1864 dnl namespace are complex and fragile enough as it is).  We must also
1865 dnl add a relative path so that -I- is supported properly.
1866 dnl
1867 dnl Substs:
1868 dnl  glibcxx_thread_h
1869 dnl
1870 dnl Defines:
1871 dnl  HAVE_GTHR_DEFAULT
1872 dnl
1873 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1874   AC_MSG_CHECKING([for thread model used by GCC])
1875   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1876   AC_MSG_RESULT([$target_thread_file])
1877
1878   if test $target_thread_file != single; then
1879     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
1880               [Define if gthr-default.h exists
1881               (meaning that threading support is enabled).])
1882   fi
1883
1884   glibcxx_thread_h=gthr-$target_thread_file.h
1885
1886   dnl Check for __GTHREADS define.
1887   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
1888   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
1889     enable_thread=yes
1890   else
1891    enable_thread=no
1892   fi
1893
1894   AC_SUBST(glibcxx_thread_h)
1895 ])
1896
1897
1898 # Check whether LC_MESSAGES is available in <locale.h>.
1899 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1900 #
1901 # This file file be copied and used freely without restrictions.  It can
1902 # be used in projects which are not available under the GNU Public License
1903 # but which still want to provide support for the GNU gettext functionality.
1904 # Please note that the actual code is *not* freely available.
1905
1906 # serial 1
1907 AC_DEFUN([AC_LC_MESSAGES], [
1908   AC_CHECK_HEADER(locale.h, [
1909     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1910       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1911        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1912     if test $ac_cv_val_LC_MESSAGES = yes; then
1913       AC_DEFINE(HAVE_LC_MESSAGES, 1,
1914                 [Define if LC_MESSAGES is available in <locale.h>.])
1915     fi
1916   ])
1917 ])
1918
1919 # Macros from the top-level gcc directory.
1920 m4_include([../config/tls.m4])
1921