sysdeps/powerpc/powerpc32/fpu/s_truncf.S

   1 /* truncf function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006, 2011 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        .rodata.cst4,"aM",@progbits,4
  22         .align  2
  23 .LC0:   /* 2**23 */
  24         .long 0x4b000000
  25
  26 /* float [fp1] truncf (float x [fp1])
  27    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  28    value, in floating format, nearest to but no larger in magnitude
  29    then the argument."
  30    We set "round toward Zero" mode and trunc by adding +-2**23 then
  31    subtracting +-2**23.  */
  32
  33         .section        ".text"
  34 ENTRY (__truncf)
  35         mffs    fp11            /* Save current FPU rounding mode.  */
  36 #ifdef SHARED
  37         mflr    r11
  38         cfi_register(lr,r11)
  39         SETUP_GOT_ACCESS(r9,got_label)
  40         addis   r9,r9,.LC0-got_label@ha
  41         lfs     fp13,.LC0-got_label@l(r9)
  42         mtlr    r11
  43         cfi_same_value (lr)
  44 #else
  45         lis     r9,.LC0@ha
  46         lfs     fp13,.LC0@l(r9)
  47 #endif
  48         fabs    fp0,fp1
  49         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  50         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  51         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  52         bnllr-  cr7
  53         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  54         ble-    cr6,.L4
  55         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  56         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  57         fabs    fp1,fp1         /* if (x == 0.0)  */
  58                                 /* x = 0.0; */
  59         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  60         blr
  61 .L4:
  62         bge-    cr6,.L9         /* if (x < 0.0)  */
  63         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  64         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  65         fnabs   fp1,fp1         /* if (x == 0.0)  */
  66                                 /* x = -0.0; */
  67 .L9:
  68         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  69         blr
  70         END (__truncf)
  71
  72 weak_alias (__truncf, truncf)
  73