sysdeps/unix/sysv/linux/arm/mmap64.S

   1 /* Copyright (C) 2000, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20
  21 #define EINVAL          22
  22 #define ENOSYS          38
  23
  24 #include "kernel-features.h"
  25
  26         /* The mmap2 system call takes six arguments, all in registers.  */
  27         .text
  28 ENTRY (__mmap64)
  29 #ifdef __NR_mmap2
  30         ldr     ip, [sp, $4]            @ offset low part
  31         str     r5, [sp, #-4]!
  32         ldr     r5, [sp, $12]           @ offset high part
  33         str     r4, [sp, #-4]!
  34         movs    r4, ip, lsl $20         @ check that offset is page-aligned
  35         mov     ip, ip, lsr $12
  36         moveqs  r4, r5, lsr $12         @ check for overflow
  37         bne     .Linval
  38         ldr     r4, [sp, $8]            @ load fd
  39         orr     r5, ip, r5, lsl $20     @ compose page offset
  40         mov     ip, r0
  41         swi     SYS_ify (mmap2)
  42         cmn     r0, $4096
  43 # ifdef __ASSUME_MMAP2_SYSCALL
  44         ldr     r4, [sp], #4
  45         ldr     r5, [sp], #4
  46         RETINSTR(cc, lr)
  47         b       PLTJMP(syscall_error)
  48 # else
  49         ldrcc   r4, [sp], #4
  50         ldrcc   r5, [sp], #4
  51         RETINSTR(cc, lr)
  52         cmn     r0, $ENOSYS
  53         bne     .Lerror
  54         /* The current kernel does not support mmap2.  Fall back to plain
  55            mmap if the offset is small enough.  */
  56         ldr     r5, [sp, $16]
  57         mov     r0, ip                  @ first arg was clobbered
  58         teq     r5, $0
  59         ldreq   r4, [sp], #4
  60         ldreq   r5, [sp], #4
  61         beq     PLTJMP(__mmap)
  62 # endif
  63 .Linval:
  64         mov     r0, $-EINVAL
  65 .Lerror:
  66         ldr     r4, [sp], #4
  67         ldr     r5, [sp], #4
  68         b       PLTJMP(syscall_error)
  69 #else
  70         /* The kernel headers do not support mmap2.  Fall back to plain
  71            mmap if the offset is small enough.  */
  72         ldr     ip, [sp, $8]
  73         teq     ip, $0
  74         beq     PLTJMP(__mmap)
  75         mov     r0, $-EINVAL
  76         b       PLTJMP(syscall_error)
  77 #endif
  78 PSEUDO_END (__mmap64)
  79
  80 weak_alias (__mmap64, mmap64)