libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:15:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  no-dist:  we don't want 'dist' and related rules.
  76 #  -Wall:  turns on all automake warnings...
  77 #  -Wno-portability:  ...except this one, since GNU make is now required.
  78 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  79 AH_TEMPLATE(PACKAGE, [Name of package])
  80 AH_TEMPLATE(VERSION, [Version number of package])
  81
  82 # -fno-builtin must be present here so that a non-conflicting form of
  83 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  84
  85 save_CXXFLAGS="$CXXFLAGS"
  86 CXXFLAGS="$CXXFLAGS -fno-builtin"
  87 AC_PROG_CC
  88 AC_PROG_CXX
  89 CXXFLAGS="$save_CXXFLAGS"
  90
  91 # Runs configure.host, and assorted other critical bits.  Sets
  92 # up critical shell variables.
  93 GLIBCXX_CONFIGURE
  94
  95 if test "x${with_newlib}" != "xyes"; then
  96   AC_LIBTOOL_DLOPEN
  97 fi
  98 AM_PROG_LIBTOOL
  99 ACX_LT_HOST_FLAGS
 100 AC_SUBST(enable_shared)
 101 AC_SUBST(enable_static)
 102
 103 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 104 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 105
 106 # Possibly disable most of the library.
 107 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 108 ## than just ignoring the results.  Faster /and/ more correct, win win.
 109 GLIBCXX_ENABLE_HOSTED
 110
 111 # Enable compiler support that doesn't require linking.
 112 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 113 GLIBCXX_ENABLE_PCH($is_hosted)
 114 GLIBCXX_ENABLE_THREADS
 115 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 116 GLIBCXX_ENABLE_DECIMAL_FLOAT
 117
 118 # Checks for compiler support that doesn't require linking.
 119 GLIBCXX_CHECK_COMPILER_FEATURES
 120
 121 # Enable all the variable C++ runtime options that don't require linking.
 122 GLIBCXX_ENABLE_CSTDIO
 123 GLIBCXX_ENABLE_CLOCALE
 124 GLIBCXX_ENABLE_ALLOCATOR
 125 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 126 GLIBCXX_ENABLE_LONG_LONG([yes])
 127 GLIBCXX_ENABLE_WCHAR_T([yes])
 128 GLIBCXX_ENABLE_C99([yes])
 129 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 130 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 131 GLIBCXX_ENABLE_DEBUG([no])
 132 GLIBCXX_ENABLE_PARALLEL([yes])
 133 GLIBCXX_ENABLE_CXX_FLAGS
 134 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 135 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 136
 137 # Checks for operating systems support that doesn't require linking.
 138 GLIBCXX_CHECK_SYSTEM_ERROR
 139
 140 # For the streamoff typedef.
 141 GLIBCXX_CHECK_INT64_T
 142
 143 # For LFS support.
 144 GLIBCXX_CHECK_LFS
 145
 146 # For showmanyc_helper().
 147 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 148 GLIBCXX_CHECK_POLL
 149 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 150
 151 # For xsputn_2().
 152 AC_CHECK_HEADERS(sys/uio.h)
 153 GLIBCXX_CHECK_WRITEV
 154
 155 # For C99 support to TR1.
 156 GLIBCXX_CHECK_C99_TR1
 157
 158 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 159 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 160
 161 # For gettimeofday support.
 162 GLIBCXX_CHECK_GETTIMEOFDAY
 163
 164 # For clock_gettime, nanosleep and sched_yield support.
 165 # NB: The default is [no], because otherwise it requires linking.
 166 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 167
 168 # For gthread support
 169 GLIBCXX_CHECK_GTHREADS
 170
 171 AC_LC_MESSAGES
 172
 173 # Check for available headers.
 174 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 175 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 176 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 177 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 178 wchar.h wctype.h])
 179
 180 # Only do link tests if native. Else, hardcode.
 181 if $GLIBCXX_IS_NATIVE; then
 182
 183   # We can do more elaborate tests that assume a working linker.
 184   CANADIAN=no
 185
 186   GLIBCXX_CHECK_LINKER_FEATURES
 187   GLIBCXX_CHECK_MATH_SUPPORT
 188   GLIBCXX_CHECK_STDLIB_SUPPORT
 189
 190   # For /dev/random and /dev/urandom for TR1.
 191   GLIBCXX_CHECK_RANDOM_TR1
 192
 193   # For TLS support.
 194   GCC_CHECK_TLS
 195
 196   # For iconv support.
 197   AM_ICONV
 198
 199 else
 200
 201   # This lets us hard-code the functionality we know we'll have in the cross
 202   # target environment.  "Let" is a sugar-coated word placed on an especially
 203   # dull and tedious hack, actually.
 204   #
 205   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 206   # that involve linking, can't be used:
 207   #    "cannot open sim-crt0.o"
 208   #    "cannot open crt0.o"
 209   # etc.  All this is because there currently exists no unified, consistent
 210   # way for top level CC information to be passed down to target directories:
 211   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 212   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 213   # crosses can be removed.
 214
 215   # If Canadian cross, then don't pick up tools from the build directory.
 216   # Used only in GLIBCXX_EXPORT_INCLUDES.
 217   if test -n "$with_cross_host" &&
 218      test x"$build_alias" != x"$with_cross_host" &&
 219      test x"$build" != x"$target";
 220   then
 221     CANADIAN=yes
 222   else
 223     CANADIAN=no
 224   fi
 225
 226   # Construct crosses by hand, eliminating bits that need ld...
 227   # GLIBCXX_CHECK_MATH_SUPPORT
 228
 229   # First, test for "known" system libraries.  We may be using newlib even
 230   # on a hosted environment.
 231   if test "x${with_newlib}" = "xyes"; then
 232     os_include_dir="os/newlib"
 233     AC_DEFINE(HAVE_HYPOT)
 234
 235     # GLIBCXX_CHECK_STDLIB_SUPPORT
 236     AC_DEFINE(HAVE_STRTOF)
 237
 238     AC_DEFINE(HAVE_ACOSF)
 239     AC_DEFINE(HAVE_ASINF)
 240     AC_DEFINE(HAVE_ATAN2F)
 241     AC_DEFINE(HAVE_ATANF)
 242     AC_DEFINE(HAVE_CEILF)
 243     AC_DEFINE(HAVE_COSF)
 244     AC_DEFINE(HAVE_COSHF)
 245     AC_DEFINE(HAVE_EXPF)
 246     AC_DEFINE(HAVE_FABSF)
 247     AC_DEFINE(HAVE_FLOORF)
 248     AC_DEFINE(HAVE_FMODF)
 249     AC_DEFINE(HAVE_FREXPF)
 250     AC_DEFINE(HAVE_LDEXPF)
 251     AC_DEFINE(HAVE_LOG10F)
 252     AC_DEFINE(HAVE_LOGF)
 253     AC_DEFINE(HAVE_MODFF)
 254     AC_DEFINE(HAVE_POWF)
 255     AC_DEFINE(HAVE_SINF)
 256     AC_DEFINE(HAVE_SINHF)
 257     AC_DEFINE(HAVE_SQRTF)
 258     AC_DEFINE(HAVE_TANF)
 259     AC_DEFINE(HAVE_TANHF)
 260
 261     AC_DEFINE(HAVE_ICONV)
 262   else
 263     GLIBCXX_CROSSCONFIG
 264   fi
 265
 266   # At some point, we should differentiate between architectures
 267   # like x86, which have long double versions, and alpha/powerpc/etc.,
 268   # which don't. For the time being, punt.
 269   if test x"long_double_math_on_this_cpu" = x"yes"; then
 270     AC_DEFINE(HAVE_ACOSL)
 271     AC_DEFINE(HAVE_ASINL)
 272     AC_DEFINE(HAVE_ATAN2L)
 273     AC_DEFINE(HAVE_ATANL)
 274     AC_DEFINE(HAVE_CEILL)
 275     AC_DEFINE(HAVE_COSL)
 276     AC_DEFINE(HAVE_COSHL)
 277     AC_DEFINE(HAVE_EXPL)
 278     AC_DEFINE(HAVE_FABSL)
 279     AC_DEFINE(HAVE_FLOORL)
 280     AC_DEFINE(HAVE_FMODL)
 281     AC_DEFINE(HAVE_FREXPL)
 282     AC_DEFINE(HAVE_LDEXPL)
 283     AC_DEFINE(HAVE_LOG10L)
 284     AC_DEFINE(HAVE_LOGL)
 285     AC_DEFINE(HAVE_MODFL)
 286     AC_DEFINE(HAVE_POWL)
 287     AC_DEFINE(HAVE_SINCOSL)
 288     AC_DEFINE(HAVE_SINL)
 289     AC_DEFINE(HAVE_SINHL)
 290     AC_DEFINE(HAVE_SQRTL)
 291     AC_DEFINE(HAVE_TANL)
 292     AC_DEFINE(HAVE_TANHL)
 293   fi
 294 fi
 295
 296 # Check for _Unwind_GetIPInfo.
 297 GCC_CHECK_UNWIND_GETIPINFO
 298
 299
 300 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 301
 302 GCC_HEADER_STDINT(include/gstdint.h)
 303
 304 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 305 GLIBCXX_ENABLE_SYMVERS([yes])
 306 GLIBCXX_ENABLE_VISIBILITY([yes])
 307
 308 ac_ldbl_compat=no
 309 case "$target" in
 310   powerpc*-*-linux* | \
 311   sparc*-*-linux* | \
 312   s390*-*-linux* | \
 313   alpha*-*-linux*)
 314   AC_TRY_COMPILE(, [
 315 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 316 #error no need for long double compatibility
 317 #endif
 318   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 319   if test "$ac_ldbl_compat" = yes; then
 320     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 321               [Define if compatibility should be provided for -mlong-double-64.])
 322     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 323   fi
 324 esac
 325 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 326
 327 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 328 GLIBCXX_CONFIGURE_TESTSUITE
 329
 330 # Define documentation rules conditionally.
 331
 332 # See if makeinfo has been installed and is modern enough
 333 # that we can use it.
 334 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 335                    [GNU texinfo.* \([0-9][0-9.]*\)],
 336                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 337 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 338
 339 # Check for doxygen
 340 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 341 AC_CHECK_PROG([DOT], dot, yes, no)
 342
 343 # Check for docbook
 344 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 345 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 346 GLIBCXX_CONFIGURE_DOCBOOK
 347
 348 # Check for xml/html dependencies.
 349 AM_CONDITIONAL(BUILD_XML,
 350                test $ac_cv_prog_DOXYGEN = "yes" &&
 351                test $ac_cv_prog_DOT = "yes" &&
 352                test $ac_cv_prog_XSLTPROC = "yes" &&
 353                test $ac_cv_prog_XMLLINT = "yes" &&
 354                test $glibcxx_stylesheets = "yes")
 355
 356 AM_CONDITIONAL(BUILD_HTML,
 357                test $ac_cv_prog_DOXYGEN = "yes" &&
 358                test $ac_cv_prog_DOT = "yes" &&
 359                test $ac_cv_prog_XSLTPROC = "yes" &&
 360                test $ac_cv_prog_XMLLINT = "yes" &&
 361                test $glibcxx_stylesheets = "yes")
 362
 363 # Check for man dependencies.
 364 AM_CONDITIONAL(BUILD_MAN,
 365                test $ac_cv_prog_DOXYGEN = "yes" &&
 366                test $ac_cv_prog_DOT = "yes")
 367
 368 # Check for pdf/epub dependencies.
 369 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 370 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 371 AM_CONDITIONAL(BUILD_PDF,
 372                test $ac_cv_prog_DBLATEX = "yes" &&
 373                test $ac_cv_prog_PDFLATEX = "yes")
 374
 375 AC_CHECK_PROG([RUBY], ruby, yes, no)
 376 AC_CHECK_PROG([DBTOEPUB], dbtoepub, yes, no)
 377 AM_CONDITIONAL(BUILD_EPUB,
 378                test $ac_cv_prog_RUBY = "yes" &&
 379                test $ac_cv_prog_DBTOEPUB = "yes")
 380
 381
 382 # Propagate the target-specific source directories through the build chain.
 383 ATOMICITY_SRCDIR=config/${atomicity_dir}
 384 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 385 ATOMIC_FLAGS=${atomic_flags}
 386 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 387 OS_INC_SRCDIR=config/${os_include_dir}
 388 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 389 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 390 AC_SUBST(ATOMICITY_SRCDIR)
 391 AC_SUBST(ATOMIC_WORD_SRCDIR)
 392 AC_SUBST(ATOMIC_FLAGS)
 393 AC_SUBST(CPU_DEFINES_SRCDIR)
 394 AC_SUBST(ABI_TWEAKS_SRCDIR)
 395 AC_SUBST(OS_INC_SRCDIR)
 396 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 397
 398
 399 # Determine cross-compile flags and AM_CONDITIONALs.
 400 #AC_SUBST(GLIBCXX_IS_NATIVE)
 401 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 402 GLIBCXX_EVALUATE_CONDITIONALS
 403
 404 AC_CACHE_SAVE
 405
 406 if test ${multilib} = yes; then
 407   multilib_arg="--enable-multilib"
 408 else
 409   multilib_arg=
 410 fi
 411
 412 # Export all the install information.
 413 GLIBCXX_EXPORT_INSTALL_INFO
 414
 415 # Export all the include and flag information to Makefiles.
 416 GLIBCXX_EXPORT_INCLUDES
 417 GLIBCXX_EXPORT_FLAGS
 418
 419 if test "$enable_shared" = yes; then
 420   LIBSUPCXX_PICFLAGS="-prefer-pic"
 421 else
 422   LIBSUPCXX_PICFLAGS=
 423 fi
 424 AC_SUBST(LIBSUPCXX_PICFLAGS)
 425
 426 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 427 dnl which can all be called multiple times as needed, plus one (different)
 428 dnl AC_OUTPUT macro.  This one lists the files to be created:
 429 AC_CONFIG_FILES(Makefile)
 430 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 431 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 432
 433 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 434 # that multilib installs will end up installed in the correct place.
 435 # The testsuite needs it for multilib-aware ABI baseline files.
 436 # To work around this not being passed down from config-ml.in ->
 437 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 438 # append it here.  Only modify Makefiles that have just been created.
 439 #
 440 # Also, get rid of this simulated-VPATH thing that automake does.
 441 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 442   [cat > vpsed$$ << \_EOF
 443 s!`test -f '$<' || echo '$(srcdir)/'`!!
 444 _EOF
 445    sed -f vpsed$$ $ac_file > tmp$$
 446    mv tmp$$ $ac_file
 447    rm vpsed$$
 448    echo 'MULTISUBDIR =' >> $ac_file
 449    ml_norecursion=yes
 450    . ${multi_basedir}/config-ml.in
 451    AS_UNSET([ml_norecursion])
 452 ])
 453
 454 AC_CONFIG_COMMANDS([generate-headers],
 455   [(cd include && ${MAKE-make} pch_build= )])
 456
 457 dnl And this actually makes things happen:
 458 AC_OUTPUT