sysdeps/unix/sysv/linux/mips/vfork.S

   1 /* Copyright (C) 2005-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 /* vfork() is just a special case of clone().  */
  19
  20 #include <sys/asm.h>
  21 #include <sysdep.h>
  22 #include <asm/unistd.h>
  23 #include <sgidefs.h>
  24 #include <tls.h>
  25
  26
  27 /* int vfork() */
  28
  29         .text
  30         .set            nomips16
  31 LOCALSZ= 1
  32 FRAMESZ= (((NARGSAVE+LOCALSZ)*SZREG)+ALSZ)&ALMASK
  33 GPOFF= FRAMESZ-(1*SZREG)
  34 NESTED(__vfork,FRAMESZ,sp)
  35 #ifdef __PIC__
  36         SETUP_GP
  37 #endif
  38         PTR_SUBU sp, FRAMESZ
  39         cfi_adjust_cfa_offset (FRAMESZ)
  40         SETUP_GP64_REG (a5, __vfork)
  41 #ifdef __PIC__
  42         SAVE_GP (GPOFF)
  43 #endif
  44 #ifdef PROF
  45 # if (_MIPS_SIM != _ABIO32)
  46         PTR_S           a5, GPOFF(sp)
  47 # endif
  48         .set            noat
  49         move            $1, ra
  50 # if (_MIPS_SIM == _ABIO32)
  51         subu            sp,sp,8
  52 # endif
  53         jal             _mcount
  54         .set            at
  55 # if (_MIPS_SIM != _ABIO32)
  56         PTR_L           a5, GPOFF(sp)
  57 # endif
  58 #endif
  59
  60         PTR_ADDU        sp, FRAMESZ
  61         cfi_adjust_cfa_offset (-FRAMESZ)
  62
  63         /* Save the PID value.  */
  64         READ_THREAD_POINTER(v1)    /* Get the thread pointer.  */
  65         lw      a2, PID_OFFSET(v1) /* Load the saved PID.  */
  66         subu    a2, $0, a2         /* Negate it.  */
  67         bnez    a2, 1f             /* If it was zero... */
  68         lui     a2, 0x8000         /* use 0x80000000 instead.  */
  69 1:      sw      a2, PID_OFFSET(v1) /* Store the temporary PID.  */
  70
  71         li              a0, 0x4112      /* CLONE_VM | CLONE_VFORK | SIGCHLD */
  72         move            a1, sp
  73
  74         /* Do the system call */
  75         li              v0,__NR_clone
  76         syscall
  77
  78         /* Restore the old PID value in the parent.  */
  79         beqz    v0, 1f          /* If we are the parent... */
  80         READ_THREAD_POINTER(v1) /* Get the thread pointer.  */
  81         lw      a2, PID_OFFSET(v1) /* Load the saved PID.  */
  82         subu    a2, $0, a2         /* Re-negate it.  */
  83         lui     a0, 0x8000         /* Load 0x80000000... */
  84         bne     a2, a0, 2f         /* ... compare against it... */
  85         li      a2, 0              /* ... use 0 instead.  */
  86 2:      sw      a2, PID_OFFSET(v1) /* Restore the PID.  */
  87 1:
  88
  89         cfi_remember_state
  90         bnez            a3,L(error)
  91
  92         /* Successful return from the parent or child.  */
  93         RESTORE_GP64_REG
  94         ret
  95
  96         /* Something bad happened -- no child created.  */
  97 L(error):
  98         cfi_restore_state
  99 #ifdef __PIC__
 100         PTR_LA          t9, __syscall_error
 101         RESTORE_GP64_REG
 102         jr              t9
 103 #else
 104         RESTORE_GP64_REG
 105         j               __syscall_error
 106 #endif
 107         END(__vfork)
 108
 109 libc_hidden_def(__vfork)
 110 weak_alias (__vfork, vfork)