sysdeps/unix/sysv/linux/mips/vfork.S

   1 /* Copyright (C) 2005-2019 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <https://www.gnu.org/licenses/>.  */
  17
  18 /* vfork() is just a special case of clone().  */
  19
  20 #include <sys/asm.h>
  21 #include <sysdep.h>
  22 #include <asm/unistd.h>
  23 #include <sgidefs.h>
  24 #include <tls.h>
  25
  26
  27 /* int vfork() */
  28
  29         .text
  30         .set            nomips16
  31 LOCALSZ= 1
  32 FRAMESZ= (((NARGSAVE+LOCALSZ)*SZREG)+ALSZ)&ALMASK
  33 GPOFF= FRAMESZ-(1*SZREG)
  34 NESTED(__libc_vfork,FRAMESZ,sp)
  35 #ifdef __PIC__
  36         SETUP_GP
  37 #endif
  38         PTR_SUBU sp, FRAMESZ
  39         cfi_adjust_cfa_offset (FRAMESZ)
  40         SETUP_GP64_REG (a5, __libc_vfork)
  41 #ifdef __PIC__
  42         SAVE_GP (GPOFF)
  43 #endif
  44 #ifdef PROF
  45 # if (_MIPS_SIM != _ABIO32)
  46         PTR_S           a5, GPOFF(sp)
  47 # endif
  48         .set            noat
  49         move            $1, ra
  50 # if (_MIPS_SIM == _ABIO32)
  51         subu            sp,sp,8
  52 # endif
  53         jal             _mcount
  54         .set            at
  55 # if (_MIPS_SIM != _ABIO32)
  56         PTR_L           a5, GPOFF(sp)
  57 # endif
  58 #endif
  59
  60         PTR_ADDU        sp, FRAMESZ
  61         cfi_adjust_cfa_offset (-FRAMESZ)
  62
  63         li              a0, 0x4112      /* CLONE_VM | CLONE_VFORK | SIGCHLD */
  64         move            a1, sp
  65
  66         /* Do the system call */
  67         li              v0,__NR_clone
  68         syscall
  69
  70         cfi_remember_state
  71         bnez            a3,L(error)
  72
  73         /* Successful return from the parent or child.  */
  74         RESTORE_GP64_REG
  75         ret
  76
  77         /* Something bad happened -- no child created.  */
  78 L(error):
  79         cfi_restore_state
  80 #ifdef __PIC__
  81         PTR_LA          t9, __syscall_error
  82         RESTORE_GP64_REG
  83         jr              t9
  84 #else
  85         RESTORE_GP64_REG
  86         j               __syscall_error
  87 #endif
  88         END(__libc_vfork)
  89
  90 #if IS_IN (libc)
  91 weak_alias (__libc_vfork, vfork)
  92 strong_alias (__libc_vfork, __vfork)
  93 libc_hidden_def (__vfork)
  94 #endif