sysdeps/ia64/fpu/s_ceilf.S

   1 .file "ceilf.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  39 //
  40 // History
  41 //==============================================================
  42 // 02/02/00 Initial version
  43 // 06/13/00 Improved speed
  44 // 06/27/00 Eliminated incorrect invalid flag setting
  45 // 05/20/02 Cleaned up namespace and sf0 syntax
  46 // 01/28/03 Improved performance
  47 //==============================================================
  48
  49 // API
  50 //==============================================================
  51 // float ceilf(float x)
  52 //==============================================================
  53
  54 // general input registers:
  55 // r14 - r19
  56
  57 rSignexp   = r14
  58 rExp       = r15
  59 rExpMask   = r16
  60 rBigexp    = r17
  61 rM1        = r18
  62 rSignexpM1 = r19
  63
  64 // floating-point registers:
  65 // f8 - f13
  66
  67 fXInt      = f9
  68 fNormX     = f10
  69 fTmp       = f11
  70 fAdj       = f12
  71 fPreResult = f13
  72
  73 // predicate registers used:
  74 // p6 - p10
  75
  76 // Overview of operation
  77 //==============================================================
  78 // float ceilf(float x)
  79 // Return an integer value (represented as a float) that is the smallest
  80 // value not less than x
  81 // This is x rounded toward +infinity to an integral value.
  82 // Inexact is set if x != ceilf(x)
  83 //==============================================================
  84
  85 // double_extended
  86 // if the exponent is > 1003e => 3F(true) = 63(decimal)
  87 // we have a significand of 64 bits 1.63-bits.
  88 // If we multiply by 2^63, we no longer have a fractional part
  89 // So input is an integer value already.
  90
  91 // double
  92 // if the exponent is >= 10033 => 34(true) = 52(decimal)
  93 // 34 + 3ff = 433
  94 // we have a significand of 53 bits 1.52-bits. (implicit 1)
  95 // If we multiply by 2^52, we no longer have a fractional part
  96 // So input is an integer value already.
  97
  98 // single
  99 // if the exponent is > 10016 => 17(true) = 23(decimal)
 100 // we have a significand of 24 bits 1.23-bits. (implicit 1)
 101 // If we multiply by 2^23, we no longer have a fractional part
 102 // So input is an integer value already.
 103
 104
 105 .section .text
 106 GLOBAL_LIBM_ENTRY(ceilf)
 107
 108 { .mfi
 109       getf.exp         rSignexp  = f8        // Get signexp, recompute if unorm
 110       fclass.m         p7,p0 = f8, 0x0b      // Test x unorm
 111       addl             rBigexp = 0x10016, r0 // Set exponent at which is integer
 112 }
 113 { .mfi
 114       mov              rM1 = -1              // Set all ones
 115       fcvt.fx.trunc.s1 fXInt  = f8           // Convert to int in significand
 116       mov              rExpMask    = 0x1FFFF // Form exponent mask
 117 }
 118 ;;
 119
 120 { .mfi
 121       mov              rSignexpM1  = 0x2FFFF // Form signexp of -1
 122       fcmp.lt.s1       p8,p9 = f8, f0        // Test x < 0
 123       nop.i            0
 124 }
 125 { .mfb
 126       setf.sig         fTmp = rM1            // Make const for setting inexact
 127       fnorm.s1         fNormX  = f8          // Normalize input
 128 (p7)  br.cond.spnt     CEIL_UNORM            // Branch if x unorm
 129 }
 130 ;;
 131
 132 CEIL_COMMON:
 133 // Return here from CEIL_UNORM
 134 { .mfi
 135       nop.m            0
 136       fclass.m         p6,p0 = f8, 0x1e7     // Test x natval, nan, inf, 0
 137       nop.i            0
 138 }
 139 ;;
 140
 141 .pred.rel "mutex",p8,p9
 142 { .mfi
 143       nop.m            0
 144 (p8)  fma.s1           fAdj = f0, f0, f0     // If x < 0, adjustment is 0
 145       nop.i            0
 146 }
 147 { .mfi
 148       nop.m            0
 149 (p9)  fma.s1           fAdj = f1, f1, f0     // If x > 0, adjustment is +1
 150       nop.i            0
 151 }
 152 ;;
 153
 154 { .mfi
 155       nop.m            0
 156       fcvt.xf          fPreResult = fXInt    // trunc(x)
 157       nop.i            0
 158 }
 159 { .mfb
 160       nop.m            0
 161 (p6)  fma.s.s0         f8 = f8, f1, f0       // Result if x natval, nan, inf, 0
 162 (p6)  br.ret.spnt      b0                    // Exit if x natval, nan, inf, 0
 163 }
 164 ;;
 165
 166 { .mmi
 167       and              rExp = rSignexp, rExpMask // Get biased exponent
 168 ;;
 169       cmp.ge           p7,p6 = rExp, rBigexp  // Is |x| >= 2^23?
 170 (p8)  cmp.lt.unc       p10,p0 = rSignexp, rSignexpM1 // Is -1 < x < 0?
 171 }
 172 ;;
 173
 174 // If -1 < x < 0, we turn off p6 and compute result as -0
 175 { .mfi
 176 (p10) cmp.ne           p6,p0 = r0,r0
 177 (p10) fmerge.s         f8 = fNormX, f0
 178       nop.i            0
 179 }
 180 ;;
 181
 182 .pred.rel "mutex",p6,p7
 183 { .mfi
 184       nop.m            0
 185 (p6)  fma.s.s0         f8 = fPreResult, f1, fAdj // Result if !int, |x| < 2^23
 186       nop.i            0
 187 }
 188 { .mfi
 189       nop.m            0
 190 (p7)  fma.s.s0         f8 = fNormX, f1, f0    // Result, if |x| >= 2^23
 191 (p10) cmp.eq           p6,p0 = r0,r0          // If -1 < x < 0, turn on p6 again
 192 }
 193 ;;
 194
 195 { .mfi
 196       nop.m            0
 197 (p6)  fcmp.eq.unc.s1   p8, p9 = fPreResult, fNormX // Is trunc(x) = x ?
 198       nop.i            0
 199 }
 200 ;;
 201
 202 { .mfi
 203       nop.m            0
 204 (p9)  fmpy.s0          fTmp = fTmp, fTmp      // Dummy to set inexact
 205       nop.i            0
 206 }
 207 { .mfb
 208       nop.m            0
 209 (p8)  fma.s.s0         f8 = fNormX, f1, f0    // If x int, result normalized x
 210       br.ret.sptk      b0                     // Exit main path, 0 < |x| < 2^23
 211 }
 212 ;;
 213
 214
 215 CEIL_UNORM:
 216 // Here if x unorm
 217 { .mfb
 218       getf.exp         rSignexp  = fNormX     // Get signexp, recompute if unorm
 219       fcmp.eq.s0       p7,p0 = f8, f0         // Dummy op to set denormal flag
 220       br.cond.sptk     CEIL_COMMON            // Return to main path
 221 }
 222 ;;
 223
 224 GLOBAL_LIBM_END(ceilf)