sysdeps/powerpc/powerpc32/fpu/s_truncf.S

   1 /* truncf function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26
  27 /* float [fp1] truncf (float x [fp1])
  28    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  29    value, in floating format, nearest to but no larger in magnitude
  30    then the argument."
  31    We set "round toward Zero" mode and trunc by adding +-2**23 then
  32    subtracting +-2**23.  */
  33
  34         .section        ".text"
  35 ENTRY (__truncf)
  36         mffs    fp11            /* Save current FPU rounding mode.  */
  37 #ifdef SHARED
  38         mflr    r11
  39 # ifdef HAVE_ASM_PPC_REL16
  40         bcl     20,31,1f
  41 1:      mflr    r9
  42         addis   r9,r9,.LC0-1b@ha
  43         mtlr    r11
  44         lfs     fp13,.LC0-1b@l(r9)
  45 # else
  46         bl      _GLOBAL_OFFSET_TABLE_@local-4
  47         mflr    r10
  48         lwz     r9,.LC0@got(10)
  49         mtlr    r11
  50         lfs     fp13,0(r9)
  51 # endif
  52 #else
  53         lis     r9,.LC0@ha
  54         lfs     fp13,.LC0@l(r9)
  55 #endif
  56         fabs    fp0,fp1
  57         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  58         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  59         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  60         bnllr-  cr7
  61         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  62         ble-    cr6,.L4
  63         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  64         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  65         fabs    fp1,fp1         /* if (x == 0.0)  */
  66                                 /* x = 0.0; */
  67         mtfsf   0x01,fp11       /* restore previous truncing mode.  */
  68         blr
  69 .L4:
  70         bge-    cr6,.L9         /* if (x < 0.0)  */
  71         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  72         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  73         fnabs   fp1,fp1         /* if (x == 0.0)  */
  74                                 /* x = -0.0; */
  75 .L9:
  76         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  77         blr
  78         END (__truncf)
  79
  80 weak_alias (__truncf, truncf)
  81