util/find-doc-nits

   1 #! /usr/bin/env perl
   2 # Copyright 2002-2016 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 require 5.10.0;
  11 use warnings;
  12 use strict;
  13 use Pod::Checker;
  14 use File::Find;
  15 use File::Basename;
  16 use File::Spec::Functions;
  17 use Getopt::Std;
  18 use lib catdir(dirname($0), "perl");
  19 use OpenSSL::Util::Pod;
  20
  21 # Options.
  22 our($opt_s);
  23 our($opt_u);
  24 our($opt_h);
  25 our($opt_n);
  26 our($opt_l);
  27
  28 sub help()
  29 {
  30     print <<EOF;
  31 Find small errors (nits) in documentation.  Options:
  32     -l Print bogus links
  33     -n Print nits in POD pages
  34     -s Also print missing sections in POD pages (implies -n)
  35     -u List undocumented functions
  36     -h Print this help message
  37 EOF
  38     exit;
  39 }
  40
  41 my $temp = '/tmp/docnits.txt';
  42 my $OUT;
  43
  44 my %mandatory_sections =
  45     ( '*'    => [ 'NAME', 'DESCRIPTION', 'COPYRIGHT' ],
  46       1      => [ 'SYNOPSIS', 'OPTIONS' ],
  47       3      => [ 'SYNOPSIS', 'RETURN VALUES' ],
  48       5      => [ ],
  49       7      => [ ] );
  50
  51 # Cross-check functions in the NAME and SYNOPSIS section.
  52 sub name_synopsis()
  53 {
  54     my $id = shift;
  55     my $filename = shift;
  56     my $contents = shift;
  57
  58     # Get NAME section and all words in it.
  59     return unless $contents =~ /=head1 NAME(.*)=head1 SYNOPSIS/ms;
  60     my $tmp = $1;
  61     $tmp =~ tr/\n/ /;
  62     print "$id trailing comma before - in NAME\n" if $tmp =~ /, *-/;
  63     $tmp =~ s/-.*//g;
  64     $tmp =~ s/,//g;
  65
  66     my $dirname = dirname($filename);
  67     my $simplename = basename($filename);
  68     $simplename =~ s/.pod$//;
  69     my $foundfilename = 0;
  70     my %foundfilenames = ();
  71     my %names;
  72     foreach my $n ( split ' ', $tmp ) {
  73         $names{$n} = 1;
  74         $foundfilename++ if $n eq $simplename;
  75         $foundfilenames{$n} = 1
  76             if -f "$dirname/$n.pod" && $n ne $simplename;
  77     }
  78     print "$id the following exist as other .pod files:\n",
  79         join(" ", sort keys %foundfilenames), "\n"
  80         if %foundfilenames;
  81     print "$id $simplename (filename) missing from NAME section\n",
  82         unless $foundfilename;
  83
  84     # Find all functions in SYNOPSIS
  85     return unless $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms;
  86     my $syn = $1;
  87     foreach my $line ( split /\n+/, $syn ) {
  88         my $sym;
  89         $line =~ s/STACK_OF\([^)]+\)/int/g;
  90         $line =~ s/__declspec\([^)]+\)//;
  91         if ( $line =~ /env (\S*)=/ ) {
  92             # environment variable env NAME=...
  93             $sym = $1;
  94         } elsif ( $line =~ /typedef.*\(\*(\S+)\)\(.*/ ) {
  95             # a callback function: typedef ... (*NAME)(...
  96             $sym = $1;
  97         } elsif ( $line =~ /typedef.* (\S+);/ ) {
  98             # a simple typedef: typedef ... NAME;
  99             $sym = $1;
 100         } elsif ( $line =~ /enum (\S*) \{/ ) {
 101             # an enumeration: enum ... {
 102             $sym = $1;
 103         } elsif ( $line =~ /#define ([A-Za-z0-9_]+)/ ) {
 104             $sym = $1;
 105         } elsif ( $line =~ /([A-Za-z0-9_]+)\(/ ) {
 106             $sym = $1;
 107         }
 108         else {
 109             next;
 110         }
 111         print "$id $sym missing from NAME section\n"
 112             unless defined $names{$sym};
 113         $names{$sym} = 2;
 114
 115         # Do some sanity checks on the prototype.
 116         print "$id prototype missing spaces around commas: $line\n"
 117             if ( $line =~ /[a-z0-9],[^ ]/ );
 118     }
 119
 120     foreach my $n ( keys %names ) {
 121         next if $names{$n} == 2;
 122         print "$id $n missing from SYNOPSIS\n";
 123     }
 124 }
 125
 126 sub check()
 127 {
 128     my $filename = shift;
 129     my $dirname = basename(dirname($filename));
 130
 131     my $contents = '';
 132     {
 133         local $/ = undef;
 134         open POD, $filename or die "Couldn't open $filename, $!";
 135         $contents = <POD>;
 136         close POD;
 137     }
 138
 139     my $id = "${filename}:1:";
 140
 141     &name_synopsis($id, $filename, $contents)
 142         unless $contents =~ /=for comment generic/
 143             or $filename =~ m@man[157]/@;
 144
 145     print "$id doesn't start with =pod\n"
 146         if $contents !~ /^=pod/;
 147     print "$id doesn't end with =cut\n"
 148         if $contents !~ /=cut\n$/;
 149     print "$id more than one cut line.\n"
 150         if $contents =~ /=cut.*=cut/ms;
 151     print "$id missing copyright\n"
 152         if $contents !~ /Copyright .* The OpenSSL Project Authors/;
 153     print "$id copyright not last\n"
 154         if $contents =~ /head1 COPYRIGHT.*=head/ms;
 155     print "$id head2 in All uppercase\n"
 156         if $contents =~ /head2\s+[A-Z ]+\n/;
 157     print "$id extra space after head\n"
 158         if $contents =~ /=head\d\s\s+/;
 159     print "$id period in NAME section\n"
 160         if $contents =~ /=head1 NAME.*\.\n.*=head1 SYNOPSIS/ms;
 161     print "$id POD markup in NAME section\n"
 162         if $contents =~ /=head1 NAME.*[<>].*=head1 SYNOPSIS/ms;
 163     print "$id Duplicate $1 in L<>\n"
 164         if $contents =~ /L<([^>]*)\|([^>]*)>/ && $1 eq $2;
 165     print "$id Bad =over $1\n"
 166         if $contents =~ /=over([^ ][^24])/;
 167
 168     # Look for multiple consecutive openssl #include lines.
 169     # Consecutive because of files like md5.pod. Sometimes it's okay
 170     # or necessary, as in ssl/SSL_set1_host.pod
 171     if ( $contents !~ /=for comment multiple includes/ ) {
 172         if ( $contents =~ /=head1 SYNOPSIS(.*)=head1 DESCRIPTION/ms ) {
 173             my $count = 0;
 174             foreach my $line ( split /\n+/, $1 ) {
 175                 if ( $line =~ m@include <openssl/@ ) {
 176                     if ( ++$count == 2 ) {
 177                         print "$id has multiple includes\n";
 178                     }
 179                 } else {
 180                     $count = 0;
 181                 }
 182             }
 183         }
 184     }
 185
 186     return unless $opt_s;
 187
 188     # Find what section this page is in.  If run from "." assume
 189     # section 3.
 190     my $section = 3;
 191     $section = $1 if $dirname =~ /man([1-9])/;
 192
 193     foreach ((@{$mandatory_sections{'*'}}, @{$mandatory_sections{$section}})) {
 194         print "$id: missing $_ head1 section\n"
 195             if $contents !~ /^=head1\s+${_}\s*$/m;
 196     }
 197
 198     open my $OUT, '>', $temp
 199         or die "Can't open $temp, $!";
 200     podchecker($filename, $OUT);
 201     close $OUT;
 202     open $OUT, '<', $temp
 203         or die "Can't read $temp, $!";
 204     while ( <$OUT> ) {
 205         next if /\(section\) in.*deprecated/;
 206         print;
 207     }
 208     close $OUT;
 209     unlink $temp || warn "Can't remove $temp, $!";
 210 }
 211
 212 my %dups;
 213
 214 sub parsenum()
 215 {
 216     my $file = shift;
 217     my @apis;
 218
 219     open my $IN, '<', $file
 220         or die "Can't open $file, $!, stopped";
 221
 222     while ( <$IN> ) {
 223         next if /\bNOEXIST\b/;
 224         next if /\bEXPORT_VAR_AS_FUNC\b/;
 225         push @apis, $1 if /([^\s]+).\s/;
 226     }
 227
 228     close $IN;
 229
 230     print "# Found ", scalar(@apis), " in $file\n";
 231     return sort @apis;
 232 }
 233
 234 sub getdocced()
 235 {
 236     my $dir = shift;
 237     my %return;
 238
 239     foreach my $pod ( glob("$dir/*.pod") ) {
 240         my %podinfo = extract_pod_info($pod);
 241         foreach my $n ( @{$podinfo{names}} ) {
 242             $return{$n} = $pod;
 243             print "# Duplicate $n in $pod and $dups{$n}\n"
 244                 if defined $dups{$n} && $dups{$n} ne $pod;
 245             $dups{$n} = $pod;
 246         }
 247     }
 248
 249     return %return;
 250 }
 251
 252 my %docced;
 253
 254 sub printem()
 255 {
 256     my $libname = shift;
 257     my $numfile = shift;
 258     my $count = 0;
 259
 260     foreach my $func ( &parsenum($numfile) ) {
 261         next if $docced{$func};
 262
 263         # Skip ASN1 utilities
 264         next if $func =~ /^ASN1_/;
 265
 266         print "$libname:$func\n";
 267         $count++;
 268     }
 269     print "# Found $count missing from $numfile\n\n";
 270 }
 271
 272
 273 # Collection of links in each POD file.
 274 # filename => [ "foo(1)", "bar(3)", ... ]
 275 my %link_collection = ();
 276 # Collection of names in each POD file.
 277 # "name(s)" => filename
 278 my %name_collection = ();
 279
 280 sub collectnames {
 281     my $filename = shift;
 282     $filename =~ m|man(\d)/|;
 283     my $section = $1;
 284     my $simplename = basename($filename, ".pod");
 285     my $id = "${filename}:1:";
 286
 287     my $contents = '';
 288     {
 289         local $/ = undef;
 290         open POD, $filename or die "Couldn't open $filename, $!";
 291         $contents = <POD>;
 292         close POD;
 293     }
 294
 295     $contents =~ /=head1 NAME([^=]*)=head1 /ms;
 296     my $tmp = $1;
 297     unless (defined $tmp) {
 298         print "$id weird name section\n";
 299         return;
 300     }
 301     $tmp =~ tr/\n/ /;
 302     $tmp =~ s/-.*//g;
 303
 304     my @names = map { s/\s+//g; $_ } split(/,/, $tmp);
 305     unless (grep { $simplename eq $_ } @names) {
 306         print "$id missing $simplename\n";
 307         push @names, $simplename;
 308     }
 309     foreach my $name (@names) {
 310         next if $name eq "";
 311         my $name_sec = "$name($section)";
 312         if (! exists $name_collection{$name_sec}) {
 313             $name_collection{$name_sec} = $filename;
 314         } else { #elsif ($filename ne $name_collection{$name_sec}) {
 315             print "$id $name_sec also in $name_collection{$name_sec}\n";
 316         }
 317     }
 318
 319     my @foreign_names =
 320         map { map { s/\s+//g; $_ } split(/,/, $_) }
 321         $contents =~ /=for\s+comment\s+foreign\s+manuals:\s*(.*)\n\n/;
 322     foreach (@foreign_names) {
 323         $name_collection{$_} = undef; # It still exists!
 324     }
 325
 326     my @links = $contents =~ /L<
 327                               # if the link is of the form L<something|name(s)>,
 328                               # then remove 'something'.  Note that 'something'
 329                               # may contain POD codes as well...
 330                               (?:(?:[^\|]|<[^>]*>)*\|)?
 331                               # we're only interested in referenses that have
 332                               # a one digit section number
 333                               ([^\/>\(]+\(\d\))
 334                              /gx;
 335     $link_collection{$filename} = [ @links ];
 336 }
 337
 338 sub checklinks {
 339     foreach my $filename (sort keys %link_collection) {
 340         foreach my $link (@{$link_collection{$filename}}) {
 341             print "${filename}:1: reference to non-existing $link\n"
 342                 unless exists $name_collection{$link};
 343         }
 344     }
 345 }
 346
 347 getopts('lnshu');
 348
 349 &help() if ( $opt_h );
 350
 351 die "Need one of -l -n -s or -u flags.\n"
 352     unless $opt_l or $opt_n or $opt_s or $opt_u;
 353
 354 if ( $opt_n or $opt_s ) {
 355     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 356         &check($_);
 357     }
 358 }
 359
 360 if ( $opt_l ) {
 361     foreach (@ARGV ? @ARGV : glob('doc/*/*.pod')) {
 362         collectnames($_);
 363     }
 364     checklinks();
 365 }
 366
 367 if ( $opt_u ) {
 368     my %temp = &getdocced('doc/man3');
 369     foreach ( keys %temp ) {
 370         $docced{$_} = $temp{$_};
 371     }
 372     &printem('crypto', 'util/libcrypto.num');
 373     &printem('ssl', 'util/libssl.num');
 374 }
 375
 376 exit;