m4/libevent.m4

   1 #
   2 # lldp_CHECK_LIBEVENT
   3 #
   4
   5 AC_DEFUN([lldp_CHECK_LIBEVENT], [
   6   # Do we require embedded libevent?
   7   AC_ARG_WITH([embedded-libevent],
   8     AS_HELP_STRING(
   9       [--with-embedded-libevent],
  10       [Force the use of embedded libevent @<:@default=no@:>@]
  11   ))
  12   if test x"$with_embedded_libevent" = x"yes"; then
  13      LIBEVENT_EMBEDDED=1
  14   else
  15     # If not forced, check first with pkg-config
  16     PKG_CHECK_MODULES([LIBEVENT], [libevent >= 2.0.5], [
  17        # Check if we have a working libevent
  18        AC_MSG_CHECKING([if system libevent works as expected])
  19        _save_CFLAGS="$CFLAGS"
  20        _save_LIBS="$LIBS"
  21        CFLAGS="$CFLAGS $LIBEVENT_CFLAGS"
  22        LIBS="$LIBS $LIBEVENT_LIBS"
  23        AC_TRY_LINK([
  24 @%:@include <sys/time.h>
  25 @%:@include <sys/types.h>
  26 @%:@include <event2/event.h>], [ struct event_base *base = event_base_new(); event_new(base, -1, 0, NULL, NULL); ],
  27        [
  28          AC_MSG_RESULT([yes])
  29        ], [
  30          AC_MSG_RESULT([no, using shipped libevent])
  31          LIBEVENT_EMBEDDED=1
  32        ])
  33        CFLAGS="$_save_CFLAGS"
  34        LIBS="$_save_LIBS"
  35     ], [
  36       # No appropriate version, let's use the shipped copy
  37       AC_MSG_NOTICE([using shipped libevent])
  38       LIBEVENT_EMBEDDED=1
  39     ])
  40   fi
  41
  42   if test x"$LIBEVENT_EMBEDDED" != x; then
  43     unset LIBEVENT_LIBS
  44     LIBEVENT_CFLAGS="-I\$(top_srcdir)/libevent/include -I\$(top_builddir)/libevent/include"
  45     LIBEVENT_LDFLAGS="\$(top_builddir)/libevent/libevent.la"
  46   fi
  47
  48   # Override configure arguments
  49   ac_configure_args="$ac_configure_args --disable-libevent-regress --disable-thread-support --disable-openssl"
  50   ac_configure_args="$ac_configure_args --disable-malloc-replacement --disable-debug-mode --enable-function-sections"
  51   ac_configure_args="$ac_configure_args --disable-shared --enable-static"
  52   AC_CONFIG_SUBDIRS([libevent])
  53   AM_CONDITIONAL([LIBEVENT_EMBEDDED], [test x"$LIBEVENT_EMBEDDED" != x])
  54   AC_SUBST([LIBEVENT_LIBS])
  55   AC_SUBST([LIBEVENT_CFLAGS])
  56   AC_SUBST([LIBEVENT_LDFLAGS])
  57 ])