sysdeps/i386/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2 # Local configure fragment for sysdeps/i386.
   3
   4 # We no longer support i386 since it lacks the atomic instructions
   5 # required to implement NPTL threading.
   6 if test "$config_machine" = i386; then
   7   AC_MSG_ERROR([
   8 *** ERROR: Support for i386 is deprecated.
   9 *** Please use host i786, i686, i585 or i486.
  10 *** For example: /src/glibc/configure --host=i686-pc-linux-gnu ..."])
  11 fi
  12
  13 # The GNU C Library can't be built for i386.  There are several reasons for
  14 # this restriction.  The primary reason is that i386 lacks the atomic
  15 # operations required to support the current NPTL implementation.  While it is
  16 # possible that such atomic operations could be emulated in the kernel to date
  17 # no such work has been done to enable this.  Even with NPTL disabled you still
  18 # have no atomic.h implementation.  Given the declining use of i386 we disable
  19 # support for building with `-march=i386' or `-mcpu=i386.' We don't explicitly
  20 # check for i386, instead we make sure the compiler has support for inlining
  21 # the builtin __sync_val_compare_and_swap. If it does then we should have no
  22 # problem building for i386.
  23 LIBC_COMPILER_BUILTIN_INLINED(
  24   [__sync_val_compare_and_swap],
  25   [int a, b, c; __sync_val_compare_and_swap (&a, b, c);],
  26   [-O0],
  27   [libc_cv_unsupported_i386=no],
  28   [AC_MSG_ERROR([
  29 *** Building with -march=i386/-mcpu=i386 is not supported.
  30 *** Please use host i786, i686, i586, or i486.
  31 *** For example: /source/glibc/configure CFLAGS='-O2 -march=i686' ...])])
  32
  33 AC_CHECK_HEADER([cpuid.h], ,
  34   [AC_MSG_ERROR([gcc must provide the <cpuid.h> header])],
  35   [/* No default includes.  */])
  36
  37 dnl Check if -Wa,-mtune=i686 works.
  38 AC_CACHE_CHECK(for assembler -mtune=i686 support, libc_cv_as_i686, [dnl
  39 LIBC_TRY_CC_OPTION([-Wa,-mtune=i686],
  40                    [libc_cv_as_i686=yes],
  41                    [libc_cv_as_i686=no])
  42 ])
  43 LIBC_CONFIG_VAR([config-asflags-i686], [$libc_cv_as_i686])
  44
  45 dnl Check if -mfma4 works.
  46 AC_CACHE_CHECK(for FMA4 support, libc_cv_cc_fma4, [dnl
  47 LIBC_TRY_CC_OPTION([-mfma4], [libc_cv_cc_fma4=yes], [libc_cv_cc_fma4=no])
  48 ])
  49 if test $libc_cv_cc_fma4 = yes; then
  50   AC_DEFINE(HAVE_FMA4_SUPPORT)
  51 fi
  52 LIBC_CONFIG_VAR([have-mfma4], [$libc_cv_cc_fma4])
  53
  54 dnl Check if -mno-vzeroupper works.
  55 AC_CACHE_CHECK(for -mno-vzeroupper support, libc_cv_cc_novzeroupper, [dnl
  56 LIBC_TRY_CC_OPTION([-mno-vzeroupper],
  57                    [libc_cv_cc_novzeroupper=yes],
  58                    [libc_cv_cc_novzeroupper=no])
  59 ])
  60 LIBC_CONFIG_VAR([config-cflags-novzeroupper], [$libc_cv_cc_novzeroupper])
  61
  62 dnl Check whether asm supports Intel MPX
  63 AC_CACHE_CHECK(for Intel MPX support, libc_cv_asm_mpx, [dnl
  64 cat > conftest.s <<\EOF
  65         bndmov %bnd0,(%esp)
  66 EOF
  67 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
  68   libc_cv_asm_mpx=yes
  69 else
  70   libc_cv_asm_mpx=no
  71 fi
  72 rm -f conftest*])
  73 if test $libc_cv_asm_mpx == yes; then
  74   AC_DEFINE(HAVE_MPX_SUPPORT)
  75 fi
  76
  77 dnl Check if -mavx2 works.
  78 AC_CACHE_CHECK(for AVX2 support, libc_cv_cc_avx2, [dnl
  79 LIBC_TRY_CC_OPTION([-mavx2], [libc_cv_cc_avx2=yes], [libc_cv_cc_avx2=no])
  80 ])
  81 if test $libc_cv_cc_avx2 = yes; then
  82   AC_DEFINE(HAVE_AVX2_SUPPORT)
  83 fi
  84 LIBC_CONFIG_VAR([config-cflags-avx2], [$libc_cv_cc_avx2])
  85
  86 AC_DEFINE(USE_REGPARMS)
  87
  88 dnl It is always possible to access static and hidden symbols in an
  89 dnl position independent way.
  90 AC_DEFINE(PI_STATIC_AND_HIDDEN)