sysdeps/i386/fpu/e_hypotf.S

   1 /* Compute the hypothenuse of X and Y.
   2    Copyright (C) 1998-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1998.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <i386-math-asm.h>
  22
  23         .text
  24 ENTRY(__ieee754_hypotf)
  25         flds    4(%esp)         // x
  26         fxam
  27         fnstsw
  28         flds    8(%esp)         // y : x
  29         movb    %ah, %ch
  30         fxam
  31         fnstsw
  32         movb    %ah, %al
  33         orb     %ch, %ah
  34         sahf
  35         jc      1f
  36         fmul    %st(0)          // y * y : x
  37         fxch                    // x : y * y
  38         fmul    %st(0)          // x * x : y * y
  39         faddp                   // x * x + y * y
  40         fsqrt
  41         FLT_NARROW_EVAL
  42 2:      ret
  43
  44         // We have to test whether any of the parameters is Inf.
  45         // In this case the result is infinity.
  46 1:      andb    $0x45, %al
  47         cmpb    $5, %al
  48         je      3f              // jump if y is Inf
  49         andb    $0x45, %ch
  50         cmpb    $5, %ch
  51         jne     4f              // jump if x is not Inf
  52         fxch
  53 3:      fstp    %st(1)
  54         fabs
  55         jmp     2b
  56
  57 4:      testb   $1, %al
  58         jnz     5f              // y is NaN
  59         fxch
  60 5:      fstp    %st(1)
  61         jmp     2b
  62
  63 END(__ieee754_hypotf)
  64 strong_alias (__ieee754_hypotf, __hypotf_finite)