util/perl/TLSProxy/ServerHello.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9
  10 package TLSProxy::ServerHello;
  11
  12 use vars '@ISA';
  13 push @ISA, 'TLSProxy::Message';
  14
  15 sub new
  16 {
  17     my $class = shift;
  18     my ($server,
  19         $data,
  20         $records,
  21         $startoffset,
  22         $message_frag_lens) = @_;
  23
  24     my $self = $class->SUPER::new(
  25         $server,
  26         TLSProxy::Message::MT_SERVER_HELLO,
  27         $data,
  28         $records,
  29         $startoffset,
  30         $message_frag_lens);
  31
  32     $self->{server_version} = 0;
  33     $self->{random} = [];
  34     $self->{session_id_len} = 0;
  35     $self->{session} = "";
  36     $self->{ciphersuite} = 0;
  37     $self->{comp_meth} = 0;
  38     $self->{extension_data} = "";
  39
  40     return $self;
  41 }
  42
  43 sub parse
  44 {
  45     my $self = shift;
  46     my $ptr = 2;
  47     my ($server_version) = unpack('n', $self->data);
  48
  49     # TODO(TLS1.3): Replace this reference to draft version before release
  50     if ($server_version == TLSProxy::Record::VERS_TLS_1_3_DRAFT) {
  51         $server_version = TLSProxy::Record::VERS_TLS_1_3;
  52         TLSProxy::Proxy->is_tls13(1);
  53     }
  54
  55     my $random = substr($self->data, $ptr, 32);
  56     $ptr += 32;
  57     my $session_id_len = 0;
  58     my $session = "";
  59     if (!TLSProxy::Proxy->is_tls13()) {
  60         $session_id_len = unpack('C', substr($self->data, $ptr));
  61         $ptr++;
  62         $session = substr($self->data, $ptr, $session_id_len);
  63         $ptr += $session_id_len;
  64     }
  65     my $ciphersuite = unpack('n', substr($self->data, $ptr));
  66     $ptr += 2;
  67     my $comp_meth = 0;
  68     if (!TLSProxy::Proxy->is_tls13()) {
  69         $comp_meth = unpack('C', substr($self->data, $ptr));
  70         $ptr++;
  71     }
  72     my $extensions_len = unpack('n', substr($self->data, $ptr));
  73     if (!defined $extensions_len) {
  74         $extensions_len = 0;
  75     } else {
  76         $ptr += 2;
  77     }
  78     #For now we just deal with this as a block of data. In the future we will
  79     #want to parse this
  80     my $extension_data;
  81     if ($extensions_len != 0) {
  82         $extension_data = substr($self->data, $ptr);
  83
  84         if (length($extension_data) != $extensions_len) {
  85             die "Invalid extension length\n";
  86         }
  87     } else {
  88         if (length($self->data) != $ptr) {
  89             die "Invalid extension length\n";
  90         }
  91         $extension_data = "";
  92     }
  93     my %extensions = ();
  94     while (length($extension_data) >= 4) {
  95         my ($type, $size) = unpack("nn", $extension_data);
  96         my $extdata = substr($extension_data, 4, $size);
  97         $extension_data = substr($extension_data, 4 + $size);
  98         $extensions{$type} = $extdata;
  99     }
 100
 101     $self->server_version($server_version);
 102     $self->random($random);
 103     $self->session_id_len($session_id_len);
 104     $self->session($session);
 105     $self->ciphersuite($ciphersuite);
 106     TLSProxy::Proxy->ciphersuite($ciphersuite);
 107     $self->comp_meth($comp_meth);
 108     $self->extension_data(\%extensions);
 109
 110     $self->process_data();
 111
 112     if (TLSProxy::Proxy->is_tls13()) {
 113         TLSProxy::Record->server_encrypting(1);
 114         TLSProxy::Record->client_encrypting(1);
 115     }
 116
 117     print "    Server Version:".$server_version."\n";
 118     print "    Session ID Len:".$session_id_len."\n";
 119     print "    Ciphersuite:".$ciphersuite."\n";
 120     print "    Compression Method:".$comp_meth."\n";
 121     print "    Extensions Len:".$extensions_len."\n";
 122 }
 123
 124 #Perform any actions necessary based on the data we've seen
 125 sub process_data
 126 {
 127     my $self = shift;
 128
 129     TLSProxy::Message->ciphersuite($self->ciphersuite);
 130 }
 131
 132 #Reconstruct the on-the-wire message data following changes
 133 sub set_message_contents
 134 {
 135     my $self = shift;
 136     my $data;
 137     my $extensions = "";
 138
 139     $data = pack('n', $self->server_version);
 140     $data .= $self->random;
 141     if (!TLSProxy::Proxy->is_tls13()) {
 142         $data .= pack('C', $self->session_id_len);
 143         $data .= $self->session;
 144     }
 145     $data .= pack('n', $self->ciphersuite);
 146     if (!TLSProxy::Proxy->is_tls13()) {
 147         $data .= pack('C', $self->comp_meth);
 148     }
 149
 150     foreach my $key (keys %{$self->extension_data}) {
 151         my $extdata = ${$self->extension_data}{$key};
 152         $extensions .= pack("n", $key);
 153         $extensions .= pack("n", length($extdata));
 154         $extensions .= $extdata;
 155         if ($key == TLSProxy::Message::EXT_DUPLICATE_EXTENSION) {
 156           $extensions .= pack("n", $key);
 157           $extensions .= pack("n", length($extdata));
 158           $extensions .= $extdata;
 159         }
 160     }
 161
 162     $data .= pack('n', length($extensions));
 163     $data .= $extensions;
 164     $self->data($data);
 165 }
 166
 167 #Read/write accessors
 168 sub server_version
 169 {
 170     my $self = shift;
 171     if (@_) {
 172       $self->{server_version} = shift;
 173     }
 174     return $self->{server_version};
 175 }
 176 sub random
 177 {
 178     my $self = shift;
 179     if (@_) {
 180       $self->{random} = shift;
 181     }
 182     return $self->{random};
 183 }
 184 sub session_id_len
 185 {
 186     my $self = shift;
 187     if (@_) {
 188       $self->{session_id_len} = shift;
 189     }
 190     return $self->{session_id_len};
 191 }
 192 sub session
 193 {
 194     my $self = shift;
 195     if (@_) {
 196       $self->{session} = shift;
 197     }
 198     return $self->{session};
 199 }
 200 sub ciphersuite
 201 {
 202     my $self = shift;
 203     if (@_) {
 204       $self->{ciphersuite} = shift;
 205     }
 206     return $self->{ciphersuite};
 207 }
 208 sub comp_meth
 209 {
 210     my $self = shift;
 211     if (@_) {
 212       $self->{comp_meth} = shift;
 213     }
 214     return $self->{comp_meth};
 215 }
 216 sub extension_data
 217 {
 218     my $self = shift;
 219     if (@_) {
 220       $self->{extension_data} = shift;
 221     }
 222     return $self->{extension_data};
 223 }
 224 sub set_extension
 225 {
 226     my ($self, $ext_type, $ext_data) = @_;
 227     $self->{extension_data}{$ext_type} = $ext_data;
 228 }
 229 sub delete_extension
 230 {
 231     my ($self, $ext_type) = @_;
 232     delete $self->{extension_data}{$ext_type};
 233 }
 234 1;