sysdeps/s390/s390-32/start.S

   1 /* Startup code compliant to the ELF s390 ABI.
   2    Copyright (C) 2000-2019 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, see
  35    <http://www.gnu.org/licenses/>.  */
  36
  37 #include <sysdep.h>
  38
  39 /*
  40    This is the canonical entry point, usually the first thing in the text
  41    segment. Most registers' values are unspecified, except for:
  42
  43    %r14         Contains a function pointer to be registered with `atexit'.
  44                 This is how the dynamic linker arranges to have DT_FINI
  45                 functions called for shared libraries that have been loaded
  46                 before this code runs.
  47
  48    %r15         The stack contains the arguments and environment:
  49                 0(%r15)                 argc
  50                 4(%r15)                 argv[0]
  51                 ...
  52                 (4*argc)(%r15)          NULL
  53                 (4*(argc+1))(%r15)      envp[0]
  54                 ...
  55                                         NULL
  56 */
  57
  58         .text
  59         .globl _start
  60         .type _start,@function
  61 _start:
  62         cfi_startproc
  63         /* Mark r14 as undefined in order to stop unwinding here!  */
  64         cfi_undefined (r14)
  65
  66         /* Check if the kernel provides highgprs facility if needed by
  67            the binary.  */
  68
  69         lr      %r6,%r15
  70         la      %r6,4(%r6)     /* Skip the argument counter.  */
  71
  72 .L11:   l       %r5,0(%r6)     /* Skip the argument vector.  */
  73         la      %r6,4(%r6)
  74         ltr     %r5,%r5
  75         jne     .L11
  76
  77 .L12:   l       %r5,0(%r6)     /* Skip the environment vector.  */
  78         la      %r6,4(%r6)
  79         ltr     %r5,%r5
  80         jne     .L12
  81
  82         /* Usually the auxiliary vector can be expected directly after
  83            the environment variables.  But we have to skip extra zeros
  84            because the loader might have removed unsecure variables for
  85            setuid programs.  */
  86
  87 .L26:   l       %r5,0(%r6)
  88         la      %r6,4(%r6)
  89         ltr     %r5,%r5
  90         jz      .L26
  91
  92         ahi     %r6,-4
  93
  94         /* Obtain the needed values from the auxiliary vector.  */
  95
  96         lhi     %r7,16         /* AT_HWCAP */
  97         lhi     %r8,3          /* AT_PHDR */
  98         lhi     %r9,5          /* AT_PHNUM */
  99         lhi     %r2,4          /* AT_PHENT */
 100 .L13:   l       %r5,0(%r6)
 101         clr     %r5,%r7
 102         jne     .L15
 103         l       %r10,4(%r6)    /* r10 = AT_HWCAP value.  */
 104 .L15:   clr     %r5,%r8
 105         jne     .L16
 106         l       %r11,4(%r6)    /* r11 = AT_PHDR value.  */
 107 .L16:   clr     %r5,%r9
 108         jne     .L17
 109         l       %r12,4(%r6)    /* r12 = AT_PHNUM value.  */
 110 .L17:   clr     %r5,%r2
 111         jne     .L18
 112         l       %r0,4(%r6)     /* r0 = AT_PHENT value.  */
 113 .L18:   ltr     %r5,%r5
 114         la      %r6,8(%r6)
 115         jnz     .L13
 116
 117         /* Locate the ELF header by looking for the first PT_LOAD
 118            segment with a p_offset of zero.  */
 119
 120         lr      %r4,%r11       /* Backup AT_PHDR.  */
 121         lhi     %r7,1          /* PT_LOAD id */
 122         lhi     %r8,0
 123 .L19:   cl      %r7,0(%r4)     /* p_type == PT_LOAD? */
 124         jne     .L20
 125         cl      %r8,4(%r4)     /* p_offset == 0? */
 126         jne     .L20
 127         l       %r9,8(%r4)     /* r9 = PT_LOAD.p_vaddr <- ELF header address  */
 128         j       .L24
 129 .L20:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 130         brct    %r12,.L19
 131
 132         j       .+2            /* Trap, there must be such a phdr.  */
 133
 134 .L24:   lr      %r4,%r11       /* Backup AT_PHDR.  */
 135         lhi     %r2,6          /* PT_PHDR id */
 136 .L23:   cl      %r2,0(%r4)
 137         jne     .L22
 138         l       %r3,8(%r4)     /* r3 = PT_PHDR p_vaddr */
 139         j       .L25
 140 .L22:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 141         brct    %r12,.L23
 142
 143         j       .L14           /* No PT_PHDR found - skip checking.  */
 144
 145 .L25:   slr     %r11,%r3       /* AT_PHDR - PT_PHDR.p_vaddr (relocation offset)*/
 146         alr     %r9,%r11       /* PT_LOAD.p_vaddr += relocation offset */
 147
 148         l       %r5,36(%r9)    /* Load the e_flags field.  */
 149         tml     %r5,1
 150         jz      .L14           /* Binary does not require highgprs facility.  */
 151
 152         tml     %r10,512       /* Check the AT_HWCAP value.  */
 153         jz      2              /* Trap if no highgprs facility available.  */
 154 .L14:
 155
 156         /* Setup pointer to literal pool of _start */
 157         basr    %r13,0
 158 .L0:    ahi     %r13,.Llit-.L0
 159
 160         /* load argc and argv from stack */
 161         la      %r4,4(%r15)             # get argv
 162         l       %r3,0(%r15)             # get argc
 163
 164         /* align the stack to a double word boundary */
 165         lhi     %r0,-8
 166         nr      %r15,%r0
 167
 168         /* Setup a stack frame and a parameter area */
 169         ahi     %r15,-104               # make room on stack
 170         xc      0(4,%r15),0(%r15)       # clear back-chain
 171
 172         /* set up arguments for __libc_start_main:
 173            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
 174            Note that envp will be determined later in __libc_start_main
 175          */
 176         stm     %r14,%r15,96(%r15)      # store rtld_fini/stack_end to parameter area
 177         la      %r7,96(%r15)
 178         l       %r6,.L2-.Llit(%r13)     # load pointer to __libc_csu_fini
 179         l       %r5,.L1-.Llit(%r13)     # load pointer to __libc_csu_init
 180         l       %r2,.L3-.Llit(%r13)     # load pointer to main
 181         l       %r1,.L4-.Llit(%r13)     # load pointer to __libc_start_main
 182 #ifdef PIC
 183         l       %r12,.L5-.Llit(%r13)    # load .got pointer
 184         la      %r6,0(%r13,%r6)
 185         la      %r5,0(%r13,%r5)
 186         la      %r12,0(%r13,%r12)
 187         l       %r2,0(%r12,%r2)
 188         la      %r1,0(%r13,%r1)
 189 #endif
 190
 191         /* ok, now branch to the libc main routine */
 192         basr    %r14,%r1
 193
 194         /* crash if __libc_start_main returns */
 195         .word   0
 196
 197         cfi_endproc
 198 .Llit:
 199 #ifndef PIC
 200 .L1:    .long  __libc_csu_init
 201 .L2:    .long  __libc_csu_fini
 202 .L3:    .long  main
 203 .L4:    .long  __libc_start_main
 204 #else
 205 .L1:    .long  __libc_csu_init-.Llit
 206 .L2:    .long  __libc_csu_fini-.Llit
 207 .L3:    .long  main@GOT
 208 .L4:    .long  __libc_start_main@plt-.Llit
 209 .L5:    .long  _GLOBAL_OFFSET_TABLE_-.Llit
 210 #endif
 211
 212 /* Define a symbol for the first piece of initialized data.  */
 213         .data
 214         .globl __data_start
 215 __data_start:
 216         .long 0
 217         .weak data_start
 218         data_start = __data_start