sysdeps/powerpc/powerpc32/power7/memchr.S

   1 /* Optimized memchr implementation for PowerPC32/POWER7 using cmpb insn.
   2    Copyright (C) 2010 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <bp-sym.h>
  22 #include <bp-asm.h>
  23
  24 /* int [r3] memchr (char *s [r3], int byte [r4], int size [r5])  */
  25         .machine  power7
  26 ENTRY (BP_SYM (__memchr))
  27         CALL_MCOUNT
  28         dcbt    0,r3
  29         clrrwi  r8,r3,2
  30         rlwimi  r4,r4,8,16,23
  31         rlwimi  r4,r4,16,0,15
  32         add     r7,r3,r5      /* Calculate the last acceptable address.  */
  33         cmplwi  r5,16
  34         ble     L(small_range)
  35
  36         cmplw   cr7,r3,r7     /* Is the address equal or less than r3?  If
  37                                  it's equal or less, it means size is either 0
  38                                  or a negative number.  */
  39         ble     cr7,L(proceed)
  40
  41         li      r7,-1         /* Make r11 the biggest if r4 <= 0.  */
  42 L(proceed):
  43         rlwinm  r6,r3,3,27,28 /* Calculate padding.  */
  44         lwz     r12,0(r8)     /* Load word from memory.  */
  45         cmpb    r10,r12,r4    /* Check for BYTE's in WORD1.  */
  46         slw     r10,r10,r6
  47         srw     r10,r10,r6
  48         cmplwi  cr7,r10,0     /* If r10 == 0, no BYTE's have been found.  */
  49         bne     cr7,L(done)
  50
  51         /* Are we done already?  */
  52         addi    r9,r8,4
  53         cmplw   cr6,r9,r7
  54         bge     cr6,L(null)
  55
  56         mtcrf   0x01,r8
  57         /* Are we now aligned to a doubleword boundary?  If so, skip to
  58            the main loop.  Otherwise, go through the alignment code.  */
  59
  60         bt      29,L(loop_setup)
  61
  62         /* Handle WORD2 of pair.  */
  63         lwzu    r12,4(r8)
  64         cmpb    r10,r12,r4
  65         cmplwi  cr7,r10,0
  66         bne     cr7,L(done)
  67
  68         /* Are we done already?  */
  69         addi    r9,r8,4
  70         cmplw   cr6,r9,r7
  71         bge     cr6,L(null)
  72
  73 L(loop_setup):
  74         sub     r5,r7,r9
  75         srwi    r6,r5,3       /* Number of loop iterations.  */
  76         mtctr   r6            /* Setup the counter.  */
  77         b       L(loop)
  78         /* Main loop to look for BYTE backwards in the string.  Since
  79            it's a small loop (< 8 instructions), align it to 32-bytes.  */
  80         .p2align  5
  81 L(loop):
  82         /* Load two words, compare and merge in a
  83            single register for speed.  This is an attempt
  84            to speed up the byte-checking process for bigger strings.  */
  85
  86         lwz     r12,4(r8)
  87         lwzu    r11,8(r8)
  88         cmpb    r10,r12,r4
  89         cmpb    r9,r11,r4
  90         or      r5,r9,r10     /* Merge everything in one word.  */
  91         cmplwi  cr7,r5,0
  92         bne     cr7,L(found)
  93         bdnz    L(loop)
  94         /* We're here because the counter reached 0, and that means we
  95            didn't have any matches for BYTE in the whole range.  Just
  96            return the original range.  */
  97         addi    r9,r8,4
  98         cmplw   cr6,r9,r7
  99         blt     cr6,L(loop_small)
 100         b       L(null)
 101
 102         /* OK, one (or both) of the words contains BYTE.  Check
 103            the first word and decrement the address in case the first
 104            word really contains BYTE.  */
 105         .align  4
 106 L(found):
 107         cmplwi  cr6,r10,0
 108         addi    r8,r8,-4
 109         bne     cr6,L(done)
 110
 111         /* BYTE must be in the second word.  Adjust the address
 112            again and move the result of cmpb to r10 so we can calculate the
 113            pointer.  */
 114
 115         mr      r10,r9
 116         addi    r8,r8,4
 117
 118         /* r10 has the output of the cmpb instruction, that is, it contains
 119            0xff in the same position as BYTE in the original
 120            word from the string.  Use that to calculate the pointer.
 121            We need to make sure BYTE is *before* the end of the
 122            range.  */
 123 L(done):
 124         cntlzw  r0,r10        /* Count leading zeroes before the match.  */
 125         srwi    r0,r0,3       /* Convert leading zeroes to bytes.  */
 126         add     r3,r8,r0
 127         cmplw   r3,r7
 128         bge     L(null)
 129         blr
 130
 131         .align  4
 132 L(null):
 133         li      r3,0
 134         blr
 135
 136 /* Deals with size <= 16.  */
 137         .align  4
 138 L(small_range):
 139         cmplwi  r5,0
 140         beq     L(null)
 141
 142         rlwinm  r6,r3,3,27,28 /* Calculate padding.  */
 143         lwz     r12,0(r8)     /* Load word from memory.  */
 144         cmpb    r10,r12,r4    /* Check for BYTE in DWORD1.  */
 145         slw     r10,r10,r6
 146         srw     r10,r10,r6
 147         cmplwi  cr7,r10,0
 148         bne     cr7,L(done)
 149
 150         /* Are we done already?  */
 151         addi    r9,r8,4
 152         cmplw   r9,r7
 153         bge     L(null)
 154         b       L(loop_small)
 155
 156         .p2align  5
 157 L(loop_small):
 158         lwzu    r12,4(r8)
 159         cmpb    r10,r12,r4
 160         addi    r9,r8,4
 161         cmplwi  cr6,r10,0
 162         bne     cr6,L(done)
 163         cmplw   r9,r7
 164         bge     L(null)
 165         b       L(loop_small)
 166
 167 END (BP_SYM (__memchr))
 168 weak_alias (BP_SYM (__memchr), BP_SYM(memchr))
 169 libc_hidden_builtin_def (memchr)