sysdeps/powerpc/powerpc32/submul_1.S

   1 /* Multiply a limb vector by a single limb, for PowerPC.
   2    Copyright (C) 1993-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <bp-sym.h>
  21 #include <bp-asm.h>
  22
  23 /* mp_limb_t mpn_submul_1 (mp_ptr res_ptr, mp_srcptr s1_ptr,
  24                            mp_size_t s1_size, mp_limb_t s2_limb)
  25    Calculate res-s1*s2 and put result back in res; return carry.  */
  26
  27 ENTRY (BP_SYM (__mpn_submul_1))
  28 #if __BOUNDED_POINTERS__
  29         slwi r10,r5,2           /* convert limbs to bytes */
  30         CHECK_BOUNDS_BOTH_WIDE (r3, r8, r9, r10)
  31         CHECK_BOUNDS_BOTH_WIDE (r4, r8, r9, r10)
  32 #endif
  33         mtctr   r5
  34
  35         lwz     r0,0(r4)
  36         mullw   r7,r0,r6
  37         mulhwu  r10,r0,r6
  38         lwz     r9,0(r3)
  39         subf    r8,r7,r9
  40         addc    r7,r7,r8                # invert cy (r7 is junk)
  41         addi    r3,r3,-4                # adjust res_ptr
  42         bdz     L(1)
  43
  44 L(0):   lwzu    r0,4(r4)
  45         stwu    r8,4(r3)
  46         mullw   r8,r0,r6
  47         adde    r7,r8,r10
  48         mulhwu  r10,r0,r6
  49         lwz     r9,4(r3)
  50         addze   r10,r10
  51         subf    r8,r7,r9
  52         addc    r7,r7,r8                # invert cy (r7 is junk)
  53         bdnz    L(0)
  54
  55 L(1):   stw     r8,4(r3)
  56         addze   r3,r10
  57         blr
  58 END (BP_SYM (__mpn_submul_1))