zlib/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_INIT([zlib], [1.1.4])
   4 AC_CONFIG_SRCDIR([zlib.h])
   5
   6 if test -n "${with_target_subdir}"; then
   7   AM_ENABLE_MULTILIB(, ..)
   8 fi
   9
  10 AC_CANONICAL_SYSTEM
  11
  12 # This works around an automake problem.
  13 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  14 AC_SUBST(mkinstalldirs)
  15
  16 AM_INIT_AUTOMAKE
  17
  18 AM_MAINTAINER_MODE
  19
  20 dnl We use these options to decide which functions to include.
  21 AC_ARG_WITH(target-subdir,
  22 [  --with-target-subdir=SUBDIR
  23                           configuring in a subdirectory])
  24
  25 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  26    COMPPATH=.
  27 else
  28    COMPPATH=..
  29 fi
  30 AC_SUBST(COMPPATH)
  31
  32 AC_ARG_WITH(cross-host,
  33 [  --with-cross-host=HOST  configuring with a cross compiler])
  34
  35 dnl Default to --enable-multilib
  36 AC_ARG_ENABLE(multilib,
  37 [  --enable-multilib       build many library versions (default)],
  38 [case "${enableval}" in
  39   yes) multilib=yes ;;
  40   no)  multilib=no ;;
  41   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  42  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
  43
  44 AC_ARG_WITH(system-zlib,
  45 [  --with-system-zlib      use installed libz])
  46
  47 # Make sure we don't test executables when making cross-tools.
  48 GCC_NO_EXECUTABLES
  49
  50 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  51 # We must force CC to /not/ be precious variables; otherwise
  52 # the wrong, non-multilib-adjusted value will be used in multilibs.
  53 # As a side effect, we have to subst CFLAGS ourselves.
  54
  55 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  56 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  57 AC_PROG_CC
  58 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  59
  60 AC_SUBST(CFLAGS)
  61
  62 # Add CET specific flags if CET is enabled
  63 GCC_CET_FLAGS(CET_FLAGS)
  64 AC_SUBST(CET_FLAGS)
  65
  66 AC_PROG_LIBTOOL
  67 AM_CONDITIONAL([ENABLE_DARWIN_AT_RPATH], [test x$enable_darwin_at_rpath = xyes])
  68
  69 # Find CPP now so that any conditional tests below won't do it and
  70 # thereby make the resulting definitions conditional.
  71 AC_PROG_CPP
  72
  73 if test -n "$with_cross_host"; then
  74    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  75    # may not work correctly, because the compiler may not be able to
  76    # link executables.
  77
  78    # We assume newlib.  This lets us hard-code the functions we know
  79    # we'll have.
  80    AC_DEFINE(HAVE_MEMCPY)
  81    AC_DEFINE(HAVE_STRERROR)
  82 else
  83    AC_FUNC_MMAP
  84    AC_CHECK_FUNCS(memcpy strerror)
  85 fi
  86
  87 AC_CHECK_HEADERS(unistd.h)
  88
  89 GCC_WITH_TOOLEXECLIBDIR
  90
  91 if test -n "$with_cross_host" &&
  92    test x"$with_cross_host" != x"no"; then
  93   toolexecdir='$(exec_prefix)/$(target_alias)'
  94   case ${with_toolexeclibdir} in
  95     no)
  96       toolexeclibdir='$(toolexecdir)/lib'
  97       ;;
  98     *)
  99       toolexeclibdir=${with_toolexeclibdir}
 100       ;;
 101   esac
 102 else
 103   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 104   toolexeclibdir='$(libdir)'
 105 fi
 106 if test "$GCC" = yes && $CC -print-multi-os-directory > /dev/null 2>&1; then
 107   multiosdir=/`$CC -print-multi-os-directory`
 108   case $multiosdir in
 109     /.) multiosdir= ;; # Avoid trailing /.
 110   esac
 111 else
 112   multiosdir=
 113 fi
 114 toolexeclibdir=${toolexeclibdir}${multiosdir}
 115 AC_SUBST(toolexecdir)
 116 AC_SUBST(toolexeclibdir)
 117
 118 AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
 119
 120 if test "${multilib}" = "yes"; then
 121   multilib_arg="--enable-multilib"
 122 else
 123   multilib_arg=
 124 fi
 125
 126 # Enable --enable-host-shared.
 127 AC_ARG_ENABLE(host-shared,
 128 [AS_HELP_STRING([--enable-host-shared],
 129                 [build host code as shared libraries])])
 130 AC_SUBST(enable_host_shared)
 131
 132 # Enable --enable-host-pie.
 133 AC_ARG_ENABLE(host-pie,
 134 [AS_HELP_STRING([--enable-host-pie],
 135                 [build host code as PIE])])
 136 AC_SUBST(enable_host_pie)
 137
 138 if test x$enable_host_shared = xyes; then
 139   PICFLAG=-fPIC
 140 elif test x$enable_host_pie = xyes; then
 141   PICFLAG=-fPIE
 142 else
 143   PICFLAG=
 144 fi
 145
 146 AC_SUBST(PICFLAG)
 147 AC_CONFIG_FILES([Makefile])
 148 AC_OUTPUT