sysdeps/unix/sysv/linux/powerpc/powerpc32/____longjmp_chk.S

   1 /* Copyright (C) 2009 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #include <rtld-global-offsets.h>
  21
  22         .section .rodata.str1.4,"aMS",@progbits,1
  23         .align 2
  24 .LC0:
  25         .string "longjmp causes uninitialized stack frame"
  26         .text
  27
  28 #define __longjmp ____longjmp_chk
  29
  30 #ifdef PIC
  31 # ifdef HAVE_ASM_PPC_REL16
  32 #  define LOAD_ARG \
  33         bcl     20,31,1f;                               \
  34 1:      mflr    r3;                                     \
  35         addis   r3,r3,_GLOBAL_OFFSET_TABLE_-1b@ha;      \
  36         addi    r3,r3,_GLOBAL_OFFSET_TABLE_-1b@l;       \
  37         lwz     r3,.LC0@got(r3)
  38 # else
  39 #  define LOAD_ARG \
  40         bl      _GLOBAL_OFFSET_TABLE_-4@local;          \
  41         mflr    r3;                                     \
  42         lwz     r3,.LC0@got(r3)
  43 # endif
  44 #else
  45 # define LOAD_ARG \
  46         lis     r3,.LC0@ha;                             \
  47         la      r3,.LC0@l(r3)
  48 #endif
  49
  50 #define CHECK_SP(reg) \
  51         cmplw   reg, r1;                                \
  52         bge+    .Lok;                                   \
  53         mflr    r0;                                     \
  54         stwu    r1,-32(r1);                             \
  55         cfi_remember_state;                             \
  56         cfi_adjust_cfa_offset (32);                     \
  57         stw     r0,36(r1);                              \
  58         cfi_offset (lr, 4);                             \
  59         mr      r31,r3;                                 \
  60         mr      r30,r4;                                 \
  61         li      r3,0;                                   \
  62         addi    r4,r1,8;                                \
  63         li      r0,__NR_sigaltstack;                    \
  64         sc;                                             \
  65         /* Without working sigaltstack we cannot perform the test.  */ \
  66         bso     .Lok2;                                  \
  67         lwz     r0,12(r1);                              \
  68         andi.   r3,r0,1;                                \
  69         beq     .Lfail;                                 \
  70         lwz     r0,16(r1);                              \
  71         lwz     r3,8(r1);                               \
  72         add     r3,r3,r0;                               \
  73         sub     r3,r3,reg;                              \
  74         cmplw   r3,r0;                                  \
  75         bge+    .Lok2;                                  \
  76 .Lfail:                                                 \
  77         LOAD_ARG;                                       \
  78         bl      HIDDEN_JUMPTARGET (__fortify_fail);     \
  79 .Lok2:                                                  \
  80         mr      r3,r31;                                 \
  81         mr      r4,r30;                                 \
  82         cfi_restore_state;                              \
  83 .Lok:
  84
  85 #include <__longjmp-common.S>