test/run_tests.pl

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 use strict;
  10 use warnings;
  11
  12 # Recognise VERBOSE and V which is common on other projects.
  13 BEGIN {
  14     $ENV{HARNESS_VERBOSE} = "yes" if $ENV{VERBOSE} || $ENV{V};
  15 }
  16
  17 use File::Spec::Functions qw/catdir catfile curdir abs2rel rel2abs/;
  18 use File::Basename;
  19 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  20 use Test::Harness qw/runtests $switches/;
  21
  22 my $srctop = $ENV{SRCTOP} || $ENV{TOP};
  23 my $bldtop = $ENV{BLDTOP} || $ENV{TOP};
  24 my $recipesdir = catdir($srctop, "test", "recipes");
  25 my $testlib = catdir($srctop, "test", "testlib");
  26 my $utillib = catdir($srctop, "util");
  27
  28 # It seems that $switches is getting interpreted with 'eval' or something
  29 # like that, and that we need to take care of backslashes or they will
  30 # disappear along the way.
  31 $testlib =~ s|\\|\\\\|g if $^O eq "MSWin32";
  32 $utillib =~ s|\\|\\\\|g if $^O eq "MSWin32";
  33
  34 # Test::Harness provides the variable $switches to give it
  35 # switches to be used when it calls our recipes.
  36 $switches = "-w \"-I$testlib\" \"-I$utillib\"";
  37
  38 my @alltests = find_matching_tests("*");
  39 my %tests = ();
  40
  41 my $initial_arg = 1;
  42 foreach my $arg (@ARGV ? @ARGV : ('alltests')) {
  43     if ($arg eq 'list') {
  44         foreach (@alltests) {
  45             (my $x = basename($_)) =~ s|^[0-9][0-9]-(.*)\.t$|$1|;
  46             print $x,"\n";
  47         }
  48         exit 0;
  49     }
  50     if ($arg eq 'alltests') {
  51         warn "'alltests' encountered, ignoring everything before that...\n"
  52             unless $initial_arg;
  53         %tests = map { $_ => 1 } @alltests;
  54     } elsif ($arg =~ m/^(-?)(.*)/) {
  55         my $sign = $1;
  56         my $test = $2;
  57         my @matches = find_matching_tests($test);
  58
  59         # If '-foo' is the first arg, it's short for 'alltests -foo'
  60         if ($sign eq '-' && $initial_arg) {
  61             %tests = map { $_ => 1 } @alltests;
  62         }
  63
  64         if (scalar @matches == 0) {
  65             warn "Test $test found no match, skipping ",
  66                 ($sign eq '-' ? "removal" : "addition"),
  67                 "...\n";
  68         } else {
  69             foreach $test (@matches) {
  70                 if ($sign eq '-') {
  71                     delete $tests{$test};
  72                 } else {
  73                     $tests{$test} = 1;
  74                 }
  75             }
  76         }
  77     } else {
  78         warn "I don't know what '$arg' is about, ignoring...\n";
  79     }
  80
  81     $initial_arg = 0;
  82 }
  83
  84 runtests(map { abs2rel($_, rel2abs(curdir())); } sort keys %tests);
  85
  86 sub find_matching_tests {
  87     my ($glob) = @_;
  88
  89     return glob(catfile($recipesdir,"*-$glob.t"));
  90 }