sysdeps/gnu/errlist.awk

   1 # Copyright (C) 1991, 92, 93, 94, 95, 96 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Library General Public License
   6 # as published by the Free Software Foundation; either version 2 of
   7 # the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Library General Public License for more details.
  13
  14 # You should have received a copy of the GNU Library General Public
  15 # License along with the GNU C Library; see the file COPYING.LIB.  If
  16 # not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17 # Cambridge, MA 02139, USA.
  18
  19 # errno.texinfo contains lines like:
  20 # @comment errno.h
  21 # @comment POSIX.1: Function not implemented
  22 # @deftypevr Macro int ENOSYS
  23 # @comment errno 78
  24
  25 BEGIN {
  26     alias["EWOULDBLOCK"] = "EAGAIN";
  27     alias["EDEADLOCK"] = "EDEADLK";
  28
  29     print "/* This file is generated from errno.texi by errlist.awk.  */"
  30     print "";
  31     print "#include <errno.h>";
  32     print "";
  33     print "const char *_sys_errlist[] =";
  34     print "  {";
  35     print "    [0] = N_(\"Success\"),"
  36   }
  37 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  38 errnoh == 1 && $1 == "@comment" \
  39   {
  40     ++errnoh;
  41     etext = $3;
  42     for (i = 4; i <= NF; ++i)
  43       etext = etext " " $i;
  44     next;
  45   }
  46 errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
  47   {
  48     e = $4; errnoh++; next;
  49   }
  50 errnoh == 3 && $1 == "@comment" && $2 == "errno" \
  51   {
  52     errno = $3 + 0;
  53     if (alias[e])
  54       printf "#if defined (%s) && %s != %s\n", e, e, alias[e];
  55     else
  56       printf "#ifdef %s\n", e;
  57     printf "    [%s] = N_(\"%s\"),\n", e, etext;
  58     print "#endif";
  59     next;
  60   }
  61 { errnoh=0 }
  62 END {
  63   print "  };";
  64   print "";
  65   print "const int _sys_nerr = sizeof _sys_errlist / sizeof _sys_errlist[0];";
  66   print "weak_alias (_sys_errlist, sys_errlist)";
  67   print "weak_alias (_sys_nerr, sys_nerr)";
  68   }