sysdeps/i386/fpu/s_fminl.S

   1 /* Compute minimum of two numbers, regarding NaN as missing argument.
   2    Copyright (C) 1997-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <libm-alias-ldouble.h>
  21 #include <sysdep.h>
  22
  23         .text
  24 ENTRY(__fminl)
  25         fldt    16(%esp)        // y
  26         fxam
  27         fnstsw
  28         fldt    4(%esp)         // y : x
  29
  30         andb    $0x45, %ah
  31         cmpb    $0x01, %ah
  32         je      2f              // y == NaN
  33
  34         fxam
  35         fnstsw
  36         andb    $0x45, %ah
  37         cmpb    $0x01, %ah
  38         je      3f              // x == NaN
  39
  40         fucom   %st(1)
  41         fnstsw
  42         sahf
  43         jc      1f
  44
  45         fxch    %st(1)
  46 1:      fstp    %st(1)
  47
  48         ret
  49
  50 2:      // st(1) is a NaN; st(0) may or may not be.
  51         fxam
  52         fnstsw
  53         andb    $0x45, %ah
  54         cmpb    $0x01, %ah
  55         je      4f
  56         // st(1) is a NaN; st(0) is not.  Test if st(1) is signaling.
  57         testb   $0x40, 23(%esp)
  58         jz      4f
  59         fstp    %st(1)
  60         ret
  61
  62 3:      // st(0) is a NaN; st(1) is not.  Test if st(0) is signaling.
  63         testb   $0x40, 11(%esp)
  64         jz      4f
  65         fstp    %st(0)
  66         ret
  67
  68 4:      // Both arguments are NaNs, or one is a signaling NaN.
  69         faddp
  70         ret
  71 END(__fminl)
  72 libm_alias_ldouble (__fmin, fmin)