sysdeps/i386/fpu/s_frexpf.S

   1 /* ix87 specific frexp implementation for float.
   2    Copyright (C) 1997, 2000, 2005, 2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21 #include "bp-sym.h"
  22 #include "bp-asm.h"
  23
  24         .section .rodata
  25
  26         .align ALIGNARG(4)
  27         .type two25,@object
  28 two25:  .byte 0, 0, 0, 0x4c
  29         ASM_SIZE_DIRECTIVE(two25)
  30
  31 #ifdef PIC
  32 #define MO(op) op##@GOTOFF(%edx)
  33 #else
  34 #define MO(op) op
  35 #endif
  36
  37 #define PARMS   LINKAGE         /* no space for saved regs */
  38 #define VAL     PARMS
  39 #define EXPP    VAL+4
  40
  41         .text
  42 ENTRY (BP_SYM (__frexpf))
  43         ENTER
  44
  45         movl    VAL(%esp), %eax
  46         xorl    %ecx, %ecx
  47         movl    %eax, %edx
  48         andl    $0x7fffffff, %eax
  49         jz      1f
  50         cmpl    $0x7f800000, %eax
  51         jae     1f
  52
  53         cmpl    $0x00800000, %eax
  54         jae     2f
  55
  56         flds    VAL(%esp)
  57 #ifdef  PIC
  58         LOAD_PIC_REG (dx)
  59 #endif
  60         fmuls   MO(two25)
  61         movl    $-25, %ecx
  62         fstps   VAL(%esp)
  63         fwait
  64         movl    VAL(%esp), %eax
  65         movl    %eax, %edx
  66         andl    $0x7fffffff, %eax
  67
  68 2:      shrl    $23, %eax
  69         andl    $0x807fffff, %edx
  70         subl    $126, %eax
  71         orl     $0x3f000000, %edx
  72         addl    %eax, %ecx
  73         movl    %edx, VAL(%esp)
  74
  75         /* Store %ecx in the variable pointed to by the second argument,
  76            get the factor from the stack and return.  */
  77 1:      movl    EXPP(%esp), %eax
  78         CHECK_BOUNDS_BOTH_WIDE (%eax, EXPP(%esp), $4)
  79         flds    VAL(%esp)
  80         movl    %ecx, (%eax)
  81
  82         LEAVE
  83         ret
  84 END (BP_SYM (__frexpf))
  85 weak_alias (BP_SYM (__frexpf), BP_SYM (frexpf))