libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:14:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  no-dist:  we don't want 'dist' and related rules.
  76 #  -Wall:  turns on all automake warnings...
  77 #  -Wno-portability:  ...except this one, since GNU make is now required.
  78 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  79 AH_TEMPLATE(PACKAGE, [Name of package])
  80 AH_TEMPLATE(VERSION, [Version number of package])
  81
  82 # -fno-builtin must be present here so that a non-conflicting form of
  83 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  84
  85 save_CXXFLAGS="$CXXFLAGS"
  86 CXXFLAGS="$CXXFLAGS -fno-builtin"
  87 AC_PROG_CC
  88 AC_PROG_CXX
  89 CXXFLAGS="$save_CXXFLAGS"
  90
  91 # Runs configure.host, and assorted other critical bits.  Sets
  92 # up critical shell variables.
  93 GLIBCXX_CONFIGURE
  94
  95 if test "x${with_newlib}" != "xyes"; then
  96   AC_LIBTOOL_DLOPEN
  97 fi
  98 AM_PROG_LIBTOOL
  99 AC_SUBST(enable_shared)
 100 AC_SUBST(enable_static)
 101
 102 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 103 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 104
 105 # Possibly disable most of the library.
 106 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 107 ## than just ignoring the results.  Faster /and/ more correct, win win.
 108 GLIBCXX_ENABLE_HOSTED
 109
 110 # Enable compiler support that doesn't require linking.
 111 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 112 GLIBCXX_ENABLE_PCH($is_hosted)
 113 GLIBCXX_ENABLE_THREADS
 114 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 115 GLIBCXX_ENABLE_DECIMAL_FLOAT
 116
 117 # Checks for compiler support that doesn't require linking.
 118 GLIBCXX_CHECK_COMPILER_FEATURES
 119
 120 # Enable all the variable C++ runtime options that don't require linking.
 121 GLIBCXX_ENABLE_CSTDIO
 122 GLIBCXX_ENABLE_CLOCALE
 123 GLIBCXX_ENABLE_ALLOCATOR
 124 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 125 GLIBCXX_ENABLE_LONG_LONG([yes])
 126 GLIBCXX_ENABLE_WCHAR_T([yes])
 127 GLIBCXX_ENABLE_C99([yes])
 128 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 129 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 130 GLIBCXX_ENABLE_DEBUG([no])
 131 GLIBCXX_ENABLE_PARALLEL([yes])
 132 GLIBCXX_ENABLE_CXX_FLAGS
 133 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 134
 135 # Checks for operating systems support that doesn't require linking.
 136 GLIBCXX_CHECK_SYSTEM_ERROR
 137
 138 # For the streamoff typedef.
 139 GLIBCXX_CHECK_INT64_T
 140
 141 # For LFS support.
 142 GLIBCXX_CHECK_LFS
 143
 144 # For showmanyc_helper().
 145 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 146 GLIBCXX_CHECK_POLL
 147 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 148
 149 # For xsputn_2().
 150 AC_CHECK_HEADERS(sys/uio.h)
 151 GLIBCXX_CHECK_WRITEV
 152
 153 # For C99 support to TR1.
 154 GLIBCXX_CHECK_C99_TR1
 155
 156 # For common values of EOF, SEEK_CUR, SEEK_END.
 157 GLIBCXX_CHECK_STDIO_MACROS
 158
 159 # For gettimeofday support.
 160 GLIBCXX_CHECK_GETTIMEOFDAY
 161
 162 # For clock_gettime, nanosleep and sched_yield support.
 163 # NB: The default is [no], because otherwise it requires linking.
 164 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 165
 166 # For gthread support
 167 GLIBCXX_CHECK_GTHREADS
 168
 169 AC_LC_MESSAGES
 170
 171 # Check for available headers.
 172 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 173 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 174 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 175 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 176 wchar.h wctype.h])
 177
 178 # Only do link tests if native. Else, hardcode.
 179 if $GLIBCXX_IS_NATIVE; then
 180
 181   # We can do more elaborate tests that assume a working linker.
 182   CANADIAN=no
 183
 184   GLIBCXX_CHECK_LINKER_FEATURES
 185   GLIBCXX_CHECK_MATH_SUPPORT
 186   GLIBCXX_CHECK_STDLIB_SUPPORT
 187
 188   # For /dev/random and /dev/urandom for TR1.
 189   GLIBCXX_CHECK_RANDOM_TR1
 190
 191   # For TLS support.
 192   GCC_CHECK_TLS
 193
 194   # For iconv support.
 195   AM_ICONV
 196
 197 else
 198
 199   # This lets us hard-code the functionality we know we'll have in the cross
 200   # target environment.  "Let" is a sugar-coated word placed on an especially
 201   # dull and tedious hack, actually.
 202   #
 203   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 204   # that involve linking, can't be used:
 205   #    "cannot open sim-crt0.o"
 206   #    "cannot open crt0.o"
 207   # etc.  All this is because there currently exists no unified, consistent
 208   # way for top level CC information to be passed down to target directories:
 209   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 210   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 211   # crosses can be removed.
 212
 213   # If Canadian cross, then don't pick up tools from the build directory.
 214   # Used only in GLIBCXX_EXPORT_INCLUDES.
 215   if test -n "$with_cross_host" &&
 216      test x"$build_alias" != x"$with_cross_host" &&
 217      test x"$build" != x"$target";
 218   then
 219     CANADIAN=yes
 220   else
 221     CANADIAN=no
 222   fi
 223
 224   # Construct crosses by hand, eliminating bits that need ld...
 225   # GLIBCXX_CHECK_MATH_SUPPORT
 226
 227   # First, test for "known" system libraries.  We may be using newlib even
 228   # on a hosted environment.
 229   if test "x${with_newlib}" = "xyes"; then
 230     os_include_dir="os/newlib"
 231     AC_DEFINE(HAVE_HYPOT)
 232
 233     # GLIBCXX_CHECK_STDLIB_SUPPORT
 234     AC_DEFINE(HAVE_STRTOF)
 235
 236     AC_DEFINE(HAVE_ACOSF)
 237     AC_DEFINE(HAVE_ASINF)
 238     AC_DEFINE(HAVE_ATAN2F)
 239     AC_DEFINE(HAVE_ATANF)
 240     AC_DEFINE(HAVE_CEILF)
 241     AC_DEFINE(HAVE_COSF)
 242     AC_DEFINE(HAVE_COSHF)
 243     AC_DEFINE(HAVE_EXPF)
 244     AC_DEFINE(HAVE_FABSF)
 245     AC_DEFINE(HAVE_FLOORF)
 246     AC_DEFINE(HAVE_FMODF)
 247     AC_DEFINE(HAVE_FREXPF)
 248     AC_DEFINE(HAVE_LDEXPF)
 249     AC_DEFINE(HAVE_LOG10F)
 250     AC_DEFINE(HAVE_LOGF)
 251     AC_DEFINE(HAVE_MODFF)
 252     AC_DEFINE(HAVE_POWF)
 253     AC_DEFINE(HAVE_SINF)
 254     AC_DEFINE(HAVE_SINHF)
 255     AC_DEFINE(HAVE_SQRTF)
 256     AC_DEFINE(HAVE_TANF)
 257     AC_DEFINE(HAVE_TANHF)
 258
 259     AC_DEFINE(HAVE_ICONV)
 260   else
 261     GLIBCXX_CROSSCONFIG
 262   fi
 263
 264   # At some point, we should differentiate between architectures
 265   # like x86, which have long double versions, and alpha/powerpc/etc.,
 266   # which don't. For the time being, punt.
 267   if test x"long_double_math_on_this_cpu" = x"yes"; then
 268     AC_DEFINE(HAVE_ACOSL)
 269     AC_DEFINE(HAVE_ASINL)
 270     AC_DEFINE(HAVE_ATAN2L)
 271     AC_DEFINE(HAVE_ATANL)
 272     AC_DEFINE(HAVE_CEILL)
 273     AC_DEFINE(HAVE_COSL)
 274     AC_DEFINE(HAVE_COSHL)
 275     AC_DEFINE(HAVE_EXPL)
 276     AC_DEFINE(HAVE_FABSL)
 277     AC_DEFINE(HAVE_FLOORL)
 278     AC_DEFINE(HAVE_FMODL)
 279     AC_DEFINE(HAVE_FREXPL)
 280     AC_DEFINE(HAVE_LDEXPL)
 281     AC_DEFINE(HAVE_LOG10L)
 282     AC_DEFINE(HAVE_LOGL)
 283     AC_DEFINE(HAVE_MODFL)
 284     AC_DEFINE(HAVE_POWL)
 285     AC_DEFINE(HAVE_SINCOSL)
 286     AC_DEFINE(HAVE_SINL)
 287     AC_DEFINE(HAVE_SINHL)
 288     AC_DEFINE(HAVE_SQRTL)
 289     AC_DEFINE(HAVE_TANL)
 290     AC_DEFINE(HAVE_TANHL)
 291   fi
 292 fi
 293
 294 # Check for _Unwind_GetIPInfo.
 295 GCC_CHECK_UNWIND_GETIPINFO
 296
 297
 298 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 299
 300 GCC_HEADER_STDINT(include/gstdint.h)
 301
 302 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 303 GLIBCXX_ENABLE_SYMVERS([yes])
 304 GLIBCXX_ENABLE_VISIBILITY([yes])
 305
 306 ac_ldbl_compat=no
 307 case "$target" in
 308   powerpc*-*-linux* | \
 309   powerpc*-*-gnu* | \
 310   sparc*-*-linux* | \
 311   s390*-*-linux* | \
 312   alpha*-*-linux*)
 313   AC_TRY_COMPILE(, [
 314 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 315 #error no need for long double compatibility
 316 #endif
 317   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 318   if test "$ac_ldbl_compat" = yes; then
 319     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 320               [Define if compatibility should be provided for -mlong-double-64.])
 321     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 322   fi
 323 esac
 324 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 325
 326 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 327 GLIBCXX_CONFIGURE_TESTSUITE
 328
 329 # Propagate the target-specific source directories through the build chain.
 330 ATOMICITY_SRCDIR=config/${atomicity_dir}
 331 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 332 ATOMIC_FLAGS=${atomic_flags}
 333 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 334 OS_INC_SRCDIR=config/${os_include_dir}
 335 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 336 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 337 AC_SUBST(ATOMICITY_SRCDIR)
 338 AC_SUBST(ATOMIC_WORD_SRCDIR)
 339 AC_SUBST(ATOMIC_FLAGS)
 340 AC_SUBST(CPU_DEFINES_SRCDIR)
 341 AC_SUBST(ABI_TWEAKS_SRCDIR)
 342 AC_SUBST(OS_INC_SRCDIR)
 343 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 344
 345
 346 # Determine cross-compile flags and AM_CONDITIONALs.
 347 #AC_SUBST(GLIBCXX_IS_NATIVE)
 348 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 349 GLIBCXX_EVALUATE_CONDITIONALS
 350
 351 AC_CACHE_SAVE
 352
 353 if test ${multilib} = yes; then
 354   multilib_arg="--enable-multilib"
 355 else
 356   multilib_arg=
 357 fi
 358
 359 # Export all the install information.
 360 GLIBCXX_EXPORT_INSTALL_INFO
 361
 362 # Export all the include and flag information to Makefiles.
 363 GLIBCXX_EXPORT_INCLUDES
 364 GLIBCXX_EXPORT_FLAGS
 365
 366 if test "$enable_shared" = yes; then
 367   LIBSUPCXX_PICFLAGS="-prefer-pic"
 368 else
 369   LIBSUPCXX_PICFLAGS=
 370 fi
 371 AC_SUBST(LIBSUPCXX_PICFLAGS)
 372
 373 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 374 dnl which can all be called multiple times as needed, plus one (different)
 375 dnl AC_OUTPUT macro.  This one lists the files to be created:
 376 AC_CONFIG_FILES(Makefile)
 377 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 378
 379 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 380 # that multilib installs will end up installed in the correct place.
 381 # The testsuite needs it for multilib-aware ABI baseline files.
 382 # To work around this not being passed down from config-ml.in ->
 383 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 384 # append it here.  Only modify Makefiles that have just been created.
 385 #
 386 # Also, get rid of this simulated-VPATH thing that automake does.
 387 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 388   [cat > vpsed$$ << \_EOF
 389 s!`test -f '$<' || echo '$(srcdir)/'`!!
 390 _EOF
 391    sed -f vpsed$$ $ac_file > tmp$$
 392    mv tmp$$ $ac_file
 393    rm vpsed$$
 394    echo 'MULTISUBDIR =' >> $ac_file
 395    ml_norecursion=yes
 396    . ${multi_basedir}/config-ml.in
 397    AS_UNSET([ml_norecursion])
 398 ])
 399
 400 AC_CONFIG_COMMANDS([generate-headers],
 401   [(cd include && ${MAKE-make} pch_build= )])
 402
 403 dnl And this actually makes things happen:
 404 AC_OUTPUT