sysdeps/sparc/sparc32/sparcv9/fpu/s_nearbyint.S

   1 /* Round float to int floating-point values without generating
   2    an inexact exception, sparc32 v9 version.
   3
   4    Copyright (C) 2013-2022 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <https://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include <math_ldbl_opt.h>
  23 #include <libm-alias-double.h>
  24
  25         /* We pop constants into the FPU registers using the incoming
  26            argument stack slots, since this avoid having to use any PIC
  27            references.  We also thus avoid having to allocate a register
  28            window.
  29
  30            VIS instructions are used to facilitate the formation of
  31            easier constants, and the propagation of the sign bit.  */
  32
  33 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  34
  35 #define ZERO            %f10                    /* 0.0 */
  36 #define SIGN_BIT        %f12                    /* -0.0 */
  37
  38 ENTRY (__nearbyint)
  39         sllx    %o0, 32, %o0
  40         or      %o0, %o1, %o0
  41         stx     %o0, [%sp + 72]
  42         ldd     [%sp + 72], %f0
  43         fcmpd   %fcc3, %f0, %f0                 /* Check for sNaN */
  44         st      %fsr, [%sp + 88]
  45         sethi   %hi(TWO_FIFTYTWO), %o2
  46         sethi   %hi(0xf8003e0), %o5
  47         ld      [%sp + 88], %o4
  48         or      %o5, %lo(0xf8003e0), %o5
  49         andn    %o4, %o5, %o4
  50         fzero   ZERO
  51         st      %o4, [%sp + 80]
  52         sllx    %o2, 32, %o2
  53         fnegd   ZERO, SIGN_BIT
  54         ld      [%sp + 80], %fsr
  55         stx     %o2, [%sp + 72]
  56         fabsd   %f0, %f14
  57         ldd     [%sp + 72], %f16
  58         fcmpd   %fcc3, %f14, %f16
  59         fmovduge %fcc3, ZERO, %f16
  60         fand    %f0, SIGN_BIT, SIGN_BIT
  61         for     %f16, SIGN_BIT, %f16
  62         faddd   %f0, %f16, %f6
  63         fsubd   %f6, %f16, %f0
  64         fabsd   %f0, %f0
  65         for     %f0, SIGN_BIT, %f0
  66         retl
  67          ld     [%sp + 88], %fsr
  68 END (__nearbyint)
  69 libm_alias_double (__nearbyint, nearbyint)