]> git.ipfire.org Git - people/ms/u-boot.git/blob - arch/arm/cpu/s3c44b0/u-boot.lds
rename _end to __bss_end__
[people/ms/u-boot.git] / arch / arm / cpu / s3c44b0 / u-boot.lds
1 /*
2 * (C) Copyright 2000-2004
3 * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
4 *
5 * See file CREDITS for list of people who contributed to this
6 * project.
7 *
8 * This program is free software; you can redistribute it and/or
9 * modify it under the terms of the GNU General Public License as
10 * published by the Free Software Foundation; either version 2 of
11 * the License, or (at your option) any later version.
12 *
13 * This program is distributed in the hope that it will be useful,
14 * but WITHOUT ANY WARRANTY; without even the implied warranty of
15 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16 * GNU General Public License for more details.
17 *
18 * You should have received a copy of the GNU General Public License
19 * along with this program; if not, write to the Free Software
20 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
21 * MA 02111-1307 USA
22 */
23
24 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
25 OUTPUT_ARCH(arm)
26 ENTRY(_start)
27 SECTIONS
28 {
29 . = 0x00000000;
30
31 . = ALIGN(4);
32 .text :
33 {
34 arch/arm/cpu/s3c44b0/start.o (.text)
35 *(.text)
36 }
37
38 . = ALIGN(4);
39 .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
40
41 . = ALIGN(4);
42 .data : {
43 *(.data)
44 }
45
46 . = ALIGN(4);
47
48 . = .;
49 __u_boot_cmd_start = .;
50 .u_boot_cmd : { *(.u_boot_cmd) }
51 __u_boot_cmd_end = .;
52
53 . = ALIGN(4);
54
55 .rel.dyn : {
56 __rel_dyn_start = .;
57 *(.rel*)
58 __rel_dyn_end = .;
59 }
60
61 .dynsym : {
62 __dynsym_start = .;
63 *(.dynsym)
64 }
65
66 .bss __rel_dyn_start (OVERLAY) : {
67 __bss_start = .;
68 *(.bss)
69 . = ALIGN(4);
70 __bss_end__ = .;
71 }
72
73 /DISCARD/ : { *(.dynstr*) }
74 /DISCARD/ : { *(.dynamic*) }
75 /DISCARD/ : { *(.plt*) }
76 /DISCARD/ : { *(.interp*) }
77 /DISCARD/ : { *(.gnu*) }
78 }