sysdeps/s390/s390-64/setjmp.S

   1 /* setjmp for 64 bit S/390, ELF version.
   2    Copyright (C) 2001-2019 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24 #include <shlib-compat.h>
  25 #include <stap-probe.h>
  26
  27 #if !IS_IN (rtld) && defined SHARED \
  28   && SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)
  29 # define NEED_COMPAT_SYMBOLS 1
  30 /* We need a unique name in case of symbol versioning.  */
  31 # define setjmp __v1setjmp
  32 # define _setjmp __v1_setjmp
  33 # define __sigsetjmp __v1__sigsetjmp
  34 #else
  35 # define NEED_COMPAT_SYMBOLS 0
  36 #endif
  37
  38         /* We include the BSD entry points here as well.  */
  39 ENTRY (setjmp)
  40         lghi   %r3,1                /* Second argument of one.  */
  41         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  42 END (setjmp)
  43
  44         /* Binary compatibility entry point.  */
  45 ENTRY(_setjmp)
  46         slgr   %r3,%r3              /* Second argument of zero.  */
  47         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  48 END (_setjmp)
  49 #if NEED_COMPAT_SYMBOLS
  50 strong_alias (_setjmp, __GI__setjmp)
  51 #else
  52 libc_hidden_def (_setjmp)
  53 #endif
  54
  55 ENTRY(__setjmp)
  56         slgr   %r3,%r3              /* Second argument of zero.  */
  57         j      .Linternal_sigsetjmp /* Branch relativ to __sigsetjmp.  */
  58 END (__setjmp)
  59
  60 ENTRY(__sigsetjmp)
  61 .Linternal_sigsetjmp:
  62         /* setjmp probe expects sig/setjmp first argument (8@%r2), second
  63            argument (-8@%r3) and target address (8@%r14).  */
  64         LIBC_PROBE (setjmp, 3, 8@%r2, -4@%r3, 8@%r14)
  65 #ifdef PTR_MANGLE
  66         stmg   %r6,%r13,0(%r2)      /* Store registers in jmp_buf.  */
  67         lgr    %r4,%r14
  68         lgr    %r5,%r15
  69         PTR_MANGLE (%r4, %r1)
  70         PTR_MANGLE2 (%r5, %r1)
  71         stmg   %r4,%r5,64(%r2)
  72 #else
  73         stmg   %r6,%r15,0(%r2)      /* Store registers in jmp_buf.  */
  74 #endif
  75         std    %f8,80(%r2)
  76         std    %f9,88(%r2)
  77         std    %f10,96(%r2)
  78         std    %f11,104(%r2)
  79         std    %f12,112(%r2)
  80         std    %f13,120(%r2)
  81         std    %f14,128(%r2)
  82         std    %f15,136(%r2)
  83 #if IS_IN (rtld)
  84         /* In ld.so we never save the signal mask.  */
  85         lghi   %r2,0
  86         br     %r14
  87 #elif defined PIC
  88         jg     __sigjmp_save@PLT    /* Branch to PLT of __sigsetjmp.  */
  89 #else
  90         jg     __sigjmp_save
  91 #endif
  92 END (__sigsetjmp)
  93 #if NEED_COMPAT_SYMBOLS
  94 strong_alias (__sigsetjmp, __GI___sigsetjmp)
  95 #else
  96 libc_hidden_def (__sigsetjmp)
  97 #endif
  98
  99 #if NEED_COMPAT_SYMBOLS
 100 /* In glibc release 2.19 new versions of setjmp-functions were introduced,
 101    but were reverted before 2.20. Thus both versions are the same function.  */
 102
 103 # undef setjmp
 104 # undef _setjmp
 105 # undef __sigsetjmp
 106
 107 strong_alias (__v1setjmp, __v2setjmp);
 108 versioned_symbol (libc, __v1setjmp, setjmp, GLIBC_2_0);
 109 compat_symbol (libc, __v2setjmp, setjmp, GLIBC_2_19);
 110
 111 strong_alias (__v1_setjmp, __v2_setjmp);
 112 versioned_symbol (libc, __v1_setjmp, _setjmp, GLIBC_2_0);
 113 compat_symbol (libc, __v2_setjmp, _setjmp, GLIBC_2_19);
 114
 115 strong_alias (__v1__sigsetjmp, __v2__sigsetjmp);
 116 versioned_symbol (libc, __v1__sigsetjmp, __sigsetjmp, GLIBC_2_0);
 117 compat_symbol (libc, __v2__sigsetjmp, __sigsetjmp, GLIBC_2_19);
 118 #endif /* NEED_COMPAT_SYMBOLS */