proto/bgp/config.Y

   1 /*
   2  *      BIRD -- Border Gateway Protocol Configuration
   3  *
   4  *      (c) 2000 Martin Mares <mj@ucw.cz>
   5  *
   6  *      Can be freely distributed and used under the terms of the GNU GPL.
   7  */
   8
   9 CF_HDR
  10
  11 #include "proto/bgp/bgp.h"
  12
  13 CF_DEFINES
  14
  15 #define BGP_CFG ((struct bgp_config *) this_proto)
  16 #define BGP_CC ((struct bgp_channel_config *) this_channel)
  17
  18 CF_DECLS
  19
  20 CF_KEYWORDS(BGP, LOCAL, NEIGHBOR, AS, HOLD, TIME, CONNECT, RETRY, KEEPALIVE,
  21         MULTIHOP, STARTUP, VIA, NEXT, HOP, SELF, DEFAULT, PATH, METRIC, ERROR,
  22         START, DELAY, FORGET, WAIT, ENABLE, DISABLE, AFTER, BGP_PATH,
  23         BGP_LOCAL_PREF, BGP_MED, BGP_ORIGIN, BGP_NEXT_HOP, BGP_ATOMIC_AGGR,
  24         BGP_AGGREGATOR, BGP_COMMUNITY, BGP_EXT_COMMUNITY, BGP_LARGE_COMMUNITY,
  25         SOURCE, ADDRESS, PASSWORD, RR, RS, CLIENT, CLUSTER, ID, AS4, ADVERTISE,
  26         IPV4, CAPABILITIES, LIMIT, PASSIVE, PREFER, OLDER, MISSING, LLADDR,
  27         DROP, IGNORE, ROUTE, REFRESH, INTERPRET, COMMUNITIES, BGP_ORIGINATOR_ID,
  28         BGP_CLUSTER_LIST, IGP, TABLE, GATEWAY, DIRECT, RECURSIVE, MED, TTL,
  29         SECURITY, DETERMINISTIC, SECONDARY, ALLOW, BFD, ADD, PATHS, RX, TX,
  30         GRACEFUL, RESTART, AWARE, CHECK, LINK, PORT, EXTENDED, MESSAGES, SETKEY,
  31         STRICT, BIND, CONFEDERATION, MEMBER, MULTICAST, FLOW4, FLOW6)
  32
  33 %type <i32> bgp_afi
  34
  35 CF_GRAMMAR
  36
  37 CF_ADDTO(proto, bgp_proto '}' )
  38
  39 bgp_proto_start: proto_start BGP {
  40      this_proto = proto_config_new(&proto_bgp, $1);
  41      BGP_CFG->local_port = BGP_PORT;
  42      BGP_CFG->remote_port = BGP_PORT;
  43      BGP_CFG->multihop = -1;    /* undefined */
  44      BGP_CFG->hold_time = 240;
  45      BGP_CFG->initial_hold_time = 240;
  46      BGP_CFG->compare_path_lengths = 1;
  47      BGP_CFG->igp_metric = 1;
  48      BGP_CFG->connect_delay_time = 5;
  49      BGP_CFG->connect_retry_time = 120;
  50      BGP_CFG->error_amnesia_time = 300;
  51      BGP_CFG->error_delay_time_min = 60;
  52      BGP_CFG->error_delay_time_max = 300;
  53      BGP_CFG->enable_refresh = 1;
  54      BGP_CFG->enable_as4 = 1;
  55      BGP_CFG->capabilities = 2;
  56      BGP_CFG->interpret_communities = 1;
  57      BGP_CFG->default_local_pref = 100;
  58      BGP_CFG->gr_mode = BGP_GR_AWARE;
  59      BGP_CFG->gr_time = 120;
  60      BGP_CFG->setkey = 1;
  61    }
  62  ;
  63
  64 bgp_loc_opts:
  65    /* empty */
  66  | bgp_loc_opts PORT expr { BGP_CFG->local_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  67  | bgp_loc_opts AS expr { BGP_CFG->local_as = $3; }
  68  ;
  69
  70 bgp_nbr_opts:
  71    /* empty */
  72  | bgp_nbr_opts PORT expr { BGP_CFG->remote_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
  73  | bgp_nbr_opts AS expr { BGP_CFG->remote_as = $3; }
  74  ;
  75
  76 bgp_proto:
  77    bgp_proto_start proto_name '{'
  78  | bgp_proto proto_item ';'
  79  | bgp_proto bgp_proto_channel ';'
  80  | bgp_proto LOCAL bgp_loc_opts ';'
  81  | bgp_proto LOCAL ipa ipa_scope bgp_loc_opts ';' {
  82      BGP_CFG->local_ip = $3;
  83      if ($4) BGP_CFG->iface = $4;
  84    }
  85  | bgp_proto NEIGHBOR bgp_nbr_opts ';'
  86  | bgp_proto NEIGHBOR ipa ipa_scope bgp_nbr_opts ';' {
  87      if (ipa_nonzero(BGP_CFG->remote_ip))
  88        cf_error("Only one neighbor per BGP instance is allowed");
  89      BGP_CFG->remote_ip = $3;
  90      if ($4) BGP_CFG->iface = $4;
  91    }
  92  | bgp_proto INTERFACE TEXT ';' { BGP_CFG->iface = if_get_by_name($3); }
  93  | bgp_proto RR CLUSTER ID idval ';' { BGP_CFG->rr_cluster_id = $5; }
  94  | bgp_proto RR CLIENT bool ';' { BGP_CFG->rr_client = $4; }
  95  | bgp_proto RS CLIENT bool ';' { BGP_CFG->rs_client = $4; }
  96  | bgp_proto CONFEDERATION expr ';' { BGP_CFG->confederation = $3; }
  97  | bgp_proto CONFEDERATION MEMBER bool ';' { BGP_CFG->confederation_member = $4; }
  98  | bgp_proto HOLD TIME expr ';' { BGP_CFG->hold_time = $4; }
  99  | bgp_proto STARTUP HOLD TIME expr ';' { BGP_CFG->initial_hold_time = $5; }
 100  | bgp_proto DIRECT ';' { BGP_CFG->multihop = 0; }
 101  | bgp_proto MULTIHOP ';' { BGP_CFG->multihop = 64; }
 102  | bgp_proto MULTIHOP expr ';' { BGP_CFG->multihop = $3; if (($3<1) || ($3>255)) cf_error("Multihop must be in range 1-255"); }
 103  | bgp_proto STRICT BIND bool ';' { BGP_CFG->strict_bind = $4; }
 104  | bgp_proto PATH METRIC bool ';' { BGP_CFG->compare_path_lengths = $4; }
 105  | bgp_proto MED METRIC bool ';' { BGP_CFG->med_metric = $4; }
 106  | bgp_proto IGP METRIC bool ';' { BGP_CFG->igp_metric = $4; }
 107  | bgp_proto PREFER OLDER bool ';' { BGP_CFG->prefer_older = $4; }
 108  | bgp_proto DETERMINISTIC MED bool ';' { BGP_CFG->deterministic_med = $4; }
 109  | bgp_proto DEFAULT BGP_MED expr ';' { BGP_CFG->default_med = $4; }
 110  | bgp_proto DEFAULT BGP_LOCAL_PREF expr ';' { BGP_CFG->default_local_pref = $4; }
 111  | bgp_proto SOURCE ADDRESS ipa ';' { BGP_CFG->local_ip = $4; }
 112  | bgp_proto START DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; log(L_WARN "%s: Start delay time option is deprecated, use connect delay time", this_proto->name); }
 113  | bgp_proto CONNECT DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; }
 114  | bgp_proto CONNECT RETRY TIME expr ';' { BGP_CFG->connect_retry_time = $5; }
 115  | bgp_proto KEEPALIVE TIME expr ';' { BGP_CFG->keepalive_time = $4; }
 116  | bgp_proto ERROR FORGET TIME expr ';' { BGP_CFG->error_amnesia_time = $5; }
 117  | bgp_proto ERROR WAIT TIME expr ',' expr ';' { BGP_CFG->error_delay_time_min = $5; BGP_CFG->error_delay_time_max = $7; }
 118  | bgp_proto DISABLE AFTER ERROR bool ';' { BGP_CFG->disable_after_error = $5; }
 119  | bgp_proto ENABLE ROUTE REFRESH bool ';' { BGP_CFG->enable_refresh = $5; }
 120  | bgp_proto ENABLE AS4 bool ';' { BGP_CFG->enable_as4 = $4; }
 121  | bgp_proto ENABLE EXTENDED MESSAGES bool ';' { BGP_CFG->enable_extended_messages = $5; }
 122  | bgp_proto CAPABILITIES bool ';' { BGP_CFG->capabilities = $3; }
 123  | bgp_proto PASSWORD text ';' { BGP_CFG->password = $3; }
 124  | bgp_proto SETKEY bool ';' { BGP_CFG->setkey = $3; }
 125  | bgp_proto PASSIVE bool ';' { BGP_CFG->passive = $3; }
 126  | bgp_proto INTERPRET COMMUNITIES bool ';' { BGP_CFG->interpret_communities = $4; }
 127  | bgp_proto ALLOW LOCAL AS ';' { BGP_CFG->allow_local_as = -1; }
 128  | bgp_proto ALLOW LOCAL AS expr ';' { BGP_CFG->allow_local_as = $5; }
 129  | bgp_proto ALLOW BGP_LOCAL_PREF bool ';' { BGP_CFG->allow_local_pref = $4; }
 130  | bgp_proto GRACEFUL RESTART bool ';' { BGP_CFG->gr_mode = $4; }
 131  | bgp_proto GRACEFUL RESTART AWARE ';' { BGP_CFG->gr_mode = BGP_GR_AWARE; }
 132  | bgp_proto GRACEFUL RESTART TIME expr ';' { BGP_CFG->gr_time = $5; }
 133  | bgp_proto TTL SECURITY bool ';' { BGP_CFG->ttl_security = $4; }
 134  | bgp_proto CHECK LINK bool ';' { BGP_CFG->check_link = $4; }
 135  | bgp_proto BFD bool ';' { BGP_CFG->bfd = $3; cf_check_bfd($3); }
 136  ;
 137
 138 bgp_afi:
 139    IPV4                 { $$ = BGP_AF_IPV4; }
 140  | IPV6                 { $$ = BGP_AF_IPV6; }
 141  | IPV4 MULTICAST       { $$ = BGP_AF_IPV4_MC; }
 142  | IPV6 MULTICAST       { $$ = BGP_AF_IPV6_MC; }
 143  | IPV4 MPLS            { $$ = BGP_AF_IPV4_MPLS; }
 144  | IPV6 MPLS            { $$ = BGP_AF_IPV6_MPLS; }
 145  | VPN4 MPLS            { $$ = BGP_AF_VPN4_MPLS; }
 146  | VPN6 MPLS            { $$ = BGP_AF_VPN6_MPLS; }
 147  | VPN4 MULTICAST       { $$ = BGP_AF_VPN4_MC; }
 148  | VPN6 MULTICAST       { $$ = BGP_AF_VPN6_MC; }
 149  | FLOW4                { $$ = BGP_AF_FLOW4; }
 150  | FLOW6                { $$ = BGP_AF_FLOW6; }
 151  ;
 152
 153 bgp_channel_start: bgp_afi
 154 {
 155   const struct bgp_af_desc *desc = bgp_get_af_desc($1);
 156
 157   if (!desc)
 158     cf_error("Unknown AFI/SAFI");
 159
 160   this_channel = channel_config_new(&channel_bgp, desc->net, this_proto);
 161   BGP_CC->c.name = desc->name;
 162   BGP_CC->c.ra_mode = RA_UNDEF;
 163   BGP_CC->afi = $1;
 164   BGP_CC->desc = desc;
 165   BGP_CC->gr_able = 0xff;       /* undefined */
 166 };
 167
 168 bgp_channel_item:
 169    channel_item
 170  | NEXT HOP ADDRESS ipa { BGP_CC->next_hop_addr = $4; }
 171  | NEXT HOP SELF { BGP_CC->next_hop_self = 1; BGP_CC->next_hop_keep = 0; }
 172  | NEXT HOP KEEP { BGP_CC->next_hop_keep = 1; BGP_CC->next_hop_self = 0; }
 173  | MISSING LLADDR SELF { BGP_CC->missing_lladdr = MLL_SELF; }
 174  | MISSING LLADDR DROP { BGP_CC->missing_lladdr = MLL_DROP; }
 175  | MISSING LLADDR IGNORE { BGP_CC->missing_lladdr = MLL_IGNORE; }
 176  | GATEWAY DIRECT { BGP_CC->gw_mode = GW_DIRECT; }
 177  | GATEWAY RECURSIVE { BGP_CC->gw_mode = GW_RECURSIVE; }
 178  | SECONDARY bool { BGP_CC->secondary = $2; }
 179  | GRACEFUL RESTART bool { BGP_CC->gr_able = $3; }
 180  | EXTENDED NEXT HOP bool { BGP_CC->ext_next_hop = $4; }
 181  | ADD PATHS RX { BGP_CC->add_path = BGP_ADD_PATH_RX; }
 182  | ADD PATHS TX { BGP_CC->add_path = BGP_ADD_PATH_TX; }
 183  | ADD PATHS bool { BGP_CC->add_path = $3 ? BGP_ADD_PATH_FULL : 0; }
 184  | IGP TABLE rtable {
 185     if (BGP_CC->desc->no_igp)
 186       cf_error("IGP table not allowed here");
 187
 188     if ($3->addr_type == NET_IP4)
 189       BGP_CC->igp_table_ip4 = $3;
 190     else if ($3->addr_type == NET_IP6)
 191       BGP_CC->igp_table_ip6 = $3;
 192     else
 193       cf_error("Mismatched IGP table type");
 194    }
 195  ;
 196
 197 bgp_channel_opts:
 198    /* empty */
 199  | bgp_channel_opts bgp_channel_item ';'
 200  ;
 201
 202 bgp_channel_opt_list:
 203    /* empty */
 204  | '{' bgp_channel_opts '}'
 205  ;
 206
 207 bgp_channel_end:
 208 {
 209   if (!this_channel->table)
 210     cf_error("Routing table not specified");
 211
 212   this_channel = NULL;
 213 };
 214
 215 bgp_proto_channel: bgp_channel_start bgp_channel_opt_list bgp_channel_end;
 216
 217
 218 CF_ADDTO(dynamic_attr, BGP_ORIGIN
 219         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_ENUM_BGP_ORIGIN, EA_CODE(EAP_BGP, BA_ORIGIN)); })
 220 CF_ADDTO(dynamic_attr, BGP_PATH
 221         { $$ = f_new_dynamic_attr(EAF_TYPE_AS_PATH, T_PATH, EA_CODE(EAP_BGP, BA_AS_PATH)); })
 222 CF_ADDTO(dynamic_attr, BGP_NEXT_HOP
 223         { $$ = f_new_dynamic_attr(EAF_TYPE_IP_ADDRESS, T_IP, EA_CODE(EAP_BGP, BA_NEXT_HOP)); })
 224 CF_ADDTO(dynamic_attr, BGP_MED
 225         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(EAP_BGP, BA_MULTI_EXIT_DISC)); })
 226 CF_ADDTO(dynamic_attr, BGP_LOCAL_PREF
 227         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(EAP_BGP, BA_LOCAL_PREF)); })
 228 CF_ADDTO(dynamic_attr, BGP_ATOMIC_AGGR
 229         { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(EAP_BGP, BA_ATOMIC_AGGR)); })
 230 CF_ADDTO(dynamic_attr, BGP_AGGREGATOR
 231         { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(EAP_BGP, BA_AGGREGATOR)); })
 232 CF_ADDTO(dynamic_attr, BGP_COMMUNITY
 233         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(EAP_BGP, BA_COMMUNITY)); })
 234 CF_ADDTO(dynamic_attr, BGP_ORIGINATOR_ID
 235         { $$ = f_new_dynamic_attr(EAF_TYPE_ROUTER_ID, T_QUAD, EA_CODE(EAP_BGP, BA_ORIGINATOR_ID)); })
 236 CF_ADDTO(dynamic_attr, BGP_CLUSTER_LIST
 237         { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(EAP_BGP, BA_CLUSTER_LIST)); })
 238 CF_ADDTO(dynamic_attr, BGP_EXT_COMMUNITY
 239         { $$ = f_new_dynamic_attr(EAF_TYPE_EC_SET, T_ECLIST, EA_CODE(EAP_BGP, BA_EXT_COMMUNITY)); })
 240 CF_ADDTO(dynamic_attr, BGP_LARGE_COMMUNITY
 241         { $$ = f_new_dynamic_attr(EAF_TYPE_LC_SET, T_LCLIST, EA_CODE(EAP_BGP, BA_LARGE_COMMUNITY)); })
 242
 243
 244
 245 CF_ENUM(T_ENUM_BGP_ORIGIN, ORIGIN_, IGP, EGP, INCOMPLETE)
 246
 247 CF_CODE
 248
 249 CF_END