sysdeps/arm/setjmp.S

   1 /* setjmp for ARM.
   2    Copyright (C) 1997-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <stap-probe.h>
  21 #include <bits/setjmp.h>
  22 #include <rtld-global-offsets.h>
  23 #include <arm-features.h>
  24
  25 ENTRY (__sigsetjmp)
  26 #ifdef PTR_MANGLE
  27         PTR_MANGLE_LOAD (a3, ip)
  28 #endif
  29         mov     ip, r0
  30
  31         /* setjmp probe expects sigsetjmp first argument (4@r0), second
  32            argument (-4@r1), and target address (4@r14), respectively.  */
  33         LIBC_PROBE (setjmp, 3, 4@r0, -4@r1, 4@r14)
  34
  35         /* Save sp and lr */
  36 #ifdef PTR_MANGLE
  37         mov     a4, sp
  38         PTR_MANGLE2 (a4, a4, a3)
  39         str     a4, [ip], #4
  40         PTR_MANGLE2 (a4, lr, a3)
  41         str     a4, [ip], #4
  42 #else
  43         str     sp, [ip], #4
  44         str     lr, [ip], #4
  45 #endif
  46         /* Save registers */
  47         sfi_breg ip, \
  48         stmia   \B!, JMP_BUF_REGLIST
  49
  50 #if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
  51 # define NEED_HWCAP 1
  52 #endif
  53
  54 #ifdef NEED_HWCAP
  55         /* Check if we have a VFP unit.  */
  56 # ifdef IS_IN_rtld
  57         ldr     a3, 1f
  58         ldr     a4, .Lrtld_local_ro
  59 0:      add     a3, pc, a3
  60         add     a3, a3, a4
  61         ldr     a3, [a3, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  62 # else
  63 #  ifdef PIC
  64         ldr     a3, 1f
  65         ldr     a4, .Lrtld_global_ro
  66 0:      add     a3, pc, a3
  67         ldr     a3, [a3, a4]
  68         ldr     a3, [a3, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  69 #  else
  70         ldr     a3, .Lhwcap
  71         ldr     a3, [a3, #0]
  72 #  endif
  73 # endif
  74 #endif
  75
  76 #ifdef __SOFTFP__
  77         tst     a3, #HWCAP_ARM_VFP
  78         beq     .Lno_vfp
  79 #endif
  80
  81         /* Store the VFP registers.
  82            Don't use VFP instructions directly because this code
  83            is used in non-VFP multilibs.  */
  84         /* Following instruction is vstmia ip!, {d8-d15}.  */
  85         sfi_breg ip, \
  86         stc     p11, cr8, [\B], #64
  87 .Lno_vfp:
  88
  89 #ifndef ARM_ASSUME_NO_IWMMXT
  90         tst     a3, #HWCAP_ARM_IWMMXT
  91         beq     .Lno_iwmmxt
  92
  93         /* Save the call-preserved iWMMXt registers.  */
  94         /* Following instructions are wstrd wr10, [ip], #8 (etc.)  */
  95         sfi_breg r12, \
  96         stcl    p1, cr10, [\B], #8
  97         sfi_breg r12, \
  98         stcl    p1, cr11, [\B], #8
  99         sfi_breg r12, \
 100         stcl    p1, cr12, [\B], #8
 101         sfi_breg r12, \
 102         stcl    p1, cr13, [\B], #8
 103         sfi_breg r12, \
 104         stcl    p1, cr14, [\B], #8
 105         sfi_breg r12, \
 106         stcl    p1, cr15, [\B], #8
 107 .Lno_iwmmxt:
 108 #endif
 109
 110         /* Make a tail call to __sigjmp_save; it takes the same args.  */
 111         B       PLTJMP(C_SYMBOL_NAME(__sigjmp_save))
 112
 113 #ifdef NEED_HWCAP
 114 # ifdef IS_IN_rtld
 115 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - PC_OFS
 116 .Lrtld_local_ro:
 117         .long   C_SYMBOL_NAME(_rtld_local_ro)(GOTOFF)
 118 # else
 119 #  ifdef PIC
 120 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - PC_OFS
 121 .Lrtld_global_ro:
 122         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
 123 #  else
 124 .Lhwcap:
 125         .long   C_SYMBOL_NAME(_dl_hwcap)
 126 #  endif
 127 # endif
 128 #endif
 129
 130 END (__sigsetjmp)
 131
 132 hidden_def (__sigsetjmp)