sysdeps/powerpc/powerpc64/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This has been coded in assembler because GCC makes such a mess of it
  20    when it's coded in C.  */
  21
  22 #include <sysdep.h>
  23 #include <math_ldbl_opt.h>
  24
  25         .section        ".toc","aw"
  26 .LC0:   /* 2**52 */
  27         .tc FD_43300000_0[TC],0x4330000000000000
  28         .section        ".text"
  29
  30 EALIGN (__rint, 4, 0)
  31         CALL_MCOUNT 0
  32         lfd     fp13,.LC0@toc(2)
  33         fabs    fp0,fp1
  34         fsub    fp12,fp13,fp13  /* generate 0.0  */
  35         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  36         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  37         bnl     cr7,.L10
  38         bng     cr6,.L4
  39         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  40         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  41         fabs    fp1,fp1         /* if (x == 0.0)  */
  42         blr                     /* x = 0.0; */
  43 .L4:
  44         bnllr   cr6             /* if (x < 0.0)  */
  45         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  46         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  47         fnabs   fp1,fp1         /* if (x == 0.0)  */
  48         blr                     /* x = -0.0; */
  49 .L10:
  50         /* Ensure sNaN input is converted to qNaN.  */
  51         fcmpu   cr7,fp1,fp1
  52         beqlr   cr7
  53         fadd    fp1,fp1,fp1
  54         blr
  55         END (__rint)
  56
  57 weak_alias (__rint, rint)
  58
  59 #ifdef NO_LONG_DOUBLE
  60 weak_alias (__rint, rintl)
  61 strong_alias (__rint, __rintl)
  62 #endif
  63 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  64 compat_symbol (libm, __rint, rintl, GLIBC_2_0)
  65 #endif