sysdeps/i386/i586/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2 Highly optimized version for ix85, x>=5.
   3 Copyright (C) 1996 Free Software Foundation, Inc.
   4 This file is part of the GNU C Library.
   5 Contributed by Torbjorn Granlund, <tege@matematik.su.se>
   6
   7 The GNU C Library is free software; you can redistribute it and/or
   8 modify it under the terms of the GNU Library General Public License as
   9 published by the Free Software Foundation; either version 2 of the
  10 License, or (at your option) any later version.
  11
  12 The GNU C Library is distributed in the hope that it will be useful,
  13 but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 Library General Public License for more details.
  16
  17 You should have received a copy of the GNU Library General Public
  18 License along with the GNU C Library; see the file COPYING.LIB.  If
  19 not, write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 Boston, MA 02111-1307, USA.  */
  21
  22 #include <sysdep.h>
  23
  24 /*
  25    INPUT PARAMETERS:
  26    (memset)                     (bzero)
  27    dst          (sp + 4)        dst     (sp + 4)
  28    ch           (sp + 8)        len     (sp + 8)
  29    len          (sp + 12)
  30 */
  31
  32
  33         .text
  34 ENTRY (memset)
  35         pushl   %edi
  36
  37         movl    8(%esp), %edi   /* destination pointer */
  38 #ifdef memset
  39         xorl    %eax, %eax      /* we fill with 0 */
  40         movl    12(%esp), %edx  /* size (in 8-bit words) */
  41 #else
  42         movb    12(%esp), %al   /* use CH to fill */
  43         movl    16(%esp), %edx  /* size (in 8-bit words) */
  44
  45         movb    %al, %ah
  46         movl    %eax, %ecx
  47         shll    $16, %eax
  48         movw    %cx, %ax
  49 #endif
  50         cld
  51
  52 /* If less than 36 bytes to write, skip tricky code (it wouldn't work).  */
  53         cmpl    $36, %edx
  54         movl    %edx, %ecx      /* needed when branch is taken! */
  55         jl      L2
  56
  57 /* First write 0-3 bytes to make the pointer 32-bit aligned.  */
  58         movl    %edi, %ecx      /* Copy ptr to ecx... */
  59         negl    %ecx            /* ...and negate that and... */
  60         andl    $3, %ecx        /* ...mask to get byte count.  */
  61         subl    %ecx, %edx      /* adjust global byte count */
  62         rep
  63         stosb
  64
  65         subl    $32, %edx       /* offset count for unrolled loop */
  66         movl    (%edi), %ecx    /* Fetch destination cache line */
  67
  68         .align  2, 0x90         /* supply 0x90 for broken assemblers */
  69 L1:     movl    28(%edi), %ecx  /* allocate cache line for destination */
  70         subl    $32, %edx       /* decr loop count */
  71         movl    %eax, 0(%edi)   /* store words pairwise */
  72         movl    %eax, 4(%edi)
  73         movl    %eax, 8(%edi)
  74         movl    %eax, 12(%edi)
  75         movl    %eax, 16(%edi)
  76         movl    %eax, 20(%edi)
  77         movl    %eax, 24(%edi)
  78         movl    %eax, 28(%edi)
  79         leal    32(%edi), %edi  /* update destination pointer */
  80         jge     L1
  81
  82         leal    32(%edx), %ecx  /* reset offset count */
  83
  84 /* Write last 0-7 full 32-bit words (up to 8 words if loop was skipped).  */
  85 L2:     shrl    $2, %ecx        /* convert byte count to longword count */
  86         rep
  87         stosl
  88
  89 /* Finally write the last 0-3 bytes.  */
  90         movl    %edx, %ecx
  91         andl    $3, %ecx
  92         rep
  93         stosb
  94
  95         /* Load result (only if used as memset).  */
  96 #ifndef memset
  97         movl    8(%esp), %eax
  98 #endif
  99         popl    %edi
 100
 101         ret