sysdeps/powerpc/powerpc64/power7/fpu/s_finite.S

   1 /* finite().  PowerPC64/POWER7 version.
   2    Copyright (C) 2010-2014 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23 /* int __finite(x)  */
  24         .section    ".toc","aw"
  25 .LC0:   /* 1.0 */
  26         .tc         FD_ONE[TC],0x3ff0000000000000
  27         .section    ".text"
  28         .type       __finite, @function
  29         .machine    power7
  30 EALIGN (__finite, 4, 0)
  31         CALL_MCOUNT 0
  32         lfd     fp0,.LC0@toc(r2)
  33         ftdiv   cr7,fp1,fp0
  34         li      r3,1
  35         bflr    30
  36
  37         /* If we are here, we either have +/-INF,
  38         NaN or denormal.  */
  39
  40         stfd    fp1,-16(r1)   /* Transfer FP to GPR's.  */
  41         ori     2,2,0         /* Force a new dispatch group.  */
  42         lhz     r4,-16+HISHORT(r1)  /* Fetch the upper 16 bits of the FP value
  43                                     (biased exponent and sign bit).  */
  44         clrlwi  r4,r4,17      /* r4 = abs(r4).  */
  45         cmpwi   cr7,r4,0x7ff0 /* r4 == 0x7ff0?  */
  46         bltlr   cr7           /* LT means finite, other non-finite.  */
  47         li      r3,0
  48         blr
  49         END (__finite)
  50
  51 hidden_def (__finite)
  52 weak_alias (__finite, finite)
  53
  54 /* It turns out that the 'double' version will also always work for
  55    single-precision.  */
  56 strong_alias (__finite, __finitef)
  57 hidden_def (__finitef)
  58 weak_alias (__finitef, finitef)
  59
  60 #ifdef IS_IN_libm
  61 # if LONG_DOUBLE_COMPAT (libm, GLIBC_2_0)
  62 compat_symbol (libm, __finite, __finitel, GLIBC_2_0)
  63 compat_symbol (libm, finite, finitel, GLIBC_2_0)
  64 # endif
  65 #else
  66 # if LONG_DOUBLE_COMPAT (libc, GLIBC_2_0)
  67 compat_symbol (libc, __finite, __finitel, GLIBC_2_0);
  68 compat_symbol (libc, finite, finitel, GLIBC_2_0);
  69 # endif
  70 #endif