util/find-doc-nits

   1 #! /usr/bin/env perl
   2 # Copyright 2002-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 require 5.10.0;
  11 use warnings;
  12 use strict;
  13 use Pod::Checker;
  14 use File::Find;
  15 use File::Basename;
  16 use File::Spec::Functions;
  17 use Getopt::Std;
  18 use lib catdir(dirname($0), "perl");
  19 use OpenSSL::Util::Pod;
  20
  21 # Options.
  22 our($opt_s);
  23 our($opt_u);
  24 our($opt_h);
  25 our($opt_n);
  26 our($opt_l);
  27 our($opt_p);
  28
  29 sub help()
  30 {
  31     print <<EOF;
  32 Find small errors (nits) in documentation.  Options:
  33     -l Print bogus links
  34     -n Print nits in POD pages
  35     -s Also print missing sections in POD pages (implies -n)
  36     -p Warn if non-public name documented (implies -n)
  37     -u List undocumented functions
  38     -h Print this help message
  39 EOF
  40     exit;
  41 }
  42
  43 my $temp = '/tmp/docnits.txt';
  44 my $OUT;
  45 my %public;
  46
  47 my %mandatory_sections =
  48     ( '*'    => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
  49       1      => [ 'SYNOPSIS', 'OPTIONS' ],
  50       3      => [ 'SYNOPSIS', 'RETURN VALUES' ],
  51       5      => [ ],
  52       7      => [ ] );
  53
  54 # Cross-check functions in the NAME and SYNOPSIS section.
  55 sub name_synopsis()
  56 {
  57     my $id = shift;
  58     my $filename = shift;
  59     my $contents = shift;
  60
  61     # Get NAME section and all words in it.
  62     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
  63     my $tmp = $1;
  64     $tmp =~ tr/\n/ /;
  65     print "$id trailing comma before - in NAME\n" if $tmp =~ /, *-/;
  66     $tmp =~ s/ -.*//g;
  67     $tmp =~ s/  */ /g;
  68     print "$id missing comma in NAME\n" if $tmp =~ /[^,] /;
  69     $tmp =~ s/,//g;
  70
  71     my $dirname = dirname($filename);
  72     my $simplename = basename($filename);
  73     $simplename =~ s/.pod$//;
  74     my $foundfilename = 0;
  75     my %foundfilenames = ();
  76     my %names;
  77     foreach my $n ( split ' ', $tmp ) {
  78         $names{$n} = 1;
  79         $foundfilename++ if $n eq $simplename;
  80         $foundfilenames{$n} = 1
  81             if -f "$dirname/$n.pod" && $n ne $simplename;
  82     }
  83     print "$id the following exist as other .pod files:\n",
  84         join(" ", sort keys %foundfilenames), "\n"
  85         if %foundfilenames;
  86     print "$id $simplename (filename) missing from NAME section\n"
  87         unless $foundfilename;
  88     foreach my $n ( keys %names ) {
  89         print "$id $n is not public\n"
  90             if $opt_p and !defined $public{$n};
  91     }
  92
  93     # Find all functions in SYNOPSIS
  94     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
  95     my $syn = $1;
  96     foreach my $line ( split /\n+/, $syn ) {
  97         my $sym;
  98         $line =~ s/STACK_OF\([^)]+\)/int/g;
  99         $line =~ s/__declspec\([^)]+\)//;
 100         if ( $line =~ /env (\S*)=/ ) {
 101             # environment variable env NAME=...
 102             $sym = $1;
 103         } elsif ( $line =~ /typedef.*\(\*(\S+)\)\(.*/ ) {
 104             # a callback function: typedef ... (*NAME)(...
 105             $sym = $1;
 106         } elsif ( $line =~ /typedef.* (\S+);/ ) {
 107             # a simple typedef: typedef ... NAME;
 108             $sym = $1;
 109         } elsif ( $line =~ /enum (\S*) \{/ ) {
 110             # an enumeration: enum ... {
 111             $sym = $1;
 112         } elsif ( $line =~ /#define ([A-Za-z0-9_]+)/ ) {
 113             $sym = $1;
 114         } elsif ( $line =~ /([A-Za-z0-9_]+)\(/ ) {
 115             $sym = $1;
 116         }
 117         else {
 118             next;
 119         }
 120         print "$id $sym missing from NAME section\n"
 121             unless defined $names{$sym};
 122         $names{$sym} = 2;
 123
 124         # Do some sanity checks on the prototype.
 125         print "$id prototype missing spaces around commas: $line\n"
 126             if ( $line =~ /[a-z0-9],[^ ]/ );
 127     }
 128
 129     foreach my $n ( keys %names ) {
 130         next if $names{$n} == 2;
 131         print "$id $n missing from SYNOPSIS\n";
 132     }
 133 }
 134
 135 sub check()
 136 {
 137     my $filename = shift;
 138     my $dirname = basename(dirname($filename));
 139
 140     my $contents = '';
 141     {
 142         local $/ = undef;
 143         open POD, $filename or die "Couldn't open $filename, $!";
 144         $contents = <POD>;
 145         close POD;
 146     }
 147
 148     my $id = "${filename}:1:";
 149
 150     &name_synopsis($id, $filename, $contents)
 151         unless $contents =~ /=for comment generic/
 152             or $filename =~ m@man[157]/@;
 153
 154     print "$id doesn't start with =pod\n"
 155         if $contents !~ /^=pod/;
 156     print "$id doesn't end with =cut\n"
 157         if $contents !~ /=cut\n$/;
 158     print "$id more than one cut line.\n"
 159         if $contents =~ /=cut.*=cut/ms;
 160     print "$id missing copyright\n"
 161         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
 162     print "$id copyright not last\n"
 163         if $contents =~ /head1 COPYRIGHT.*=head/ms;
 164     print "$id head2 in All uppercase\n"
 165         if $contents =~ /head2\s+[A-Z ]+\n/;
 166     print "$id extra space after head\n"
 167         if $contents =~ /=head\d\s\s+/;
 168     print "$id period in NAME section\n"
 169         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
 170     print "$id POD markup in NAME section\n"
 171         if $contents =~ /=head1 NAME.*[<>].*=head1 SYNOPSIS/ms;
 172     print "$id Duplicate $1 in L<>\n"
 173         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
 174     print "$id Bad =over $1\n"
 175         if $contents =~ /=over([^ ][^24])/;
 176
 177     # Look for multiple consecutive openssl #include lines.
 178     # Consecutive because of files like md5.pod. Sometimes it's okay
 179     # or necessary, as in ssl/SSL_set1_host.pod
 180     if ( $contents !~ /=for comment multiple includes/ ) {
 181         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
 182             my $count = 0;
 183             foreach my $line ( split /\n+/, $1 ) {
 184                 if ( $line =~ m@include <openssl/@ ) {
 185                     if ( ++$count == 2 ) {
 186                         print "$id has multiple includes\n";
 187                     }
 188                 } else {
 189                     $count = 0;
 190                 }
 191             }
 192         }
 193     }
 194
 195     return unless $opt_s;
 196
 197     # Find what section this page is in.  If run from "." assume
 198     # section 3.
 199     my $section = 3;
 200     $section = $1 if $dirname =~ /man([1-9])/;
 201
 202     foreach ((@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}})) {
 203         print "$id: missing $_ head1 section\n"
 204             if $contents !~ /^=head1\s+${_}\s*$/m;
 205     }
 206
 207     open my $OUT, '>', $temp
 208         or die "Can't open $temp, $!";
 209     podchecker($filename, $OUT);
 210     close $OUT;
 211     open $OUT, '<', $temp
 212         or die "Can't read $temp, $!";
 213     while ( <$OUT> ) {
 214         next if /\(section\) in.*deprecated/;
 215         print;
 216     }
 217     close $OUT;
 218     unlink $temp || warn "Can't remove $temp, $!";
 219 }
 220
 221 my %dups;
 222
 223 sub parsenum()
 224 {
 225     my $file = shift;
 226     my @apis;
 227
 228     open my $IN, '<', $file
 229         or die "Can't open $file, $!, stopped";
 230
 231     while ( <$IN> ) {
 232         next if /^#/;
 233         next if /\bNOEXIST\b/;
 234         next if /\bEXPORT_VAR_AS_FUNC\b/;
 235         my @fields = split();
 236         die "Malformed line $_"
 237             if scalar @fields != 2 && scalar @fields != 4;
 238         push @apis, $fields[0];
 239     }
 240
 241     close $IN;
 242
 243     print "# Found ", scalar(@apis), " in $file\n" unless $opt_p;
 244     return sort @apis;
 245 }
 246
 247 sub getdocced()
 248 {
 249     my $dir = shift;
 250     my %return;
 251
 252     foreach my $pod ( glob("$dir/*.pod") ) {
 253         my %podinfo = extract_pod_info($pod);
 254         foreach my $n ( @{$podinfo{names}} ) {
 255             $return{$n} = $pod;
 256             print "# Duplicate $n in $pod and $dups{$n}\n"
 257                 if defined $dups{$n} && $dups{$n} ne $pod;
 258             $dups{$n} = $pod;
 259         }
 260     }
 261
 262     return %return;
 263 }
 264
 265 my %docced;
 266
 267 sub printem()
 268 {
 269     my $libname = shift;
 270     my $numfile = shift;
 271     my $count = 0;
 272
 273     foreach my $func ( &parsenum($numfile) ) {
 274         next if $docced{$func};
 275
 276         # Skip ASN1 utilities
 277         next if $func =~ /^ASN1_/;
 278
 279         print "$libname:$func\n";
 280         $count++;
 281     }
 282     print "# Found $count missing from $numfile\n\n";
 283 }
 284
 285
 286 # Collection of links in each POD file.
 287 # filename => [ "foo(1)", "bar(3)", ... ]
 288 my %link_collection = ();
 289 # Collection of names in each POD file.
 290 # "name(s)" => filename
 291 my %name_collection = ();
 292
 293 sub collectnames {
 294     my $filename = shift;
 295     $filename =~ m|man(\d)/|;
 296     my $section = $1;
 297     my $simplename = basename($filename, ".pod");
 298     my $id = "${filename}:1:";
 299
 300     my $contents = '';
 301     {
 302         local $/ = undef;
 303         open POD, $filename or die "Couldn't open $filename, $!";
 304         $contents = <POD>;
 305         close POD;
 306     }
 307
 308     $contents =~ /=head1 NAME([^=]*)=head1 /ms;
 309     my $tmp = $1;
 310     unless (defined $tmp) {
 311         print "$id weird name section\n";
 312         return;
 313     }
 314     $tmp =~ tr/\n/ /;
 315     $tmp =~ s/-.*//g;
 316
 317     my @names = map { s/\s+//g; $_ } split(/,/, $tmp);
 318     unless (grep { $simplename eq $_ } @names) {
 319         print "$id missing $simplename\n";
 320         push @names, $simplename;
 321     }
 322     foreach my $name (@names) {
 323         next if $name eq "";
 324         my $name_sec = "$name($section)";
 325         if (! exists $name_collection{$name_sec}) {
 326             $name_collection{$name_sec} = $filename;
 327         } else { #elsif ($filename ne $name_collection{$name_sec}) {
 328             print "$id $name_sec also in $name_collection{$name_sec}\n";
 329         }
 330     }
 331
 332     my @foreign_names =
 333         map { map { s/\s+//g; $_ } split(/,/, $_) }
 334         $contents =~ /=for\s+comment\s+foreign\s+manuals:\s*(.*)\n\n/;
 335     foreach (@foreign_names) {
 336         $name_collection{$_} = undef; # It still exists!
 337     }
 338
 339     my @links = $contents =~ /L<
 340                               # if the link is of the form L<something|name(s)>,
 341                               # then remove 'something'.  Note that 'something'
 342                               # may contain POD codes as well...
 343                               (?:(?:[^\|]|<[^>]*>)*\|)?
 344                               # we're only interested in referenses that have
 345                               # a one digit section number
 346                               ([^\/>\(]+\(\d\))
 347                              /gx;
 348     $link_collection{$filename} = [ @links ];
 349 }
 350
 351 sub checklinks {
 352     foreach my $filename (sort keys %link_collection) {
 353         foreach my $link (@{$link_collection{$filename}}) {
 354             print "${filename}:1: reference to non-existing $link\n"
 355                 unless exists $name_collection{$link};
 356         }
 357     }
 358 }
 359
 360 sub publicize() {
 361     foreach my $name ( &parsenum('util/libcrypto.num') ) {
 362         $public{$name} = 1;
 363     }
 364     foreach my $name ( &parsenum('util/libssl.num') ) {
 365         $public{$name} = 1;
 366     }
 367     foreach my $name ( &parsenum('util/private.num') ) {
 368         $public{$name} = 1;
 369     }
 370 }
 371
 372 getopts('lnsphu');
 373
 374 &help() if $opt_h;
 375
 376 die "Need one of -l -n -s -p or -u flags.\n"
 377     unless $opt_l or $opt_n or $opt_s or $opt_p or $opt_u;
 378
 379 $opt_n = 1 if $opt_s or $opt_p;
 380
 381 if ( $opt_n ) {
 382     &publicize() if $opt_p;
 383     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 384         &check($_);
 385     }
 386 }
 387
 388 if ( $opt_l ) {
 389     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 390         collectnames($_);
 391     }
 392     checklinks();
 393 }
 394
 395 if ( $opt_u ) {
 396     my %temp = &getdocced('doc/man3');
 397     foreach ( keys %temp ) {
 398         $docced{$_} = $temp{$_};
 399     }
 400     &printem('crypto', 'util/libcrypto.num');
 401     &printem('ssl', 'util/libssl.num');
 402 }
 403
 404 exit;