sysdeps/powerpc/powerpc64/fpu/s_round.S

   1 /* round function.  PowerPC64 version.
   2    Copyright (C) 2004-2019 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21 #include <libm-alias-double.h>
  22
  23         .section        ".toc","aw"
  24 .LC0:   /* 2**52 */
  25         .tc FD_43300000_0[TC],0x4330000000000000
  26 .LC1:   /* 0.5 */
  27         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  28         .section        ".text"
  29
  30 /* double [fp1] round (double x [fp1])
  31    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  32    integer value, rounding halfway cases away from zero, regardless of
  33    the current rounding mode."  However PowerPC Architecture defines
  34    "Round to Nearest" as "Choose the best approximation. In case of a
  35    tie, choose the one that is even (least significant bit o).".
  36    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  37    "Round toward Zero" mode and round by adding +-0.5 before rounding
  38    to the integer value.  */
  39
  40 ENTRY (__round, 4)
  41         CALL_MCOUNT 0
  42         lfd     fp13,.LC0@toc(2)
  43         fabs    fp0,fp1
  44         fsub    fp12,fp13,fp13  /* generate 0.0  */
  45         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  46         mffs    fp11            /* Save current FPU rounding mode and
  47                                    "inexact" state.  */
  48         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  49         bnl-    cr7,.L10
  50         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  51         lfd     fp10,.LC1@toc(2)
  52         ble-    cr6,.L4
  53         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  54         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  55         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  56         fabs    fp1,fp1         /* if (x == 0.0)  */
  57                                 /* x = 0.0; */
  58         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  59                                    "inexact" state.  */
  60         blr
  61 .L4:
  62         fsub    fp9,fp1,fp10    /* x+= 0.5;  */
  63         bge-    cr6,.L9         /* if (x < 0.0)  */
  64         fsub    fp1,fp9,fp13    /* x-= TWO52;  */
  65         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  66         fnabs   fp1,fp1         /* if (x == 0.0)  */
  67                                 /* x = -0.0; */
  68 .L9:
  69         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  70                                    "inexact" state.  */
  71         blr
  72 .L10:
  73         /* Ensure sNaN input is converted to qNaN.  */
  74         fcmpu   cr7,fp1,fp1
  75         beqlr   cr7
  76         fadd    fp1,fp1,fp1
  77         blr
  78         END (__round)
  79
  80 libm_alias_double (__round, round)