sysdeps/powerpc/powerpc64/power7/strcasecmp.S

   1 /* Optimized strcasecmp implementation for PowerPC64.
   2    Copyright (C) 2011 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <bp-sym.h>
  22 #include <bp-asm.h>
  23 #include <locale-defines.h>
  24
  25 /* int [r3] strcasecmp (const char *s1 [r3], const char *s2 [r4] )
  26
  27    or if defined USE_IN_EXTENDED_LOCALE_MODEL:
  28
  29    int [r3] strcasecmp_l (const char *s1 [r3], const char *s2 [r4],
  30                           __locale_t loc [r5]) */
  31
  32 #ifndef STRCMP
  33 # define __STRCMP __strcasecmp
  34 # define STRCMP   strcasecmp
  35 #endif
  36
  37 ENTRY (BP_SYM (__STRCMP))
  38         CALL_MCOUNT 2
  39
  40 #define rRTN    r3      /* Return value */
  41 #define rSTR1   r5      /* 1st string */
  42 #define rSTR2   r4      /* 2nd string */
  43 #define rLOCARG r5      /* 3rd argument: locale_t */
  44 #define rCHAR1  r6      /* Byte readed from 1st string */
  45 #define rCHAR2  r7      /* Byte readed from 2nd string */
  46 #define rADDR1  r8      /* Address of tolower(rCHAR1) */
  47 #define rADDR2  r12     /* Address of tolower(rCHAR2) */
  48 #define rLWR1   r8      /* Word tolower(rCHAR1) */
  49 #define rLWR2   r12     /* Word tolower(rCHAR2) */
  50 #define rTMP    r9
  51 #define rLOC    r11     /* Default locale address */
  52
  53         cmpd    cr7, r3, r4
  54 #ifndef USE_IN_EXTENDED_LOCALE_MODEL
  55         ld      rTMP, __libc_tsd_LOCALE@got@tprel(r2)
  56         add     rLOC, rTMP, __libc_tsd_LOCALE@tls
  57         ld      rLOC, 0(rLOC)
  58 #else
  59         mr      rLOC, rLOCARG
  60 #endif
  61         ld      rLOC, LOCALE_CTYPE_TOLOWER(rLOC)
  62         mr      rSTR1, rRTN
  63         li      rRTN, 0
  64         beqlr   cr7
  65
  66
  67         /* Unrolling loop for POWER: loads are done with 'lbz' plus
  68         offset and string descriptors are only updated in the end
  69         of loop unrolling. */
  70
  71         lbz     rCHAR1, 0(rSTR1)        /* Load char from s1 */
  72         lbz     rCHAR2, 0(rSTR2)        /* Load char from s2 */
  73 L(loop):
  74         cmpdi   rCHAR1, 0               /* *s1 == '\0' ? */
  75         sldi    rADDR1, rCHAR1, 2       /* Calculate address for tolower(*s1) */
  76         sldi    rADDR2, rCHAR2, 2       /* Calculate address for tolower(*s2) */
  77         lwzx    rLWR1, rLOC, rADDR1     /* Load tolower(*s1) */
  78         lwzx    rLWR2, rLOC, rADDR2     /* Load tolower(*s2) */
  79         cmpw    cr1, rLWR1, rLWR2       /* r = tolower(*s1) == tolower(*s2) ? */
  80         crorc   4*cr1+eq,eq,4*cr1+eq    /* (*s1 != '\0') || (r == 1) */
  81         beq     cr1, L(done)
  82         lbz     rCHAR1, 1(rSTR1)
  83         lbz     rCHAR2, 1(rSTR2)
  84         cmpdi   rCHAR1, 0
  85         sldi    rADDR1, rCHAR1, 2
  86         sldi    rADDR2, rCHAR2, 2
  87         lwzx    rLWR1, rLOC, rADDR1
  88         lwzx    rLWR2, rLOC, rADDR2
  89         cmpw    cr1, rLWR1, rLWR2
  90         crorc   4*cr1+eq,eq,4*cr1+eq
  91         beq     cr1, L(done)
  92         lbz     rCHAR1, 2(rSTR1)
  93         lbz     rCHAR2, 2(rSTR2)
  94         cmpdi   rCHAR1, 0
  95         sldi    rADDR1, rCHAR1, 2
  96         sldi    rADDR2, rCHAR2, 2
  97         lwzx    rLWR1, rLOC, rADDR1
  98         lwzx    rLWR2, rLOC, rADDR2
  99         cmpw    cr1, rLWR1, rLWR2
 100         crorc   4*cr1+eq,eq,4*cr1+eq
 101         beq     cr1, L(done)
 102         lbz     rCHAR1, 3(rSTR1)
 103         lbz     rCHAR2, 3(rSTR2)
 104         cmpdi   rCHAR1, 0
 105         /* Increment both string descriptors */
 106         addi    rSTR1, rSTR1, 4
 107         addi    rSTR2, rSTR2, 4
 108         sldi    rADDR1, rCHAR1, 2
 109         sldi    rADDR2, rCHAR2, 2
 110         lwzx    rLWR1, rLOC, rADDR1
 111         lwzx    rLWR2, rLOC, rADDR2
 112         cmpw    cr1, rLWR1, rLWR2
 113         crorc   4*cr1+eq,eq,4*cr1+eq
 114         beq     cr1,L(done)
 115         lbz     rCHAR1, 0(rSTR1)        /* Load char from s1 */
 116         lbz     rCHAR2, 0(rSTR2)        /* Load char from s2 */
 117         b       L(loop)
 118 L(done):
 119         subf    r0, rLWR2, rLWR1
 120         extsw   rRTN, r0
 121         blr
 122 END (BP_SYM (__STRCMP))
 123
 124 weak_alias (BP_SYM (__STRCMP), BP_SYM (STRCMP))
 125 libc_hidden_builtin_def (__STRCMP)