sysdeps/sparc/sparc32/__longjmp.S

   1 /* Copyright (C) 1991, 93, 96, 97, 98, 99 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Library General Public License as
   6    published by the Free Software Foundation; either version 2 of the
   7    License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Library General Public License for more details.
  13
  14    You should have received a copy of the GNU Library General Public
  15    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17    Boston, MA 02111-1307, USA.  */
  18
  19 #include <sysdep.h>
  20
  21 #define _ASM 1
  22 #include <jmp_buf.h>
  23 #define ENV(base,reg) [%base + (reg * 4)]
  24 #define ST_FLUSH_WINDOWS 3
  25 #define RW_FP [%fp + 0x38]
  26
  27 ENTRY(__longjmp)
  28         /* Store our arguments in global registers so we can still
  29            use them while unwinding frames and their register windows.  */
  30
  31         ld ENV(o0,JB_FP), %g3   /* Cache target FP in register %g3.  */
  32         mov %o0, %g1            /* ENV in %g1 */
  33         orcc %o1, %g0, %g2      /* VAL in %g2 */
  34         be,a 0f                 /* Branch if zero; else skip delay slot.  */
  35          mov 1, %g2             /* Delay slot only hit if zero: VAL = 1.  */
  36 0:
  37         xor %fp, %g3, %o0
  38         add %fp, 512, %o1
  39         andncc %o0, 4095, %o0
  40         bne LOC(thread)
  41          cmp %o1, %g3
  42         bl LOC(thread)
  43
  44         /* Now we will loop, unwinding the register windows up the stack
  45            until the restored %fp value matches the target value in %g3.  */
  46
  47 LOC(loop):
  48         cmp %fp, %g3            /* Have we reached the target frame? */
  49         bl,a LOC(loop)          /* Loop while current fp is below target.  */
  50          restore                /* Unwind register window in delay slot.  */
  51         be,a LOC(found)         /* Better have hit it exactly.  */
  52          ld ENV(g1,JB_SP), %o0  /* Delay slot: extract target SP.  */
  53
  54 LOC(thread):
  55         /*
  56          * Do a "flush register windows trap".  The trap handler in the
  57          * kernel writes all the register windows to their stack slots, and
  58          * marks them all as invalid (needing to be sucked up from the
  59          * stack when used).  This ensures that all information needed to
  60          * unwind to these callers is in memory, not in the register
  61          * windows.
  62          */
  63         ta      ST_FLUSH_WINDOWS
  64         ld      ENV(g1,JB_PC), %o7 /* Set return PC. */
  65         ld      ENV(g1,JB_SP), %fp /* Set saved SP on restore below. */
  66         sub     %fp, 64, %sp    /* Allocate a register frame. */
  67         st      %g3, RW_FP      /* Set saved FP on restore below. */
  68         retl
  69          restore %g2, 0, %o0    /* Restore values from above register frame. */
  70
  71 LOC(found):
  72         /* We have unwound register windows so %fp matches the target.  */
  73         mov %o0, %sp            /* OK, install new SP.  */
  74
  75 LOC(sp_ok):
  76         ld ENV(g1,JB_PC), %o0   /* Extract target return PC.  */
  77         jmp %o0 + 8             /* Return there.  */
  78          mov %g2, %o0           /* Delay slot: set return value.  */
  79
  80 END(__longjmp)