configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([pakfire],
  24         [0.9.27],
  25         [info@ipfire.org],
  26         [pakfire],
  27         [http://git.ipfire.org/?p=pakfire.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36
  37 AM_INIT_AUTOMAKE([
  38         foreign
  39         1.11
  40         -Wall
  41         -Wno-portability
  42         silent-rules
  43         tar-pax
  44         subdir-objects
  45 ])
  46 AM_SILENT_RULES([yes])
  47 LT_PREREQ(2.2)
  48 LT_INIT([disable-static])
  49
  50 IT_PROG_INTLTOOL([0.40.0])
  51
  52 GETTEXT_PACKAGE=pakfire
  53 AC_SUBST(GETTEXT_PACKAGE)
  54
  55 AC_PROG_LN_S
  56 AC_PROG_MKDIR_P
  57 AC_PROG_SED
  58
  59 AC_ARG_ENABLE([debug],
  60         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  61         [], [enable_debug=no])
  62 AS_IF([test "x$enable_debug" = "xyes"], [
  63         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  64 ])
  65
  66 # pkg-config
  67 PKG_PROG_PKG_CONFIG
  68 # This makes sure pkg.m4 is available.
  69 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  70
  71 # C Compiler
  72 AC_PROG_CC
  73 AC_PROG_CC_C99
  74 AC_PROG_CC_C_O
  75 AC_PROG_GCC_TRADITIONAL
  76 AC_OPENMP
  77
  78 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  79         -pipe \
  80         -Wall \
  81         -Wextra \
  82         -Wno-inline \
  83         -Wundef \
  84         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
  85         -Wno-unused-parameter \
  86         -Wno-unused-result \
  87         -fno-strict-aliasing \
  88         -ffunction-sections \
  89         -fdata-sections \
  90         -fstack-protector-all \
  91         --param=ssp-buffer-size=4])
  92 AC_SUBST([OUR_CFLAGS], $with_cflags)
  93
  94 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
  95         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
  96                 -Wp,-D_FORTIFY_SOURCE=2])],
  97         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
  98 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
  99
 100 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 101         -Wl,--as-needed \
 102         -Wl,--no-undefined \
 103         -Wl,--gc-sections \
 104         -Wl,-z,relro \
 105         -Wl,-z,now])
 106 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 107
 108 # Bison & Flex
 109 AC_PROG_YACC
 110 AM_PROG_LEX
 111
 112 # Python
 113 AM_PATH_PYTHON([3.6])
 114
 115 AC_C_CONST
 116 AC_CHECK_LIB([m], [round])
 117
 118 AC_CHECK_HEADERS([ \
 119         assert.h \
 120         ctypes.h \
 121         math.h \
 122         stdarg.h \
 123         stdlib.h \
 124         string.h \
 125         syslog.h \
 126         sys/stat.h \
 127         unistd.h
 128 ])
 129
 130 AC_CHECK_FUNCS([ \
 131         assert \
 132         secure_getenv \
 133         strcmp \
 134         strdup
 135 ])
 136
 137 save_LIBS="$LIBS"
 138
 139 # libdl
 140 LIBS=
 141 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 142 DL_LIBS="$LIBS"
 143 AC_SUBST(DL_LIBS)
 144
 145 # libcap
 146 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 147
 148 LIBS=
 149 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 150 CAP_LIBS="$LIBS"
 151 AC_SUBST(CAP_LIBS)
 152
 153 # libsolv
 154 AC_CHECK_HEADERS([solv/solvversion.h], [], [AC_MSG_ERROR([*** libsolv headers not found])])
 155
 156 LIBS=
 157 AC_SEARCH_LIBS([solver_create], [solv], [], [AC_MSG_ERROR([*** libsolv library not found])])
 158 SOLV_LIBS="$LIBS"
 159 AC_SUBST(SOLV_LIBS)
 160 LIBS="$save_LIBS"
 161
 162 PKG_CHECK_MODULES([ARCHIVE], [libarchive])
 163 PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}])
 164 PKG_CHECK_MODULES([LZMA], [liblzma])
 165
 166 AM_PATH_LIBGCRYPT([1.8.0], [], [AC_MSG_ERROR([*** libgcrypt not found])])
 167 AM_PATH_GPGME([1.6.0], [], [AC_MSG_ERROR([*** GPGME not found])])
 168
 169 AC_ARG_WITH([systemdsystemunitdir],
 170         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 171         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 172 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 173 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
 174
 175 AC_CONFIG_FILES([
 176         Makefile
 177         po/Makefile.in
 178         src/pakfire/__version__.py
 179 ])
 180
 181 AC_OUTPUT
 182 AC_MSG_RESULT([
 183         $PACKAGE_NAME $VERSION
 184
 185         Debug:                  ${enable_debug}
 186
 187         CFLAGS:                 ${OUR_CFLAGS} ${CFLAGS}
 188         CPPFLAGS:               ${OUR_CPPFLAGS} ${CPPFLAGS}
 189         LDFLAGS:                ${OUR_LDFLAGS} ${LDFLAGS}
 190         PYTHON_CFLAGS:          ${PYTHON_DEVEL_CFLAGS}
 191         PYTHON_LIBS:            ${PYTHON_DEVEL_LIBS}
 192 ])