sysdeps/unix/sysv/linux/s390/s390-64/clone.S

   1 /* Wrapper around clone system call.  64 bit S/390 version.
   2    Copyright (C) 2001-2019 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <https://www.gnu.org/licenses/>.  */
  19
  20 /* clone is even more special than fork as it mucks with stacks
  21    and invokes a function in the right context after its all over.  */
  22
  23 #include <sysdep.h>
  24 #include <tls.h>
  25 #define _ERRNO_H        1
  26 #include <bits/errno.h>
  27
  28 /* int __clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  29                pid_t *parent_tid, void *tls, pid_t *child_tid);  */
  30 /* sys_clone  (void *child_stack, unsigned long flags,
  31                pid_t *parent_tid, pid_t *child_tid, void *tls);  */
  32
  33         .text
  34 ENTRY(__clone)
  35         stg     %r6,48(%r15)            /* store %r6 to save area */
  36         cfi_offset (%r6,-112)
  37         lgr     %r0,%r5                 /* move *arg out of the way */
  38         ltgr    %r1,%r2                 /* check fn and move to %r1 */
  39         jz      error                   /* no NULL function pointers */
  40         ltgr    %r2,%r3                 /* check child_stack and move to %r2 */
  41         jz      error                   /* no NULL stack pointers */
  42         lgr     %r3,%r4                 /* move flags to %r3 */
  43         lgr     %r4,%r6                 /* move parent_tid to %r4 */
  44         lg      %r5,168(%r15)           /* load child_tid from stack */
  45         lg      %r6,160(%r15)           /* load tls from stack */
  46         svc     SYS_ify(clone)
  47         ltgr    %r2,%r2                 /* check return code */
  48         jz      thread_start
  49         lg      %r6,48(%r15)            /* restore %r6 */
  50         jgm     SYSCALL_ERROR_LABEL
  51         br      %r14
  52 error:
  53         lghi    %r2,-EINVAL
  54         jg      SYSCALL_ERROR_LABEL
  55 PSEUDO_END (__clone)
  56
  57 thread_start:
  58         cfi_startproc
  59         /* Mark r14 as undefined in order to stop unwinding here!  */
  60         cfi_undefined (r14)
  61         /* fn is in gpr 1, arg in gpr 0 */
  62         lgr     %r2,%r0         /* set first parameter to void *arg */
  63         aghi    %r15,-160       /* make room on the stack for the save area */
  64         xc      0(8,%r15),0(%r15)
  65         basr    %r14,%r1        /* jump to fn */
  66         DO_CALL (exit, 1)
  67         cfi_endproc
  68
  69 libc_hidden_def (__clone)
  70 weak_alias (__clone, clone)