sysdeps/unix/sysv/linux/sparc/sparc64/clone.S

   1 /* Copyright (C) 1997-2017 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson (rth@tamu.edu).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <asm/errno.h>
  23 #include <asm/unistd.h>
  24 #include <tcb-offsets.h>
  25 #include <sysdep.h>
  26
  27 #define CLONE_VM        0x00000100
  28
  29 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  30              pid_t *ptid, void *tls, pid_t *ctid); */
  31
  32         .register       %g2,#scratch
  33         .register       %g3,#scratch
  34
  35         .text
  36
  37 ENTRY (__clone)
  38         save    %sp, -192, %sp
  39         cfi_def_cfa_register(%fp)
  40         cfi_window_save
  41         cfi_register(%o7, %i7)
  42
  43         /* sanity check arguments */
  44         brz,pn  %i0, 99f                /* fn non-NULL? */
  45          mov    %i0, %g2
  46         brz,pn  %i1, 99f                /* child_stack non-NULL? */
  47          mov    %i2, %o0                /* clone flags */
  48
  49         /* The child_stack is the top of the stack, allocate one
  50            whole stack frame from that as this is what the kernel
  51            expects.  Also, subtract STACK_BIAS.  */
  52         sub     %i1, 192 + 0x7ff, %o1
  53         mov     %i3, %g3
  54
  55         mov     %i4,%o2                 /* PTID */
  56         mov     %i5,%o3                 /* TLS */
  57         ldx     [%fp+0x7ff+176],%o4     /* CTID */
  58
  59         /* Do the system call */
  60         set     __NR_clone, %g1
  61         ta      0x6d
  62         bcs,pn  %xcc, 98f
  63          nop
  64         brnz,pn %o1, __thread_start
  65          nop
  66         jmpl    %i7 + 8, %g0
  67          restore %o0, %g0, %o0
  68 99:     mov     EINVAL, %o0
  69 98:     call    HIDDEN_JUMPTARGET(__errno_location)
  70          mov    %o0, %i0
  71         st      %i0, [%o0]
  72         jmpl    %i7 + 8, %g0
  73          restore %g0,-1,%o0
  74 END(__clone)
  75
  76         .type __thread_start,@function
  77 __thread_start:
  78         mov     %g0, %fp        /* terminate backtrace */
  79         call    %g2
  80          mov    %g3,%o0
  81         call    HIDDEN_JUMPTARGET(_exit),0
  82          nop
  83
  84         .size   __thread_start, .-__thread_start
  85
  86 libc_hidden_def (__clone)
  87 weak_alias (__clone, clone)