util/perl/TLSProxy/ServerHello.pm

   1 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   2 #
   3 # Licensed under the OpenSSL license (the "License").  You may not use
   4 # this file except in compliance with the License.  You can obtain a copy
   5 # in the file LICENSE in the source distribution or at
   6 # https://www.openssl.org/source/license.html
   7
   8 use strict;
   9
  10 package TLSProxy::ServerHello;
  11
  12 use vars '@ISA';
  13 push @ISA, 'TLSProxy::Message';
  14
  15 my $hrrrandom = pack("C*", 0xCF, 0x21, 0xAD, 0x74, 0xE5, 0x9A, 0x61, 0x11, 0xBE,
  16                            0x1D, 0x8C, 0x02, 0x1E, 0x65, 0xB8, 0x91, 0xC2, 0xA2,
  17                            0x11, 0x16, 0x7A, 0xBB, 0x8C, 0x5E, 0x07, 0x9E, 0x09,
  18                            0xE2, 0xC8, 0xA8, 0x33, 0x9C);
  19
  20 sub new
  21 {
  22     my $class = shift;
  23     my ($server,
  24         $data,
  25         $records,
  26         $startoffset,
  27         $message_frag_lens) = @_;
  28
  29     my $self = $class->SUPER::new(
  30         $server,
  31         TLSProxy::Message::MT_SERVER_HELLO,
  32         $data,
  33         $records,
  34         $startoffset,
  35         $message_frag_lens);
  36
  37     $self->{server_version} = 0;
  38     $self->{random} = [];
  39     $self->{session_id_len} = 0;
  40     $self->{session} = "";
  41     $self->{ciphersuite} = 0;
  42     $self->{comp_meth} = 0;
  43     $self->{extension_data} = "";
  44
  45     return $self;
  46 }
  47
  48 sub parse
  49 {
  50     my $self = shift;
  51     my $ptr = 2;
  52     my ($server_version) = unpack('n', $self->data);
  53     my $neg_version = $server_version;
  54
  55     my $random = substr($self->data, $ptr, 32);
  56     $ptr += 32;
  57     my $session_id_len = 0;
  58     my $session = "";
  59     $session_id_len = unpack('C', substr($self->data, $ptr));
  60     $ptr++;
  61     $session = substr($self->data, $ptr, $session_id_len);
  62     $ptr += $session_id_len;
  63
  64     my $ciphersuite = unpack('n', substr($self->data, $ptr));
  65     $ptr += 2;
  66     my $comp_meth = 0;
  67     $comp_meth = unpack('C', substr($self->data, $ptr));
  68     $ptr++;
  69
  70     my $extensions_len = unpack('n', substr($self->data, $ptr));
  71     if (!defined $extensions_len) {
  72         $extensions_len = 0;
  73     } else {
  74         $ptr += 2;
  75     }
  76     #For now we just deal with this as a block of data. In the future we will
  77     #want to parse this
  78     my $extension_data;
  79     if ($extensions_len != 0) {
  80         $extension_data = substr($self->data, $ptr);
  81
  82         if (length($extension_data) != $extensions_len) {
  83             die "Invalid extension length\n";
  84         }
  85     } else {
  86         if (length($self->data) != $ptr) {
  87             die "Invalid extension length\n";
  88         }
  89         $extension_data = "";
  90     }
  91     my %extensions = ();
  92     while (length($extension_data) >= 4) {
  93         my ($type, $size) = unpack("nn", $extension_data);
  94         my $extdata = substr($extension_data, 4, $size);
  95         $extension_data = substr($extension_data, 4 + $size);
  96         $extensions{$type} = $extdata;
  97         if ($type == TLSProxy::Message::EXT_SUPPORTED_VERSIONS) {
  98             $neg_version = unpack('n', $extdata);
  99         }
 100     }
 101
 102     if ($random eq $hrrrandom) {
 103         TLSProxy::Proxy->is_tls13(1);
 104         # TODO(TLS1.3): Replace this reference to draft version before release
 105     } elsif ($neg_version == TLSProxy::Record::VERS_TLS_1_3_DRAFT) {
 106         $neg_version = TLSProxy::Record::VERS_TLS_1_3;
 107         TLSProxy::Proxy->is_tls13(1);
 108
 109         TLSProxy::Record->server_encrypting(1);
 110         TLSProxy::Record->client_encrypting(1);
 111     }
 112
 113     $self->server_version($server_version);
 114     $self->random($random);
 115     $self->session_id_len($session_id_len);
 116     $self->session($session);
 117     $self->ciphersuite($ciphersuite);
 118     TLSProxy::Proxy->ciphersuite($ciphersuite);
 119     $self->comp_meth($comp_meth);
 120     $self->extension_data(\%extensions);
 121
 122     $self->process_data();
 123
 124
 125     print "    Server Version:".$server_version."\n";
 126     print "    Session ID Len:".$session_id_len."\n";
 127     print "    Ciphersuite:".$ciphersuite."\n";
 128     print "    Compression Method:".$comp_meth."\n";
 129     print "    Extensions Len:".$extensions_len."\n";
 130 }
 131
 132 #Perform any actions necessary based on the data we've seen
 133 sub process_data
 134 {
 135     my $self = shift;
 136
 137     TLSProxy::Message->ciphersuite($self->ciphersuite);
 138 }
 139
 140 #Reconstruct the on-the-wire message data following changes
 141 sub set_message_contents
 142 {
 143     my $self = shift;
 144     my $data;
 145     my $extensions = "";
 146
 147     $data = pack('n', $self->server_version);
 148     $data .= $self->random;
 149     $data .= pack('C', $self->session_id_len);
 150     $data .= $self->session;
 151     $data .= pack('n', $self->ciphersuite);
 152     $data .= pack('C', $self->comp_meth);
 153
 154     foreach my $key (keys %{$self->extension_data}) {
 155         my $extdata = ${$self->extension_data}{$key};
 156         $extensions .= pack("n", $key);
 157         $extensions .= pack("n", length($extdata));
 158         $extensions .= $extdata;
 159         if ($key == TLSProxy::Message::EXT_DUPLICATE_EXTENSION) {
 160           $extensions .= pack("n", $key);
 161           $extensions .= pack("n", length($extdata));
 162           $extensions .= $extdata;
 163         }
 164     }
 165
 166     $data .= pack('n', length($extensions));
 167     $data .= $extensions;
 168     $self->data($data);
 169 }
 170
 171 #Read/write accessors
 172 sub server_version
 173 {
 174     my $self = shift;
 175     if (@_) {
 176       $self->{server_version} = shift;
 177     }
 178     return $self->{server_version};
 179 }
 180 sub random
 181 {
 182     my $self = shift;
 183     if (@_) {
 184       $self->{random} = shift;
 185     }
 186     return $self->{random};
 187 }
 188 sub session_id_len
 189 {
 190     my $self = shift;
 191     if (@_) {
 192       $self->{session_id_len} = shift;
 193     }
 194     return $self->{session_id_len};
 195 }
 196 sub session
 197 {
 198     my $self = shift;
 199     if (@_) {
 200       $self->{session} = shift;
 201     }
 202     return $self->{session};
 203 }
 204 sub ciphersuite
 205 {
 206     my $self = shift;
 207     if (@_) {
 208       $self->{ciphersuite} = shift;
 209     }
 210     return $self->{ciphersuite};
 211 }
 212 sub comp_meth
 213 {
 214     my $self = shift;
 215     if (@_) {
 216       $self->{comp_meth} = shift;
 217     }
 218     return $self->{comp_meth};
 219 }
 220 sub extension_data
 221 {
 222     my $self = shift;
 223     if (@_) {
 224       $self->{extension_data} = shift;
 225     }
 226     return $self->{extension_data};
 227 }
 228 sub set_extension
 229 {
 230     my ($self, $ext_type, $ext_data) = @_;
 231     $self->{extension_data}{$ext_type} = $ext_data;
 232 }
 233 sub delete_extension
 234 {
 235     my ($self, $ext_type) = @_;
 236     delete $self->{extension_data}{$ext_type};
 237 }
 238 1;