sysdeps/i386/i686/mempcpy.S

   1 /* Copy memory block and return pointer to following byte.
   2    For Intel 80x86, x>=6.
   3    This file is part of the GNU C Library.
   4    Copyright (C) 1998-2021 Free Software Foundation, Inc.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <https://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include "asm-syntax.h"
  22
  23 #define PARMS   4               /* no space for saved regs */
  24 #define RTN     PARMS
  25 #define DEST    RTN
  26 #define SRC     DEST+4
  27 #define LEN     SRC+4
  28
  29         .text
  30 #if defined PIC && IS_IN (libc)
  31 ENTRY_CHK (__mempcpy_chk)
  32         movl    12(%esp), %eax
  33         cmpl    %eax, 16(%esp)
  34         jb      HIDDEN_JUMPTARGET (__chk_fail)
  35 END_CHK (__mempcpy_chk)
  36 #endif
  37 ENTRY (__mempcpy)
  38
  39         movl    LEN(%esp), %ecx
  40         movl    %edi, %eax
  41         cfi_register (edi, eax)
  42         movl    DEST(%esp), %edi
  43         movl    %esi, %edx
  44         cfi_register (esi, edx)
  45         movl    SRC(%esp), %esi
  46         cld
  47         shrl    $1, %ecx
  48         jnc     1f
  49         movsb
  50 1:      shrl    $1, %ecx
  51         jnc     2f
  52         movsw
  53 2:      rep
  54         movsl
  55         xchgl   %edi, %eax
  56         cfi_restore (edi)
  57         movl    %edx, %esi
  58         cfi_restore (esi)
  59
  60         ret
  61 END (__mempcpy)
  62 libc_hidden_def (__mempcpy)
  63 weak_alias (__mempcpy, mempcpy)
  64 libc_hidden_builtin_def (mempcpy)