sysdeps/unix/sysv/linux/m68k/clone.S

   1 /* Copyright (C) 1996 Free Software Foundation, Inc.
   2    Contributed by Andreas Schwab (schwab@issan.informatik.uni-dortmund.de)
   3
   4 The GNU C Library is free software; you can redistribute it and/or
   5 modify it under the terms of the GNU Library General Public License as
   6 published by the Free Software Foundation; either version 2 of the
   7 License, or (at your option) any later version.
   8
   9 The GNU C Library is distributed in the hope that it will be useful,
  10 but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 Library General Public License for more details.
  13
  14 You should have received a copy of the GNU Library General Public
  15 License along with the GNU C Library; see the file COPYING.LIB.  If
  16 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17 Cambridge, MA 02139, USA.  */
  18
  19 /* clone is even more special than fork as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #include <errnos.h>
  24
  25 /* int clone (int (*fn) (), void *child_stack, int flags, int nargs, ...) */
  26
  27         .text
  28 ENTRY (__clone)
  29         /* Sanity check arguments.  */
  30         movel   #-EINVAL, %d0
  31         movel   4(%sp), %a0             /* no NULL function pointers */
  32         tstl    %a0
  33         jeq     syscall_error
  34         movel   8(%sp), %a1             /* no NULL stack pointers */
  35         tstl    %a1
  36         jeq     syscall_error
  37         movel   16(%sp), %d1            /* no negative argument counts */
  38         jmi     syscall_error
  39
  40         /* Allocate space on the new stack and copy args over */
  41         movel   %d1, %d0
  42         negl    %d0
  43         lea     (%a1,%d0.l*4), %a1
  44         jeq     2f
  45 1:      movel   16(%sp,%d1.l*4), -4(%a1,%d1.l*4)
  46         subql   #1, %d1
  47         jne     1b
  48 2:
  49
  50         /* Do the system call */
  51         exg     %d2, %a1                /* save %d2 and get stack pointer */
  52         movel   12(%sp), %d1            /* get flags */
  53         movel   #SYS_ify (clone), %d0
  54         trap    #0
  55         exg     %d2, %a1                /* restore %d2 */
  56
  57         tstl    %d0
  58         jmi     syscall_error
  59         jeq     thread_start
  60
  61         rts
  62
  63         SYSCALL_ERROR_HANDLER
  64
  65 thread_start:
  66         subl    %fp, %fp        /* terminate the stack frame */
  67         jsr     (%a0)
  68         movel   %d0, -(%sp)
  69 #ifdef PIC
  70         bsrl    _exit@PLTPC
  71 #else
  72         jbsr    _exit
  73 #endif
  74
  75 weak_alias (__clone, clone)