sysdeps/i386/i386-mcount.S

   1 /* i386-specific implementation of profiling support.
   2    Copyright (C) 1997-2021 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <https://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22 /* We need a special version of the `mcount' function since for ix86 it
  23    must not clobber any register.  This has several reasons:
  24      - there is a bug in gcc as of version 2.7.2.2 which prohibits the
  25        use of profiling together with nested functions
  26      - the ELF `fixup' function uses GCC's regparm feature
  27      - some (future) systems might want to pass parameters in registers.  */
  28
  29         .globl C_SYMBOL_NAME(_mcount)
  30         .type C_SYMBOL_NAME(_mcount), @function
  31         .align ALIGNARG(4)
  32 C_LABEL(_mcount)
  33         _CET_ENDBR
  34         /* Save the caller-clobbered registers.  */
  35         pushl %eax
  36         pushl %ecx
  37         pushl %edx
  38
  39         movl 12(%esp), %edx
  40         movl 4(%ebp), %eax
  41
  42         /* No need to access the PLT or GOT, __mcount_internal is an
  43            internal function and we can make a relative call.  */
  44         call C_SYMBOL_NAME(__mcount_internal)
  45
  46         /* Pop the saved registers.  Please note that `mcount' has no
  47            return value.  */
  48         popl %edx
  49         popl %ecx
  50         popl %eax
  51         ret
  52         ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(_mcount))
  53
  54 #undef mcount
  55 weak_alias (_mcount, mcount)
  56
  57         /* Same as above, but doesn't require a frame pointer */
  58         .globl C_SYMBOL_NAME(__fentry__)
  59         .type C_SYMBOL_NAME(__fentry__), @function
  60         .align ALIGNARG(4)
  61 C_LABEL(__fentry__)
  62         _CET_ENDBR
  63         /* Save the caller-clobbered registers.  */
  64         pushl %eax
  65         pushl %ecx
  66         pushl %edx
  67
  68         movl 12(%esp), %edx
  69         movl 16(%esp), %eax
  70
  71         /* No need to access the PLT or GOT, __mcount_internal is an
  72            internal function and we can make a relative call.  */
  73         call C_SYMBOL_NAME(__mcount_internal)
  74
  75         /* Pop the saved registers.  Please note that `__fentry__' has no
  76            return value.  */
  77         popl %edx
  78         popl %ecx
  79         popl %eax
  80         ret
  81         ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(__fentry__))