sysdeps/powerpc/powerpc32/fpu/s_lround.S

   1 /* lround function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata
  23         .align 3
  24         .type   NEGZERO.0,@object
  25         .size   NEGZERO.0,8
  26 NEGZERO.0:
  27         .long 0x00000000
  28         .long 0
  29         .type   POINTFIVE.0,@object
  30         .size   POINTFIVE.0,8
  31 POINTFIVE.0:
  32         .long 0x3fe00000
  33         .long 0
  34
  35         .section        .rodata.cst8,"aM",@progbits,8
  36         .align 3
  37 .LC0:   /* 0.0 */
  38         .long 0x00000000
  39         .long 0
  40 .LC1:   /* 0.5 */
  41         .long 0x3fe00000
  42         .long 0
  43
  44         .section        ".text"
  45
  46 /* long [r3] lround (float x [fp1])
  47    IEEE 1003.1 lround function.  IEEE specifies "round to the nearest
  48    integer value, rounding halfway cases away from zero, regardless of
  49    the current rounding mode."  However PowerPC Architecture defines
  50    "round to Nearest" as "Choose the best approximation. In case of a
  51    tie, choose the one that is even (least significant bit o).".
  52    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  53    "round toward Zero" mode and round by adding +-0.5 before rounding
  54    to the integer value.  */
  55
  56 ENTRY (__lround)
  57 #ifdef SHARED
  58         mflr    r11
  59         bl      _GLOBAL_OFFSET_TABLE_@local-4
  60         mflr    r10
  61         lwz     r9,.LC0@got(10)
  62         mtlr    r11
  63         lfd     fp12,0(r9)
  64 #else
  65         lis     r9,.LC0@ha
  66         lfd     fp12,.LC0@l(r9)
  67 #endif
  68 #ifdef SHARED
  69         lwz     r9,.LC1@got(10)
  70         lfd     fp10,0(r9)
  71 #else
  72         lis     r9,.LC1@ha
  73         lfd     fp10,.LC1@l(r9)
  74 #endif
  75         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  76         ble-    cr6,.L4
  77         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  78 .L9:
  79         fctiwz  fp2,fp1         /* Convert To Integer DW lround toward 0.  */
  80         stfd    fp2,-8(r1)
  81         nop     /* Insure the following load is in a different dispatch group */
  82         nop     /* to avoid pipe stall on POWER4&5.  */
  83         nop
  84         lwz     r3,-4(r1)
  85         blr
  86 .L4:
  87         fsub    fp1,fp1,fp10    /* x-= 0.5;  */
  88         b       .L9
  89         END (__lround)
  90
  91 strong_alias (__lround, __lround)
  92 weak_alias (__lround, lround)
  93
  94 strong_alias (__lround, __lroundf)
  95 weak_alias (__lround, lroundf)
  96
  97 #ifdef NO_LONG_DOUBLE
  98 weak_alias (__lround, lroundl)
  99 strong_alias (__lround, __lroundl)
 100 #endif