sysdeps/ia64/fpu/s_log1pl.S

   1 .file "log1pl.s"
   2
   3 // Copyright (C) 2000, 2001, Intel Corporation
   4 // All rights reserved.
   5 //
   6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
   7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23 //
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://developer.intel.com/opensource.
  39 //
  40 // *********************************************************************
  41 //
  42 // History:
  43 // 2/02/00  hand-optimized
  44 // 4/04/00  Unwind support added
  45 // 8/15/00  Bundle added after call to __libm_error_support to properly
  46 //          set [the previously overwritten] GR_Parameter_RESULT.
  47 //
  48 // *********************************************************************
  49 //
  50 // *********************************************************************
  51 //
  52 // Function:   Combined logl(x), log1pl(x), and log10l(x) where
  53 //             logl(x)   = ln(x), for double-extended precision x values
  54 //             log1pl(x) = ln(x+1), for double-extended precision x values
  55 //             log10l(x) = log (x), for double-extended precision x values
  56 //                           10
  57 //
  58 // *********************************************************************
  59 //
  60 // Resources Used:
  61 //
  62 //    Floating-Point Registers: f8 (Input and Return Value)
  63 //                              f9,f33-f55,f99
  64 //
  65 //    General Purpose Registers:
  66 //      r32-r53
  67 //      r54-r57 (Used to pass arguments to error handling routine)
  68 //
  69 //    Predicate Registers:      p6-p15
  70 //
  71 // *********************************************************************
  72 //
  73 // IEEE Special Conditions:
  74 //
  75 //    Denormal  fault raised on denormal inputs
  76 //    Overflow exceptions cannot occur
  77 //    Underflow exceptions raised when appropriate for log1p
  78 //    (Error Handling Routine called for underflow)
  79 //    Inexact raised when appropriate by algorithm
  80 //
  81 //    logl(inf) = inf
  82 //    logl(-inf) = QNaN
  83 //    logl(+/-0) = -inf
  84 //    logl(SNaN) = QNaN
  85 //    logl(QNaN) = QNaN
  86 //    logl(EM_special Values) = QNaN
  87 //    log1pl(inf) = inf
  88 //    log1pl(-inf) = QNaN
  89 //    log1pl(+/-0) = +/-0
  90 //    log1pl(-1) =  -inf
  91 //    log1pl(SNaN) = QNaN
  92 //    log1pl(QNaN) = QNaN
  93 //    log1pl(EM_special Values) = QNaN
  94 //    log10l(inf) = inf
  95 //    log10l(-inf) = QNaN
  96 //    log10l(+/-0) = -inf
  97 //    log10l(SNaN) = QNaN
  98 //    log10l(QNaN) = QNaN
  99 //    log10l(EM_special Values) = QNaN
 100 //
 101 // *********************************************************************
 102 //
 103 // Computation is based on the following kernel.
 104 //
 105 // ker_log_64( in_FR    :  X,
 106 //          in_FR    :  E,
 107 //          in_FR    :  Em1,
 108 //          in_GR    :  Expo_Range,
 109 //          out_FR   :  Y_hi,
 110 //          out_FR   :  Y_lo,
 111 //          out_FR   :  Scale,
 112 //          out_PR   :  Safe  )
 113 //
 114 // Overview
 115 //
 116 // The method consists of three cases.
 117 //
 118 // If   |X+Em1| < 2^(-80)       use case log1pl_small;
 119 // elseif       |X+Em1| < 2^(-7)        use case log_near1;
 120 // else                         use case log_regular;
 121 //
 122 // Case log1pl_small:
 123 //
 124 // logl( 1 + (X+Em1) ) can be approximated by (X+Em1).
 125 //
 126 // Case log_near1:
 127 //
 128 //   logl( 1 + (X+Em1) ) can be approximated by a simple polynomial
 129 //   in W = X+Em1. This polynomial resembles the truncated Taylor
 130 //   series W - W^/2 + W^3/3 - ...
 131 //
 132 // Case log_regular:
 133 //
 134 //   Here we use a table lookup method. The basic idea is that in
 135 //   order to compute logl(Arg) for an argument Arg in [1,2), we
 136 //   construct a value G such that G*Arg is close to 1 and that
 137 //   logl(1/G) is obtainable easily from a table of values calculated
 138 //   beforehand. Thus
 139 //
 140 //      logl(Arg) = logl(1/G) + logl(G*Arg)
 141 //               = logl(1/G) + logl(1 + (G*Arg - 1))
 142 //
 143 //   Because |G*Arg - 1| is small, the second term on the right hand
 144 //   side can be approximated by a short polynomial. We elaborate
 145 //   this method in four steps.
 146 //
 147 //   Step 0: Initialization
 148 //
 149 //   We need to calculate logl( E + X ). Obtain N, S_hi, S_lo such that
 150 //
 151 //      E + X = 2^N * ( S_hi + S_lo )   exactly
 152 //
 153 //   where S_hi in [1,2) and S_lo is a correction to S_hi in the sense
 154 //   that |S_lo| <= ulp(S_hi).
 155 //
 156 //   Step 1: Argument Reduction
 157 //
 158 //   Based on S_hi, obtain G_1, G_2, G_3 from a table and calculate
 159 //
 160 //      G := G_1 * G_2 * G_3
 161 //      r := (G * S_hi - 1)  + G * S_lo
 162 //
 163 //   These G_j's have the property that the product is exactly
 164 //   representable and that |r| < 2^(-12) as a result.
 165 //
 166 //   Step 2: Approximation
 167 //
 168 //
 169 //   logl(1 + r) is approximated by a short polynomial poly(r).
 170 //
 171 //   Step 3: Reconstruction
 172 //
 173 //
 174 //   Finally, logl( E + X ) is given by
 175 //
 176 //   logl( E + X )   =   logl( 2^N * (S_hi + S_lo) )
 177 //                 ~=~  N*logl(2) + logl(1/G) + logl(1 + r)
 178 //                 ~=~  N*logl(2) + logl(1/G) + poly(r).
 179 //
 180 // **** Algorithm ****
 181 //
 182 // Case log1pl_small:
 183 //
 184 // Although logl(1 + (X+Em1)) is basically X+Em1, we would like to
 185 // preserve the inexactness nature as well as consistent behavior
 186 // under different rounding modes. Note that this case can only be
 187 // taken if E is set to be 1.0. In this case, Em1 is zero, and that
 188 // X can be very tiny and thus the final result can possibly underflow.
 189 // Thus, we compare X against a threshold that is dependent on the
 190 // input Expo_Range. If |X| is smaller than this threshold, we set
 191 // SAFE to be FALSE.
 192 //
 193 // The result is returned as Y_hi, Y_lo, and in the case of SAFE
 194 // is FALSE, an additional value Scale is also returned.
 195 //
 196 //      W    := X + Em1
 197 //      Threshold := Threshold_Table( Expo_Range )
 198 //      Tiny      := Tiny_Table( Expo_Range )
 199 //
 200 //      If ( |W| > Threshold ) then
 201 //         Y_hi  := W
 202 //         Y_lo  := -W*W
 203 //      Else
 204 //         Y_hi  := W
 205 //         Y_lo  := -Tiny
 206 //         Scale := 2^(-100)
 207 //         Safe  := FALSE
 208 //      EndIf
 209 //
 210 //
 211 // One may think that Y_lo should be -W*W/2; however, it does not matter
 212 // as Y_lo will be rounded off completely except for the correct effect in
 213 // directed rounding. Clearly -W*W is simplier to compute. Moreover,
 214 // because of the difference in exponent value, Y_hi + Y_lo or
 215 // Y_hi + Scale*Y_lo is always inexact.
 216 //
 217 // Case log_near1:
 218 //
 219 // Here we compute a simple polynomial. To exploit parallelism, we split
 220 // the polynomial into two portions.
 221 //
 222 //      W := X + Em1
 223 //      Wsq := W * W
 224 //      W4  := Wsq*Wsq
 225 //      W6  := W4*Wsq
 226 //      Y_hi := W + Wsq*(P_1 + W*(P_2 + W*(P_3 + W*P_4))
 227 //      Y_lo := W6*(P_5 + W*(P_6 + W*(P_7 + W*P_8)))
 228 //      set lsb(Y_lo) to be 1
 229 //
 230 // Case log_regular:
 231 //
 232 // We present the algorithm in four steps.
 233 //
 234 //   Step 0. Initialization
 235 //   ----------------------
 236 //
 237 //   Z := X + E
 238 //   N := unbaised exponent of Z
 239 //   S_hi := 2^(-N) * Z
 240 //   S_lo := 2^(-N) * { (max(X,E)-Z) + min(X,E) }
 241 //
 242 //   Note that S_lo is always 0 for the case E = 0.
 243 //
 244 //   Step 1. Argument Reduction
 245 //   --------------------------
 246 //
 247 //   Let
 248 //
 249 //      Z = 2^N * S_hi = 2^N * 1.d_1 d_2 d_3 ... d_63
 250 //
 251 //   We obtain G_1, G_2, G_3 by the following steps.
 252 //
 253 //
 254 //      Define          X_0 := 1.d_1 d_2 ... d_14. This is extracted
 255 //                      from S_hi.
 256 //
 257 //      Define          A_1 := 1.d_1 d_2 d_3 d_4. This is X_0 truncated
 258 //                      to lsb = 2^(-4).
 259 //
 260 //      Define          index_1 := [ d_1 d_2 d_3 d_4 ].
 261 //
 262 //      Fetch           Z_1 := (1/A_1) rounded UP in fixed point with
 263 //      fixed point     lsb = 2^(-15).
 264 //                      Z_1 looks like z_0.z_1 z_2 ... z_15
 265 //                      Note that the fetching is done using index_1.
 266 //                      A_1 is actually not needed in the implementation
 267 //                      and is used here only to explain how is the value
 268 //                      Z_1 defined.
 269 //
 270 //      Fetch           G_1 := (1/A_1) truncated to 21 sig. bits.
 271 //      floating pt.    Again, fetching is done using index_1. A_1
 272 //                      explains how G_1 is defined.
 273 //
 274 //      Calculate       X_1 := X_0 * Z_1 truncated to lsb = 2^(-14)
 275 //                           = 1.0 0 0 0 d_5 ... d_14
 276 //                      This is accomplised by integer multiplication.
 277 //                      It is proved that X_1 indeed always begin
 278 //                      with 1.0000 in fixed point.
 279 //
 280 //
 281 //      Define          A_2 := 1.0 0 0 0 d_5 d_6 d_7 d_8. This is X_1
 282 //                      truncated to lsb = 2^(-8). Similar to A_1,
 283 //                      A_2 is not needed in actual implementation. It
 284 //                      helps explain how some of the values are defined.
 285 //
 286 //      Define          index_2 := [ d_5 d_6 d_7 d_8 ].
 287 //
 288 //      Fetch           Z_2 := (1/A_2) rounded UP in fixed point with
 289 //      fixed point     lsb = 2^(-15). Fetch done using index_2.
 290 //                      Z_2 looks like z_0.z_1 z_2 ... z_15
 291 //
 292 //      Fetch           G_2 := (1/A_2) truncated to 21 sig. bits.
 293 //      floating pt.
 294 //
 295 //      Calculate       X_2 := X_1 * Z_2 truncated to lsb = 2^(-14)
 296 //                           = 1.0 0 0 0 0 0 0 0 d_9 d_10 ... d_14
 297 //                      This is accomplised by integer multiplication.
 298 //                      It is proved that X_2 indeed always begin
 299 //                      with 1.00000000 in fixed point.
 300 //
 301 //
 302 //      Define          A_3 := 1.0 0 0 0 0 0 0 0 d_9 d_10 d_11 d_12 d_13 1.
 303 //                      This is 2^(-14) + X_2 truncated to lsb = 2^(-13).
 304 //
 305 //      Define          index_3 := [ d_9 d_10 d_11 d_12 d_13 ].
 306 //
 307 //      Fetch           G_3 := (1/A_3) truncated to 21 sig. bits.
 308 //      floating pt.    Fetch is done using index_3.
 309 //
 310 //      Compute         G := G_1 * G_2 * G_3.
 311 //
 312 //      This is done exactly since each of G_j only has 21 sig. bits.
 313 //
 314 //      Compute
 315 //
 316 //              r := (G*S_hi - 1) + G*S_lo   using 2 FMA operations.
 317 //
 318 //      thus, r approximates G*(S_hi+S_lo) - 1 to within a couple of
 319 //      rounding errors.
 320 //
 321 //
 322 //  Step 2. Approximation
 323 //  ---------------------
 324 //
 325 //   This step computes an approximation to logl( 1 + r ) where r is the
 326 //   reduced argument just obtained. It is proved that |r| <= 1.9*2^(-13);
 327 //   thus logl(1+r) can be approximated by a short polynomial:
 328 //
 329 //      logl(1+r) ~=~ poly = r + Q1 r^2 + ... + Q4 r^5
 330 //
 331 //
 332 //  Step 3. Reconstruction
 333 //  ----------------------
 334 //
 335 //   This step computes the desired result of logl(X+E):
 336 //
 337 //      logl(X+E)  =   logl( 2^N * (S_hi + S_lo) )
 338 //                =   N*logl(2) + logl( S_hi + S_lo )
 339 //                =   N*logl(2) + logl(1/G) +
 340 //                    logl(1 + C*(S_hi+S_lo) - 1 )
 341 //
 342 //   logl(2), logl(1/G_j) are stored as pairs of (single,double) numbers:
 343 //   log2_hi, log2_lo, log1byGj_hi, log1byGj_lo. The high parts are
 344 //   single-precision numbers and the low parts are double precision
 345 //   numbers. These have the property that
 346 //
 347 //      N*log2_hi + SUM ( log1byGj_hi )
 348 //
 349 //   is computable exactly in double-extended precision (64 sig. bits).
 350 //   Finally
 351 //
 352 //      Y_hi := N*log2_hi + SUM ( log1byGj_hi )
 353 //      Y_lo := poly_hi + [ poly_lo +
 354 //              ( SUM ( log1byGj_lo ) + N*log2_lo ) ]
 355 //      set lsb(Y_lo) to be 1
 356 //
 357
 358 #include "libm_support.h"
 359
 360 #ifdef _LIBC
 361 .rodata
 362 #else
 363 .data
 364 #endif
 365
 366 // P_7, P_6, P_5, P_4, P_3, P_2, and P_1
 367
 368 .align 64
 369 Constants_P:
 370 ASM_TYPE_DIRECTIVE(Constants_P,@object)
 371 data4  0xEFD62B15,0xE3936754,0x00003FFB,0x00000000
 372 data4  0xA5E56381,0x8003B271,0x0000BFFC,0x00000000
 373 data4  0x73282DB0,0x9249248C,0x00003FFC,0x00000000
 374 data4  0x47305052,0xAAAAAA9F,0x0000BFFC,0x00000000
 375 data4  0xCCD17FC9,0xCCCCCCCC,0x00003FFC,0x00000000
 376 data4  0x00067ED5,0x80000000,0x0000BFFD,0x00000000
 377 data4  0xAAAAAAAA,0xAAAAAAAA,0x00003FFD,0x00000000
 378 data4  0xFFFFFFFE,0xFFFFFFFF,0x0000BFFD,0x00000000
 379 ASM_SIZE_DIRECTIVE(Constants_P)
 380
 381 // log2_hi, log2_lo, Q_4, Q_3, Q_2, and Q_1
 382
 383 .align 64
 384 Constants_Q:
 385 ASM_TYPE_DIRECTIVE(Constants_Q,@object)
 386 data4  0x00000000,0xB1721800,0x00003FFE,0x00000000
 387 data4  0x4361C4C6,0x82E30865,0x0000BFE2,0x00000000
 388 data4  0x328833CB,0xCCCCCAF2,0x00003FFC,0x00000000
 389 data4  0xA9D4BAFB,0x80000077,0x0000BFFD,0x00000000
 390 data4  0xAAABE3D2,0xAAAAAAAA,0x00003FFD,0x00000000
 391 data4  0xFFFFDAB7,0xFFFFFFFF,0x0000BFFD,0x00000000
 392 ASM_SIZE_DIRECTIVE(Constants_Q)
 393
 394 // Z1 - 16 bit fixed, G1 and H1 - IEEE single
 395
 396 .align 64
 397 Constants_Z_G_H_h1:
 398 ASM_TYPE_DIRECTIVE(Constants_Z_G_H_h1,@object)
 399 data4  0x00008000,0x3F800000,0x00000000,0x00000000,0x00000000,0x00000000
 400 data4  0x00007879,0x3F70F0F0,0x3D785196,0x00000000,0x617D741C,0x3DA163A6
 401 data4  0x000071C8,0x3F638E38,0x3DF13843,0x00000000,0xCBD3D5BB,0x3E2C55E6
 402 data4  0x00006BCB,0x3F579430,0x3E2FF9A0,0x00000000,0xD86EA5E7,0xBE3EB0BF
 403 data4  0x00006667,0x3F4CCCC8,0x3E647FD6,0x00000000,0x86B12760,0x3E2E6A8C
 404 data4  0x00006187,0x3F430C30,0x3E8B3AE7,0x00000000,0x5C0739BA,0x3E47574C
 405 data4  0x00005D18,0x3F3A2E88,0x3EA30C68,0x00000000,0x13E8AF2F,0x3E20E30F
 406 data4  0x0000590C,0x3F321640,0x3EB9CEC8,0x00000000,0xF2C630BD,0xBE42885B
 407 data4  0x00005556,0x3F2AAAA8,0x3ECF9927,0x00000000,0x97E577C6,0x3E497F34
 408 data4  0x000051EC,0x3F23D708,0x3EE47FC5,0x00000000,0xA6B0A5AB,0x3E3E6A6E
 409 data4  0x00004EC5,0x3F1D89D8,0x3EF8947D,0x00000000,0xD328D9BE,0xBDF43E3C
 410 data4  0x00004BDB,0x3F17B420,0x3F05F3A1,0x00000000,0x0ADB090A,0x3E4094C3
 411 data4  0x00004925,0x3F124920,0x3F0F4303,0x00000000,0xFC1FE510,0xBE28FBB2
 412 data4  0x0000469F,0x3F0D3DC8,0x3F183EBF,0x00000000,0x10FDE3FA,0x3E3A7895
 413 data4  0x00004445,0x3F088888,0x3F20EC80,0x00000000,0x7CC8C98F,0x3E508CE5
 414 data4  0x00004211,0x3F042108,0x3F29516A,0x00000000,0xA223106C,0xBE534874
 415 ASM_SIZE_DIRECTIVE(Constants_Z_G_H_h1)
 416
 417 // Z2 - 16 bit fixed, G2 and H2 - IEEE single
 418
 419 .align 64
 420 Constants_Z_G_H_h2:
 421 ASM_TYPE_DIRECTIVE(Constants_Z_G_H_h2,@object)
 422 data4  0x00008000,0x3F800000,0x00000000,0x00000000,0x00000000,0x00000000
 423 data4  0x00007F81,0x3F7F00F8,0x3B7F875D,0x00000000,0x22C42273,0x3DB5A116
 424 data4  0x00007F02,0x3F7E03F8,0x3BFF015B,0x00000000,0x21F86ED3,0x3DE620CF
 425 data4  0x00007E85,0x3F7D08E0,0x3C3EE393,0x00000000,0x484F34ED,0xBDAFA07E
 426 data4  0x00007E08,0x3F7C0FC0,0x3C7E0586,0x00000000,0x3860BCF6,0xBDFE07F0
 427 data4  0x00007D8D,0x3F7B1880,0x3C9E75D2,0x00000000,0xA78093D6,0x3DEA370F
 428 data4  0x00007D12,0x3F7A2328,0x3CBDC97A,0x00000000,0x72A753D0,0x3DFF5791
 429 data4  0x00007C98,0x3F792FB0,0x3CDCFE47,0x00000000,0xA7EF896B,0x3DFEBE6C
 430 data4  0x00007C20,0x3F783E08,0x3CFC15D0,0x00000000,0x409ECB43,0x3E0CF156
 431 data4  0x00007BA8,0x3F774E38,0x3D0D874D,0x00000000,0xFFEF71DF,0xBE0B6F97
 432 data4  0x00007B31,0x3F766038,0x3D1CF49B,0x00000000,0x5D59EEE8,0xBE080483
 433 data4  0x00007ABB,0x3F757400,0x3D2C531D,0x00000000,0xA9192A74,0x3E1F91E9
 434 data4  0x00007A45,0x3F748988,0x3D3BA322,0x00000000,0xBF72A8CD,0xBE139A06
 435 data4  0x000079D1,0x3F73A0D0,0x3D4AE46F,0x00000000,0xF8FBA6CF,0x3E1D9202
 436 data4  0x0000795D,0x3F72B9D0,0x3D5A1756,0x00000000,0xBA796223,0xBE1DCCC4
 437 data4  0x000078EB,0x3F71D488,0x3D693B9D,0x00000000,0xB6B7C239,0xBE049391
 438 ASM_SIZE_DIRECTIVE(Constants_Z_G_H_h2)
 439
 440 // G3 and H3 - IEEE single and h3 -IEEE double
 441
 442 .align 64
 443 Constants_Z_G_H_h3:
 444 ASM_TYPE_DIRECTIVE(Constants_Z_G_H_h3,@object)
 445 data4  0x3F7FFC00,0x38800100,0x562224CD,0x3D355595
 446 data4  0x3F7FF400,0x39400480,0x06136FF6,0x3D8200A2
 447 data4  0x3F7FEC00,0x39A00640,0xE8DE9AF0,0x3DA4D68D
 448 data4  0x3F7FE400,0x39E00C41,0xB10238DC,0xBD8B4291
 449 data4  0x3F7FDC00,0x3A100A21,0x3B1952CA,0xBD89CCB8
 450 data4  0x3F7FD400,0x3A300F22,0x1DC46826,0xBDB10707
 451 data4  0x3F7FCC08,0x3A4FF51C,0xF43307DB,0x3DB6FCB9
 452 data4  0x3F7FC408,0x3A6FFC1D,0x62DC7872,0xBD9B7C47
 453 data4  0x3F7FBC10,0x3A87F20B,0x3F89154A,0xBDC3725E
 454 data4  0x3F7FB410,0x3A97F68B,0x62B9D392,0xBD93519D
 455 data4  0x3F7FAC18,0x3AA7EB86,0x0F21BD9D,0x3DC18441
 456 data4  0x3F7FA420,0x3AB7E101,0x2245E0A6,0xBDA64B95
 457 data4  0x3F7F9C20,0x3AC7E701,0xAABB34B8,0x3DB4B0EC
 458 data4  0x3F7F9428,0x3AD7DD7B,0x6DC40A7E,0x3D992337
 459 data4  0x3F7F8C30,0x3AE7D474,0x4F2083D3,0x3DC6E17B
 460 data4  0x3F7F8438,0x3AF7CBED,0x811D4394,0x3DAE314B
 461 data4  0x3F7F7C40,0x3B03E1F3,0xB08F2DB1,0xBDD46F21
 462 data4  0x3F7F7448,0x3B0BDE2F,0x6D34522B,0xBDDC30A4
 463 data4  0x3F7F6C50,0x3B13DAAA,0xB1F473DB,0x3DCB0070
 464 data4  0x3F7F6458,0x3B1BD766,0x6AD282FD,0xBDD65DDC
 465 data4  0x3F7F5C68,0x3B23CC5C,0xF153761A,0xBDCDAB83
 466 data4  0x3F7F5470,0x3B2BC997,0x341D0F8F,0xBDDADA40
 467 data4  0x3F7F4C78,0x3B33C711,0xEBC394E8,0x3DCD1BD7
 468 data4  0x3F7F4488,0x3B3BBCC6,0x52E3E695,0xBDC3532B
 469 data4  0x3F7F3C90,0x3B43BAC0,0xE846B3DE,0xBDA3961E
 470 data4  0x3F7F34A0,0x3B4BB0F4,0x785778D4,0xBDDADF06
 471 data4  0x3F7F2CA8,0x3B53AF6D,0xE55CE212,0x3DCC3ED1
 472 data4  0x3F7F24B8,0x3B5BA620,0x9E382C15,0xBDBA3103
 473 data4  0x3F7F1CC8,0x3B639D12,0x5C5AF197,0x3D635A0B
 474 data4  0x3F7F14D8,0x3B6B9444,0x71D34EFC,0xBDDCCB19
 475 data4  0x3F7F0CE0,0x3B7393BC,0x52CD7ADA,0x3DC74502
 476 data4  0x3F7F04F0,0x3B7B8B6D,0x7D7F2A42,0xBDB68F17
 477 ASM_SIZE_DIRECTIVE(Constants_Z_G_H_h3)
 478
 479 //
 480 //  Exponent Thresholds and Tiny Thresholds
 481 //  for 8, 11, 15, and 17 bit exponents
 482 //
 483 //  Expo_Range             Value
 484 //
 485 //  0 (8  bits)            2^(-126)
 486 //  1 (11 bits)            2^(-1022)
 487 //  2 (15 bits)            2^(-16382)
 488 //  3 (17 bits)            2^(-16382)
 489 //
 490 //  Tiny_Table
 491 //  ----------
 492 //  Expo_Range             Value
 493 //
 494 //  0 (8  bits)            2^(-16382)
 495 //  1 (11 bits)            2^(-16382)
 496 //  2 (15 bits)            2^(-16382)
 497 //  3 (17 bits)            2^(-16382)
 498 //
 499
 500 .align 64
 501 Constants_Threshold:
 502 ASM_TYPE_DIRECTIVE(Constants_Threshold,@object)
 503 data4  0x00000000,0x80000000,0x00003F81,0x00000000
 504 data4  0x00000000,0x80000000,0x00000001,0x00000000
 505 data4  0x00000000,0x80000000,0x00003C01,0x00000000
 506 data4  0x00000000,0x80000000,0x00000001,0x00000000
 507 data4  0x00000000,0x80000000,0x00000001,0x00000000
 508 data4  0x00000000,0x80000000,0x00000001,0x00000000
 509 data4  0x00000000,0x80000000,0x00000001,0x00000000
 510 data4  0x00000000,0x80000000,0x00000001,0x00000000
 511 ASM_SIZE_DIRECTIVE(Constants_Threshold)
 512
 513 .align 64
 514 Constants_1_by_LN10:
 515 ASM_TYPE_DIRECTIVE(Constants_1_by_LN10,@object)
 516 data4  0x37287195,0xDE5BD8A9,0x00003FFD,0x00000000
 517 data4  0xACCF70C8,0xD56EAABE,0x00003FBB,0x00000000
 518 ASM_SIZE_DIRECTIVE(Constants_1_by_LN10)
 519
 520 FR_Input_X = f8
 521 FR_Neg_One = f9
 522 FR_E       = f33
 523 FR_Em1     = f34
 524 FR_Y_hi    = f34
 525 // Shared with Em1
 526 FR_Y_lo    = f35
 527 FR_Scale   = f36
 528 FR_X_Prime = f37
 529 FR_Z       = f38
 530 FR_S_hi    = f38
 531 // Shared with Z
 532 FR_W       = f39
 533 FR_G       = f40
 534 FR_wsq     = f40
 535 // Shared with G
 536 FR_H       = f41
 537 FR_w4      = f41
 538 // Shared with H
 539 FR_h       = f42
 540 FR_w6      = f42
 541 // Shared with h
 542 FR_G_tmp   = f43
 543 FR_poly_lo = f43
 544 // Shared with G_tmp
 545 FR_P8      = f43
 546 // Shared with G_tmp
 547 FR_H_tmp   = f44
 548 FR_poly_hi = f44
 549   // Shared with H_tmp
 550 FR_P7      = f44
 551 // Shared with H_tmp
 552 FR_h_tmp   = f45
 553 FR_rsq     = f45
 554 // Shared with h_tmp
 555 FR_P6      = f45
 556 // Shared with h_tmp
 557 FR_abs_W   = f46
 558 FR_r       = f46
 559 // Shared with abs_W
 560 FR_AA      = f47
 561 FR_log2_hi = f47
 562 // Shared with AA
 563 FR_BB          = f48
 564 FR_log2_lo     = f48
 565 // Shared with BB
 566 FR_S_lo        = f49
 567 FR_two_negN    = f50
 568 FR_float_N     = f51
 569 FR_Q4          = f52
 570 FR_dummy       = f52
 571 // Shared with Q4
 572 FR_P4          = f52
 573 // Shared with Q4
 574 FR_Threshold    = f52
 575 // Shared with Q4
 576 FR_Q3          = f53
 577 FR_P3          = f53
 578 // Shared with Q3
 579 FR_Tiny        = f53
 580 // Shared with Q3
 581 FR_Q2          = f54
 582 FR_P2          = f54
 583 // Shared with Q2
 584 FR_1LN10_hi     = f54
 585 // Shared with Q2
 586 FR_Q1           = f55
 587 FR_P1           = f55
 588 // Shared with Q1
 589 FR_1LN10_lo     = f55
 590 // Shared with Q1
 591 FR_P5           = f98
 592 FR_SCALE        = f98
 593 FR_Output_X_tmp = f99
 594
 595 GR_Expo_Range   = r32
 596 GR_Table_Base   = r34
 597 GR_Table_Base1  = r35
 598 GR_Table_ptr    = r36
 599 GR_Index2       = r37
 600 GR_signif       = r38
 601 GR_X_0          = r39
 602 GR_X_1          = r40
 603 GR_X_2          = r41
 604 GR_Z_1          = r42
 605 GR_Z_2          = r43
 606 GR_N            = r44
 607 GR_Bias         = r45
 608 GR_M            = r46
 609 GR_ScaleN       = r47
 610 GR_Index3       = r48
 611 GR_Perturb      = r49
 612 GR_Table_Scale  = r50
 613
 614 //
 615 // Added for unwind support
 616 //
 617
 618 GR_SAVE_PFS         = r51
 619 GR_SAVE_B0          = r52
 620 GR_SAVE_GP          = r53
 621 GR_Parameter_X      = r54
 622 GR_Parameter_Y      = r55
 623 GR_Parameter_RESULT = r56
 624 GR_Parameter_TAG    = r57
 625
 626 FR_X                = f8
 627 FR_Y                = f0
 628 FR_RESULT           = f99
 629
 630 .section .text
 631 .proc logl#
 632 .global logl#
 633 .align 64
 634 logl:
 635 #ifdef _LIBC
 636 .global __ieee754_logl
 637 __ieee754_logl:
 638 #endif
 639 { .mfi
 640 alloc r32 = ar.pfs,0,22,4,0
 641 (p0)  fnorm.s1 FR_X_Prime = FR_Input_X
 642 (p0)  cmp.eq.unc  p7, p0 = r0, r0
 643 }
 644 { .mfi
 645 (p0)  cmp.ne.unc  p14, p0 = r0, r0
 646 (p0)  fclass.m.unc p6, p0 =  FR_Input_X, 0x1E3
 647 (p0)  cmp.ne.unc  p15, p0 = r0, r0 ;;
 648 }
 649 { .mfi
 650  nop.m 0
 651 (p0)  fclass.nm.unc p10, p0 =  FR_Input_X, 0x1FF
 652  nop.i 0
 653 }
 654 { .mfi
 655 nop.m 999
 656 (p0)  fcmp.eq.unc.s1 p8, p0 =  FR_Input_X, f0
 657  nop.i 0
 658 }
 659 { .mfi
 660         nop.m 999
 661 (p0)  fcmp.lt.unc.s1 p13, p0 =  FR_Input_X, f0
 662  nop.i 0
 663 }
 664 { .mfi
 665         nop.m 999
 666 (p0)  fcmp.eq.unc.s1 p9, p0 =  FR_Input_X, f1
 667         nop.i 999 ;;
 668 }
 669 { .mfi
 670         nop.m 999
 671 (p0)  fsub.s1 FR_Em1 = f0,f1
 672         nop.i 999
 673 }
 674 { .mfb
 675         nop.m 999
 676 (p0)  fadd FR_E = f0,f0
 677 //
 678 //    Create E = 0 and Em1 = -1
 679 //    Check for X == 1, meaning logl(1)
 680 //    Check for X < 0, meaning logl(negative)
 681 //    Check for X == 0, meaning logl(0)
 682 //    Identify NatVals, NaNs, Infs.
 683 //    Identify EM unsupporteds.
 684 //    Identify Negative values - us S1 so as
 685 //    not to raise denormal operand exception
 686 //    Set p15 to false for log
 687 //    Set p14 to false for log
 688 //    Set p7 true for log and log1p
 689 //
 690 (p0)  br.cond.sptk L(LOGL_BEGIN) ;;
 691 }
 692
 693 .endp logl
 694 ASM_SIZE_DIRECTIVE(logl)
 695
 696 .section .text
 697 .proc log10l#
 698 .global log10l#
 699 .align 64
 700 log10l:
 701 #ifdef _LIBC
 702 .global __ieee754_log10l
 703 __ieee754_log10l:
 704 #endif
 705 { .mfi
 706 alloc r32 = ar.pfs,0,22,4,0
 707 (p0)  fadd FR_E = f0,f0
 708       nop.i 0
 709 }
 710 { .mfi
 711       nop.m 0
 712 (p0)  fsub.s1 FR_Em1 = f0,f1
 713       nop.i 0
 714 }
 715 { .mfi
 716 (p0)  cmp.ne.unc  p15, p0 = r0, r0
 717 (p0)  fcmp.eq.unc.s1 p9, p0 =  FR_Input_X, f1
 718       nop.i 0
 719 }
 720 { .mfi
 721 (p0)  cmp.eq.unc  p14, p0 = r0, r0
 722 (p0)  fcmp.lt.unc.s1 p13, p0 =  FR_Input_X, f0
 723 (p0)  cmp.ne.unc  p7, p0 = r0, r0 ;;
 724 }
 725 { .mfi
 726         nop.m 999
 727 (p0)  fcmp.eq.unc.s1 p8, p0 =  FR_Input_X, f0
 728         nop.i 999
 729 }
 730 { .mfi
 731         nop.m 999
 732 (p0)  fclass.nm.unc p10, p0 =  FR_Input_X, 0x1FF
 733         nop.i 999 ;;
 734 }
 735 { .mfi
 736         nop.m 999
 737 (p0)  fclass.m.unc p6, p0 =  FR_Input_X, 0x1E3
 738         nop.i 999
 739 }
 740 { .mfb
 741         nop.m 999
 742 (p0)  fnorm.s1 FR_X_Prime = FR_Input_X
 743 //
 744 //    Create E = 0 and Em1 = -1
 745 //    Check for X == 1, meaning logl(1)
 746 //    Check for X < 0, meaning logl(negative)
 747 //    Check for X == 0, meaning logl(0)
 748 //    Identify NatVals, NaNs, Infs.
 749 //    Identify EM unsupporteds.
 750 //    Identify Negative values - us S1 so as
 751 //    Identify Negative values - us S1 so as
 752 //    not to raise denormal operand exception
 753 //    Set p15 to false for log10
 754 //    Set p14 to true for log10
 755 //    Set p7 to false for log10
 756 //
 757 (p0)  br.cond.sptk L(LOGL_BEGIN) ;;
 758 }
 759
 760 .endp log10l
 761 ASM_SIZE_DIRECTIVE(log10l)
 762
 763 .section .text
 764 .proc log1pl#
 765 .global log1pl#
 766 .align 64
 767 log1pl:
 768 #ifdef _LIBC
 769 .global __log1pl
 770 __log1pl:
 771 #endif
 772 { .mfi
 773 alloc r32 = ar.pfs,0,22,4,0
 774 (p0)  fsub.s1 FR_Neg_One = f0,f1
 775 (p0)  cmp.eq.unc  p7, p0 = r0, r0
 776 }
 777 { .mfi
 778 (p0)  cmp.ne.unc  p14, p0 = r0, r0
 779 (p0)  fnorm.s1 FR_X_Prime = FR_Input_X
 780 (p0)  cmp.eq.unc  p15, p0 = r0, r0 ;;
 781 }
 782 { .mfi
 783       nop.m 0
 784 (p0)  fclass.m.unc p6, p0 =  FR_Input_X, 0x1E3
 785       nop.i 0
 786 }
 787 { .mfi
 788       nop.m 999
 789 (p0)  fclass.nm.unc p10, p0 =  FR_Input_X, 0x1FF
 790       nop.i 0
 791 }
 792 { .mfi
 793       nop.m 999
 794 (p0)  fcmp.eq.unc.s1 p9, p0 =  FR_Input_X, f0
 795       nop.i 0
 796 }
 797 { .mfi
 798       nop.m 999
 799 (p0)  fadd FR_Em1 = f0,f0
 800       nop.i 999 ;;
 801 }
 802 { .mfi
 803         nop.m 999
 804 (p0)  fadd FR_E = f0,f1
 805         nop.i 999 ;;
 806 }
 807 { .mfi
 808         nop.m 999
 809 (p0)  fcmp.eq.unc.s1 p8, p0 =  FR_Input_X, FR_Neg_One
 810         nop.i 999
 811 }
 812 { .mfi
 813         nop.m 999
 814 (p0)  fcmp.lt.unc.s1 p13, p0 =  FR_Input_X, FR_Neg_One
 815         nop.i 999
 816 }
 817 L(LOGL_BEGIN):
 818 { .mfi
 819         nop.m 999
 820 (p0)  fadd.s1 FR_Z = FR_X_Prime, FR_E
 821         nop.i 999
 822 }
 823 { .mlx
 824         nop.m 999
 825 (p0)  movl GR_Table_Scale = 0x0000000000000018 ;;
 826 }
 827 { .mmi
 828         nop.m 999
 829         nop.m 999
 830 //
 831 //    Create E = 1 and Em1 = 0
 832 //    Check for X == 0, meaning logl(1+0)
 833 //    Check for X < -1, meaning logl(negative)
 834 //    Check for X == -1, meaning logl(0)
 835 //    Normalize x
 836 //    Identify NatVals, NaNs, Infs.
 837 //    Identify EM unsupporteds.
 838 //    Identify Negative values - us S1 so as
 839 //    not to raise denormal operand exception
 840 //    Set p15 to true for log1p
 841 //    Set p14 to false for log1p
 842 //    Set p7 true for log and log1p
 843 //
 844 (p0)  addl GR_Table_Base = @ltoff(Constants_Z_G_H_h1#),gp
 845 }
 846 { .mfi
 847       nop.m 999
 848 (p0)  fmax.s1 FR_AA = FR_X_Prime, FR_E
 849       nop.i 999 ;;
 850 }
 851 { .mfi
 852       ld8    GR_Table_Base = [GR_Table_Base]
 853 (p0)  fmin.s1 FR_BB = FR_X_Prime, FR_E
 854       nop.i 999
 855 }
 856 { .mfb
 857       nop.m 999
 858 (p0)  fadd.s1 FR_W = FR_X_Prime, FR_Em1
 859 //
 860 //    Begin load of constants base
 861 //    FR_Z = Z = |x| + E
 862 //    FR_W = W = |x| + Em1
 863 //    AA = fmax(|x|,E)
 864 //    BB = fmin(|x|,E)
 865 //
 866 (p6)  br.cond.spnt L(LOGL_64_special) ;;
 867 }
 868 { .mib
 869         nop.m 999
 870         nop.i 999
 871 (p10) br.cond.spnt L(LOGL_64_unsupported) ;;
 872 }
 873 { .mib
 874         nop.m 999
 875         nop.i 999
 876 (p13) br.cond.spnt L(LOGL_64_negative) ;;
 877 }
 878 { .mib
 879 (p0)  getf.sig GR_signif = FR_Z
 880         nop.i 999
 881 (p9)  br.cond.spnt L(LOGL_64_one) ;;
 882 }
 883 { .mib
 884         nop.m 999
 885         nop.i 999
 886 (p8)  br.cond.spnt L(LOGL_64_zero) ;;
 887 }
 888 { .mfi
 889 (p0)  getf.exp GR_N =  FR_Z
 890 //
 891 //    Raise possible denormal operand exception
 892 //    Create Bias
 893 //
 894 //    This function computes ln( x + e )
 895 //    Input  FR 1: FR_X   = FR_Input_X
 896 //    Input  FR 2: FR_E   = FR_E
 897 //    Input  FR 3: FR_Em1 = FR_Em1
 898 //    Input  GR 1: GR_Expo_Range = GR_Expo_Range = 1
 899 //    Output FR 4: FR_Y_hi
 900 //    Output FR 5: FR_Y_lo
 901 //    Output FR 6: FR_Scale
 902 //    Output PR 7: PR_Safe
 903 //
 904 (p0)  fsub.s1 FR_S_lo = FR_AA, FR_Z
 905 //
 906 //    signif = getf.sig(Z)
 907 //    abs_W = fabs(w)
 908 //
 909 (p0)  extr.u GR_Table_ptr = GR_signif, 59, 4 ;;
 910 }
 911 { .mfi
 912         nop.m 999
 913 (p0)  fmerge.se FR_S_hi =  f1,FR_Z
 914 (p0)  extr.u GR_X_0 = GR_signif, 49, 15
 915 }
 916 { .mmi
 917        nop.m 999
 918        nop.m 999
 919 (p0)  addl GR_Table_Base1 = @ltoff(Constants_Z_G_H_h2#),gp ;;
 920 }
 921 { .mlx
 922       ld8    GR_Table_Base1 = [GR_Table_Base1]
 923 (p0)  movl GR_Bias = 0x000000000000FFFF ;;
 924 }
 925 { .mfi
 926         nop.m 999
 927 (p0)  fabs FR_abs_W =  FR_W
 928 (p0)  pmpyshr2.u GR_Table_ptr = GR_Table_ptr,GR_Table_Scale,0
 929 }
 930 { .mfi
 931         nop.m 999
 932 //
 933 //    Branch out for special input values
 934 //
 935 (p0)  fcmp.lt.unc.s0 p8, p0 =  FR_Input_X, f0
 936         nop.i 999 ;;
 937 }
 938 { .mfi
 939         nop.m 999
 940 //
 941 //    X_0 = extr.u(signif,49,15)
 942 //    Index1 = extr.u(signif,59,4)
 943 //
 944 (p0)  fadd.s1 FR_S_lo = FR_S_lo, FR_BB
 945         nop.i 999 ;;
 946 }
 947 { .mii
 948         nop.m 999
 949         nop.i 999 ;;
 950 //
 951 //    Offset_to_Z1 = 24 * Index1
 952 //    For performance, don't use result
 953 //    for 3 or 4 cycles.
 954 //
 955 (p0)  add GR_Table_ptr = GR_Table_ptr, GR_Table_Base ;;
 956 }
 957 //
 958 //    Add Base to Offset for Z1
 959 //    Create Bias
 960 { .mmi
 961 (p0)  ld4 GR_Z_1 = [GR_Table_ptr],4 ;;
 962 (p0)  ldfs  FR_G = [GR_Table_ptr],4
 963         nop.i 999 ;;
 964 }
 965 { .mmi
 966 (p0)  ldfs  FR_H = [GR_Table_ptr],8 ;;
 967 (p0)  ldfd  FR_h = [GR_Table_ptr],0
 968 (p0)  pmpyshr2.u GR_X_1 = GR_X_0,GR_Z_1,15
 969 }
 970 //
 971 //    Load Z_1
 972 //    Get Base of Table2
 973 //
 974 { .mfi
 975 (p0)  getf.exp GR_M = FR_abs_W
 976         nop.f 999
 977         nop.i 999 ;;
 978 }
 979 { .mii
 980         nop.m 999
 981         nop.i 999 ;;
 982 //
 983 //    M = getf.exp(abs_W)
 984 //    S_lo = AA - Z
 985 //    X_1 = pmpyshr2(X_0,Z_1,15)
 986 //
 987 (p0)  sub GR_M = GR_M, GR_Bias ;;
 988 }
 989 //
 990 //    M = M - Bias
 991 //    Load G1
 992 //    N = getf.exp(Z)
 993 //
 994 { .mii
 995 (p0)  cmp.gt.unc  p11, p0 =  -80, GR_M
 996 (p0)  cmp.gt.unc  p12, p0 =  -7, GR_M ;;
 997 (p0)  extr.u GR_Index2 = GR_X_1, 6, 4 ;;
 998 }
 999 { .mib
1000         nop.m 999
1001 //
1002 //    if -80 > M, set p11
1003 //    Index2 = extr.u(X_1,6,4)
1004 //    if -7  > M, set p12
1005 //    Load H1
1006 //
1007 (p0)  pmpyshr2.u GR_Index2 = GR_Index2,GR_Table_Scale,0
1008 (p11) br.cond.spnt L(log1pl_small) ;;
1009 }
1010 { .mib
1011       nop.m 999
1012         nop.i 999
1013 (p12) br.cond.spnt L(log1pl_near) ;;
1014 }
1015 { .mii
1016 (p0)  sub GR_N = GR_N, GR_Bias
1017 //
1018 //    poly_lo = r * poly_lo
1019 //
1020 (p0)  add GR_Perturb = 0x1, r0 ;;
1021 (p0)  sub GR_ScaleN = GR_Bias, GR_N
1022 }
1023 { .mii
1024 (p0)  setf.sig FR_float_N = GR_N
1025         nop.i 999 ;;
1026 //
1027 //    Prepare Index2 - pmpyshr2.u(X_1,Z_2,15)
1028 //    Load h1
1029 //    S_lo = S_lo + BB
1030 //    Branch for -80 > M
1031 //
1032 (p0)  add GR_Index2 = GR_Index2, GR_Table_Base1
1033 }
1034 { .mmi
1035 (p0)  setf.exp FR_two_negN = GR_ScaleN
1036       nop.m 999
1037 (p0)  addl GR_Table_Base = @ltoff(Constants_Z_G_H_h3#),gp ;;
1038 }
1039 //
1040 //    Index2 points to Z2
1041 //    Branch for -7 > M
1042 //
1043 { .mmb
1044 (p0)  ld4 GR_Z_2 = [GR_Index2],4
1045 (p0)  ld8 GR_Table_Base = [GR_Table_Base]
1046         nop.b 999 ;;
1047 }
1048 (p0)  nop.i 999
1049 //
1050 //    Load Z_2
1051 //    N = N - Bias
1052 //    Tablebase points to Table3
1053 //
1054 { .mmi
1055 (p0)  ldfs  FR_G_tmp = [GR_Index2],4 ;;
1056 //
1057 //    Load G_2
1058 //    pmpyshr2  X_2= (X_1,Z_2,15)
1059 //    float_N = setf.sig(N)
1060 //    ScaleN = Bias - N
1061 //
1062 (p0)  ldfs  FR_H_tmp = [GR_Index2],8
1063         nop.i 999 ;;
1064 }
1065 //
1066 //    Load H_2
1067 //    two_negN = setf.exp(scaleN)
1068 //    G = G_1 * G_2
1069 //
1070 { .mfi
1071 (p0)  ldfd  FR_h_tmp = [GR_Index2],0
1072         nop.f 999
1073 (p0)  pmpyshr2.u GR_X_2 = GR_X_1,GR_Z_2,15 ;;
1074 }
1075 { .mii
1076         nop.m 999
1077 (p0)  extr.u GR_Index3 = GR_X_2, 1, 5 ;;
1078 //
1079 //    Load h_2
1080 //    H = H_1 + H_2
1081 //    h = h_1 + h_2
1082 //    Index3 = extr.u(X_2,1,5)
1083 //
1084 (p0)  shladd GR_Index3 = GR_Index3,4,GR_Table_Base
1085 }
1086 { .mmi
1087         nop.m 999
1088         nop.m 999
1089 //
1090 //    float_N = fcvt.xf(float_N)
1091 //    load G3
1092 //
1093 (p0)  addl GR_Table_Base = @ltoff(Constants_Q#),gp ;;
1094 }
1095 { .mmi
1096       nop.m 999
1097       ld8    GR_Table_Base = [GR_Table_Base]
1098       nop.i 999
1099 };;
1100
1101 { .mfi
1102 (p0)  ldfe FR_log2_hi = [GR_Table_Base],16
1103 (p0)  fmpy.s1 FR_S_lo = FR_S_lo, FR_two_negN
1104         nop.i 999 ;;
1105 }
1106 { .mmf
1107         nop.m 999
1108 //
1109 //    G = G3 * G
1110 //    Load h3
1111 //    Load log2_hi
1112 //    H = H + H3
1113 //
1114 (p0)  ldfe FR_log2_lo = [GR_Table_Base],16
1115 (p0)  fmpy.s1 FR_G = FR_G, FR_G_tmp ;;
1116 }
1117 { .mmf
1118 (p0)  ldfs  FR_G_tmp = [GR_Index3],4
1119 //
1120 //    h = h + h3
1121 //    r = G * S_hi + 1
1122 //    Load log2_lo
1123 //
1124 (p0)  ldfe FR_Q4 = [GR_Table_Base],16
1125 (p0)  fadd.s1 FR_h = FR_h, FR_h_tmp ;;
1126 }
1127 { .mfi
1128 (p0)  ldfe FR_Q3 = [GR_Table_Base],16
1129 (p0)  fadd.s1 FR_H = FR_H, FR_H_tmp
1130         nop.i 999 ;;
1131 }
1132 { .mmf
1133 (p0)  ldfs  FR_H_tmp = [GR_Index3],4
1134 (p0)  ldfe FR_Q2 = [GR_Table_Base],16
1135 //
1136 //    Comput Index for Table3
1137 //    S_lo = S_lo * two_negN
1138 //
1139 (p0)  fcvt.xf FR_float_N = FR_float_N ;;
1140 }
1141 //
1142 //    If S_lo == 0, set p8 false
1143 //    Load H3
1144 //    Load ptr to table of polynomial coeff.
1145 //
1146 { .mmf
1147 (p0)  ldfd  FR_h_tmp = [GR_Index3],0
1148 (p0)  ldfe FR_Q1 = [GR_Table_Base],0
1149 (p0)  fcmp.eq.unc.s1 p0, p8 =  FR_S_lo, f0 ;;
1150 }
1151 { .mfi
1152         nop.m 999
1153 (p0)  fmpy.s1 FR_G = FR_G, FR_G_tmp
1154         nop.i 999 ;;
1155 }
1156 { .mfi
1157         nop.m 999
1158 (p0)  fadd.s1 FR_H = FR_H, FR_H_tmp
1159         nop.i 999 ;;
1160 }
1161 { .mfi
1162         nop.m 999
1163 (p0)  fms.s1 FR_r = FR_G, FR_S_hi, f1
1164         nop.i 999
1165 }
1166 { .mfi
1167         nop.m 999
1168 (p0)  fadd.s1 FR_h = FR_h, FR_h_tmp
1169         nop.i 999 ;;
1170 }
1171 { .mfi
1172         nop.m 999
1173 (p0)  fma.s1 FR_Y_hi = FR_float_N, FR_log2_hi, FR_H
1174         nop.i 999 ;;
1175 }
1176 { .mfi
1177         nop.m 999
1178 //
1179 //    Load Q4
1180 //    Load Q3
1181 //    Load Q2
1182 //    Load Q1
1183 //
1184 (p8) fma.s1 FR_r = FR_G, FR_S_lo, FR_r
1185         nop.i 999
1186 }
1187 { .mfi
1188         nop.m 999
1189 //
1190 //    poly_lo = r * Q4 + Q3
1191 //    rsq = r* r
1192 //
1193 (p0)  fma.s1 FR_h = FR_float_N, FR_log2_lo, FR_h
1194         nop.i 999 ;;
1195 }
1196 { .mfi
1197         nop.m 999
1198 //
1199 //    If (S_lo!=0) r = s_lo * G + r
1200 //
1201 (p0)  fma.s1 FR_poly_lo = FR_r, FR_Q4, FR_Q3
1202         nop.i 999
1203 }
1204 //
1205 //    Create a 0x00000....01
1206 //    poly_lo = poly_lo * rsq + h
1207 //
1208 { .mfi
1209 (p0)  setf.sig FR_dummy = GR_Perturb
1210 (p0)  fmpy.s1 FR_rsq = FR_r, FR_r
1211         nop.i 999 ;;
1212 }
1213 { .mfi
1214         nop.m 999
1215 //
1216 //    h = N * log2_lo + h
1217 //    Y_hi = n * log2_hi + H
1218 //
1219 (p0)  fma.s1 FR_poly_lo = FR_poly_lo, FR_r, FR_Q2
1220         nop.i 999
1221 }
1222 { .mfi
1223         nop.m 999
1224 (p0)  fma.s1 FR_poly_hi = FR_Q1, FR_rsq, FR_r
1225         nop.i 999 ;;
1226 }
1227 { .mfi
1228         nop.m 999
1229 //
1230 //    poly_lo = r * poly_o + Q2
1231 //    poly_hi = Q1 * rsq + r
1232 //
1233 (p0)  fmpy.s1 FR_poly_lo = FR_poly_lo, FR_r
1234         nop.i 999 ;;
1235 }
1236 { .mfi
1237         nop.m 999
1238 (p0)  fma.s1 FR_poly_lo = FR_poly_lo, FR_rsq, FR_h
1239         nop.i 999 ;;
1240 }
1241 { .mfb
1242         nop.m 999
1243 (p0)  fadd.s1 FR_Y_lo = FR_poly_hi, FR_poly_lo
1244 //
1245 //    Create the FR for a binary "or"
1246 //    Y_lo = poly_hi + poly_lo
1247 //
1248 // (p0)  for FR_dummy = FR_Y_lo,FR_dummy ;;
1249 //
1250 //    Turn the lsb of Y_lo ON
1251 //
1252 // (p0)  fmerge.se FR_Y_lo =  FR_Y_lo,FR_dummy ;;
1253 //
1254 //    Merge the new lsb into Y_lo, for alone doesn't
1255 //
1256 (p0)  br.cond.sptk LOGL_main ;;
1257 }
1258 L(log1pl_near):
1259 { .mmi
1260         nop.m 999
1261         nop.m 999
1262 //    /*******************************************************/
1263 //    /*********** Branch log1pl_near  ************************/
1264 //    /*******************************************************/
1265 (p0)  addl GR_Table_Base = @ltoff(Constants_P#),gp ;;
1266 }
1267 { .mmi
1268       nop.m 999
1269       ld8    GR_Table_Base = [GR_Table_Base]
1270       nop.i 999
1271 };;
1272 //
1273 //    Load base address of poly. coeff.
1274 //
1275 { .mmb
1276 (p0)  add GR_Table_ptr = 0x40,GR_Table_Base
1277 //
1278 //    Address tables with separate pointers
1279 //
1280 (p0)  ldfe FR_P8 = [GR_Table_Base],16
1281         nop.b 999 ;;
1282 }
1283 { .mmb
1284 (p0)  ldfe FR_P4 = [GR_Table_ptr],16
1285 //
1286 //    Load P4
1287 //    Load P8
1288 //
1289 (p0)  ldfe FR_P7 = [GR_Table_Base],16
1290         nop.b 999 ;;
1291 }
1292 { .mmf
1293 (p0)  ldfe FR_P3 = [GR_Table_ptr],16
1294 //
1295 //    Load P3
1296 //    Load P7
1297 //
1298 (p0)  ldfe FR_P6 = [GR_Table_Base],16
1299 (p0)  fmpy.s1 FR_wsq = FR_W, FR_W ;;
1300 }
1301 { .mfi
1302 (p0)  ldfe FR_P2 = [GR_Table_ptr],16
1303         nop.f 999
1304         nop.i 999 ;;
1305 }
1306 { .mfi
1307         nop.m 999
1308 (p0)  fma.s1 FR_Y_hi = FR_W, FR_P4, FR_P3
1309         nop.i 999
1310 }
1311 //
1312 //    Load P2
1313 //    Load P6
1314 //    Wsq = w * w
1315 //    Y_hi = p4 * w + p3
1316 //
1317 { .mfi
1318 (p0)  ldfe FR_P5 = [GR_Table_Base],16
1319 (p0)  fma.s1 FR_Y_lo = FR_W, FR_P8, FR_P7
1320         nop.i 999 ;;
1321 }
1322 { .mfi
1323 (p0)  ldfe FR_P1 = [GR_Table_ptr],16
1324 //
1325 //    Load P1
1326 //    Load P5
1327 //    Y_lo = p8 * w + P7
1328 //
1329 (p0)  fmpy.s1 FR_w4 = FR_wsq, FR_wsq
1330         nop.i 999 ;;
1331 }
1332 { .mfi
1333         nop.m 999
1334 (p0)  fma.s1 FR_Y_hi = FR_W, FR_Y_hi, FR_P2
1335         nop.i 999
1336 }
1337 { .mfi
1338         nop.m 999
1339 (p0)  fma.s1 FR_Y_lo = FR_W, FR_Y_lo, FR_P6
1340 (p0)  add GR_Perturb = 0x1, r0 ;;
1341 }
1342 { .mfi
1343         nop.m 999
1344 //
1345 //    w4 = w2 * w2
1346 //    Y_hi = y_hi * w + p2
1347 //    Y_lo = y_lo * w + p6
1348 //    Create perturbation bit
1349 //
1350 (p0)  fmpy.s1 FR_w6 = FR_w4, FR_wsq
1351         nop.i 999 ;;
1352 }
1353 { .mfi
1354         nop.m 999
1355 (p0)  fma.s1 FR_Y_hi = FR_W, FR_Y_hi, FR_P1
1356         nop.i 999
1357 }
1358 //
1359 //    Y_hi = y_hi * w + p1
1360 //    w6 = w4 * w2
1361 //
1362 { .mfi
1363 (p0)  setf.sig FR_Q4 = GR_Perturb
1364 (p0)  fma.s1 FR_Y_lo = FR_W, FR_Y_lo, FR_P5
1365         nop.i 999 ;;
1366 }
1367 { .mfi
1368         nop.m 999
1369 (p0)  fma.s1 FR_dummy = FR_wsq,FR_Y_hi, f0
1370         nop.i 999
1371 }
1372 { .mfi
1373         nop.m 999
1374 (p0)  fma.s1 FR_Y_hi = FR_W,f1,f0
1375         nop.i 999
1376 };;
1377 { .mfb
1378         nop.m 999
1379 //
1380 //    Y_hi = w
1381 //    Y_lo = y_lo * w + p5
1382 //
1383 (p0)  fma.s1 FR_Y_lo = FR_w6, FR_Y_lo,FR_dummy
1384 //
1385 //    Y_lo = y_lo * w6   + y_high order part.
1386 //
1387 //    performance
1388 //
1389 (p0)  br.cond.sptk LOGL_main ;;
1390 }
1391 L(log1pl_small):
1392 { .mmi
1393         nop.m 999
1394 //  /*******************************************************/
1395 //  /*********** Branch log1pl_small  ***********************/
1396 //  /*******************************************************/
1397 (p0)  addl GR_Table_Base = @ltoff(Constants_Threshold#),gp
1398 }
1399 { .mfi
1400       nop.m 999
1401 (p0)  mov FR_Em1 = FR_W
1402 (p0)  cmp.eq.unc  p7, p0 = r0, r0 ;;
1403 }
1404 { .mlx
1405       ld8    GR_Table_Base = [GR_Table_Base]
1406 (p0)  movl GR_Expo_Range = 0x0000000000000004 ;;
1407 }
1408 //
1409 //    Set Safe to true
1410 //    Set Expo_Range = 0 for single
1411 //    Set Expo_Range = 2 for double
1412 //    Set Expo_Range = 4 for double-extended
1413 //
1414 { .mmi
1415 (p0)  shladd GR_Table_Base = GR_Expo_Range,4,GR_Table_Base ;;
1416 (p0)  ldfe FR_Threshold = [GR_Table_Base],16
1417         nop.i 999
1418 }
1419 { .mlx
1420         nop.m 999
1421 (p0)  movl GR_Bias = 0x000000000000FF9B ;;
1422 }
1423 { .mfi
1424 (p0)  ldfe FR_Tiny = [GR_Table_Base],0
1425         nop.f 999
1426         nop.i 999 ;;
1427 }
1428 { .mfi
1429         nop.m 999
1430 (p0)  fcmp.gt.unc.s1 p13, p12 =  FR_abs_W, FR_Threshold
1431         nop.i 999 ;;
1432 }
1433 { .mfi
1434         nop.m 999
1435 (p13) fnmpy.s1 FR_Y_lo = FR_W, FR_W
1436         nop.i 999
1437 }
1438 { .mfi
1439         nop.m 999
1440 (p13) fadd FR_SCALE = f0, f1
1441         nop.i 999 ;;
1442 }
1443 { .mfi
1444         nop.m 999
1445 (p12) fsub.s1 FR_Y_lo = f0, FR_Tiny
1446 (p12) cmp.ne.unc  p7, p0 = r0, r0
1447 }
1448 { .mfi
1449 (p12) setf.exp FR_SCALE = GR_Bias
1450         nop.f 999
1451         nop.i 999 ;;
1452 }
1453 { .mfb
1454         nop.m 999
1455 //
1456 //    Set p7 to SAFE = FALSE
1457 //    Set Scale = 2^-100
1458 //
1459 (p0)  fma.s0 f8 = FR_Y_lo,FR_SCALE,FR_Y_hi
1460 (p0)  br.ret.sptk   b0 ;;
1461 }
1462 L(LOGL_64_one):
1463 { .mfb
1464         nop.m 999
1465 (p0)  fmpy.s0 f8 = FR_Input_X, f0
1466 (p0)  br.ret.sptk   b0 ;;
1467 }
1468 //
1469 //    Raise divide by zero for +/-0 input.
1470 //
1471 L(LOGL_64_zero):
1472 { .mfi
1473 (p0)  mov   GR_Parameter_TAG = 0
1474 //
1475 //    If we have logl(1), log10l(1) or log1pl(0), return 0.
1476 //
1477 (p0)  fsub.s0 FR_Output_X_tmp = f0, f1
1478         nop.i 999 ;;
1479 }
1480 { .mii
1481 (p14) mov   GR_Parameter_TAG = 6
1482         nop.i 999 ;;
1483 (p15) mov   GR_Parameter_TAG = 138 ;;
1484 }
1485 { .mfb
1486         nop.m 999
1487 (p0)  frcpa.s0 FR_Output_X_tmp, p8 =  FR_Output_X_tmp, f0
1488 (p0)  br.cond.sptk __libm_error_region ;;
1489 }
1490 { .mfb
1491         nop.m 999
1492 //
1493 //    Report that logl(0) computed
1494 //     { .mfb
1495 (p0)  mov   FR_Input_X     = FR_Output_X_tmp
1496 (p0)  br.ret.sptk   b0 ;;
1497 }
1498
1499 L(LOGL_64_special):
1500 { .mfi
1501         nop.m 999
1502 //
1503 //    Return -Inf or value from handler.
1504 //
1505 (p0)  fclass.m.unc p7, p0 =  FR_Input_X, 0x1E1
1506         nop.i 999 ;;
1507 }
1508 { .mfb
1509         nop.m 999
1510 //
1511 //    Check for Natval, QNan, SNaN, +Inf
1512 //
1513 (p7)  fmpy.s0 f8 =  FR_Input_X, f1
1514 //
1515 //    For SNaN raise invalid and return QNaN.
1516 //    For QNaN raise invalid and return QNaN.
1517 //    For +Inf return +Inf.
1518 //
1519 (p7)  br.ret.sptk   b0 ;;
1520 }
1521 //
1522 //    For -Inf raise invalid and return QNaN.
1523 //
1524 { .mii
1525 (p0)  mov   GR_Parameter_TAG = 1
1526         nop.i 999 ;;
1527 (p14) mov   GR_Parameter_TAG = 7 ;;
1528 }
1529 { .mfi
1530 (p15) mov   GR_Parameter_TAG = 139
1531         nop.f 999
1532         nop.i 999 ;;
1533 }
1534 { .mfb
1535         nop.m 999
1536 (p0)  fmpy.s0 FR_Output_X_tmp =  FR_Input_X, f0
1537 (p0)  br.cond.sptk __libm_error_region ;;
1538 }
1539 //
1540 //    Report that logl(-Inf) computed
1541 //    Report that log10l(-Inf) computed
1542 //    Report that log1p(-Inf) computed
1543 //
1544 { .mfb
1545       nop.m 0
1546 (p0)  mov   FR_Input_X     = FR_Output_X_tmp
1547 (p0)  br.ret.sptk   b0 ;;
1548 }
1549 L(LOGL_64_unsupported):
1550 { .mfb
1551         nop.m 999
1552 //
1553 //    Return generated NaN or other value .
1554 //
1555 (p0)  fmpy.s0 f8 = FR_Input_X, f0
1556 (p0)  br.ret.sptk   b0 ;;
1557 }
1558 L(LOGL_64_negative):
1559 { .mfi
1560         nop.m 999
1561 //
1562 //    Deal with x < 0 in a special way
1563 //
1564 (p0)  frcpa.s0 FR_Output_X_tmp, p8 =  f0, f0
1565 //
1566 //    Deal with x < 0 in a special way - raise
1567 //    invalid and produce QNaN indefinite.
1568 //
1569 (p0)  mov   GR_Parameter_TAG = 1 ;;
1570 }
1571 { .mii
1572 (p14) mov   GR_Parameter_TAG = 7
1573         nop.i 999 ;;
1574 (p15) mov   GR_Parameter_TAG = 139
1575 }
1576 .endp log1pl
1577 ASM_SIZE_DIRECTIVE(log1pl)
1578
1579 .proc __libm_error_region
1580 __libm_error_region:
1581 .prologue
1582 { .mfi
1583         add   GR_Parameter_Y=-32,sp             // Parameter 2 value
1584         nop.f 0
1585 .save   ar.pfs,GR_SAVE_PFS
1586         mov  GR_SAVE_PFS=ar.pfs                 // Save ar.pfs
1587 }
1588 { .mfi
1589 .fframe 64
1590         add sp=-64,sp                           // Create new stack
1591         nop.f 0
1592         mov GR_SAVE_GP=gp                       // Save gp
1593 };;
1594 { .mmi
1595         stfe [GR_Parameter_Y] = FR_Y,16         // Save Parameter 2 on stack
1596         add GR_Parameter_X = 16,sp              // Parameter 1 address
1597 .save   b0, GR_SAVE_B0
1598         mov GR_SAVE_B0=b0                       // Save b0
1599 };;
1600 .body
1601 { .mib
1602         stfe [GR_Parameter_X] = FR_X            // Store Parameter 1 on stack
1603         add   GR_Parameter_RESULT = 0,GR_Parameter_Y
1604         nop.b 0                                 // Parameter 3 address
1605 }
1606 { .mib
1607         stfe [GR_Parameter_Y] = FR_RESULT      // Store Parameter 3 on stack
1608         add   GR_Parameter_Y = -16,GR_Parameter_Y
1609         br.call.sptk b0=__libm_error_support#  // Call error handling function
1610 };;
1611 { .mmi
1612         nop.m 0
1613         nop.m 0
1614         add   GR_Parameter_RESULT = 48,sp
1615 };;
1616 { .mmi
1617         ldfe  f8 = [GR_Parameter_RESULT]       // Get return result off stack
1618 .restore sp
1619         add   sp = 64,sp                       // Restore stack pointer
1620         mov   b0 = GR_SAVE_B0                  // Restore return address
1621 };;
1622 { .mib
1623         mov   gp = GR_SAVE_GP                  // Restore gp
1624         mov   ar.pfs = GR_SAVE_PFS             // Restore ar.pfs
1625         br.ret.sptk     b0                     // Return
1626 };;
1627
1628 .endp __libm_error_region
1629 ASM_SIZE_DIRECTIVE(__libm_error_region)
1630
1631 .proc LOGL_main
1632 LOGL_main:
1633 { .mfi
1634         nop.m 999
1635 //
1636 //    kernel_log_64 computes ln(X + E)
1637 //
1638 (p7)  fadd.s0 FR_Input_X = FR_Y_lo,FR_Y_hi
1639       nop.i 0
1640 }
1641 { .mmi
1642       nop.m 999
1643       nop.m 999
1644 (p14) addl GR_Table_Base = @ltoff(Constants_1_by_LN10#),gp ;;
1645 }
1646 { .mmi
1647       nop.m 999
1648 (p14) ld8    GR_Table_Base = [GR_Table_Base]
1649       nop.i 999
1650 };;
1651
1652 { .mmi
1653 (p14) ldfe FR_1LN10_hi = [GR_Table_Base],16 ;;
1654 (p14) ldfe FR_1LN10_lo = [GR_Table_Base]
1655         nop.i 999 ;;
1656 }
1657 { .mfi
1658         nop.m 999
1659 (p14) fmpy.s1 FR_Output_X_tmp = FR_Y_lo,FR_1LN10_hi
1660         nop.i 999 ;;
1661 }
1662 { .mfi
1663         nop.m 999
1664 (p14) fma.s1  FR_Output_X_tmp = FR_Y_hi,FR_1LN10_lo,FR_Output_X_tmp
1665         nop.i 999 ;;
1666 }
1667 { .mfb
1668         nop.m 999
1669 (p14) fma.s0 FR_Input_X = FR_Y_hi,FR_1LN10_hi,FR_Output_X_tmp
1670 (p0)  br.ret.sptk   b0 ;;
1671 }
1672 .endp LOGL_main
1673 ASM_SIZE_DIRECTIVE(LOGL_main)
1674
1675 .type   __libm_error_support#,@function
1676 .global __libm_error_support#