arch/arm/lib/crt0_64.S

   1 /*
   2  * crt0 - C-runtime startup Code for AArch64 U-Boot
   3  *
   4  * (C) Copyright 2013
   5  * David Feng <fenghua@phytium.com.cn>
   6  *
   7  * (C) Copyright 2012
   8  * Albert ARIBAUD <albert.u.boot@aribaud.net>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <asm-offsets.h>
  15 #include <asm/macro.h>
  16 #include <linux/linkage.h>
  17
  18 /*
  19  * This file handles the target-independent stages of the U-Boot
  20  * start-up where a C runtime environment is needed. Its entry point
  21  * is _main and is branched into from the target's start.S file.
  22  *
  23  * _main execution sequence is:
  24  *
  25  * 1. Set up initial environment for calling board_init_f().
  26  *    This environment only provides a stack and a place to store
  27  *    the GD ('global data') structure, both located in some readily
  28  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  29  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  30  *    CONSTANT initialized data are available. GD should be zeroed
  31  *    before board_init_f() is called.
  32  *
  33  * 2. Call board_init_f(). This function prepares the hardware for
  34  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  35  *    be available yet, , board_init_f() must use the current GD to
  36  *    store any data which must be passed on to later stages. These
  37  *    data include the relocation destination, the future stack, and
  38  *    the future GD location.
  39  *
  40  * 3. Set up intermediate environment where the stack and GD are the
  41  *    ones allocated by board_init_f() in system RAM, but BSS and
  42  *    initialized non-const data are still not available.
  43  *
  44  * 4a.For U-Boot proper (not SPL), call relocate_code(). This function
  45  *    relocates U-Boot from its current location into the relocation
  46  *    destination computed by board_init_f().
  47  *
  48  * 4b.For SPL, board_init_f() just returns (to crt0). There is no
  49  *    code relocation in SPL.
  50  *
  51  * 5. Set up final environment for calling board_init_r(). This
  52  *    environment has BSS (initialized to 0), initialized non-const
  53  *    data (initialized to their intended value), and stack in system
  54  *    RAM (for SPL moving the stack and GD into RAM is optional - see
  55  *    CONFIG_SPL_STACK_R). GD has retained values set by board_init_f().
  56  *
  57  * TODO: For SPL, implement stack relocation on AArch64.
  58  *
  59  * 6. For U-Boot proper (not SPL), some CPUs have some work left to do
  60  *    at this point regarding memory, so call c_runtime_cpu_setup.
  61  *
  62  * 7. Branch to board_init_r().
  63  *
  64  * For more information see 'Board Initialisation Flow in README.
  65  */
  66
  67 ENTRY(_main)
  68
  69 /*
  70  * Set up initial C runtime environment and call board_init_f(0).
  71  */
  72 #if defined(CONFIG_TPL_BUILD) && defined(CONFIG_TPL_NEEDS_SEPARATE_STACK)
  73         ldr     x0, =(CONFIG_TPL_STACK)
  74 #elif defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
  75         ldr     x0, =(CONFIG_SPL_STACK)
  76 #else
  77         ldr     x0, =(CONFIG_SYS_INIT_SP_ADDR)
  78 #endif
  79         bic     sp, x0, #0xf    /* 16-byte alignment for ABI compliance */
  80         mov     x0, sp
  81         bl      board_init_f_alloc_reserve
  82         mov     sp, x0
  83         /* set up gd here, outside any C code */
  84         mov     x18, x0
  85         bl      board_init_f_init_reserve
  86
  87         mov     x0, #0
  88         bl      board_init_f
  89
  90 #if !defined(CONFIG_SPL_BUILD)
  91 /*
  92  * Set up intermediate environment (new sp and gd) and call
  93  * relocate_code(addr_moni). Trick here is that we'll return
  94  * 'here' but relocated.
  95  */
  96         ldr     x0, [x18, #GD_START_ADDR_SP]    /* x0 <- gd->start_addr_sp */
  97         bic     sp, x0, #0xf    /* 16-byte alignment for ABI compliance */
  98         ldr     x18, [x18, #GD_NEW_GD]          /* x18 <- gd->new_gd */
  99
 100         adr     lr, relocation_return
 101 #if CONFIG_POSITION_INDEPENDENT
 102         /* Add in link-vs-runtime offset */
 103         adr     x0, _start              /* x0 <- Runtime value of _start */
 104         ldr     x9, _TEXT_BASE          /* x9 <- Linked value of _start */
 105         sub     x9, x9, x0              /* x9 <- Run-vs-link offset */
 106         add     lr, lr, x9
 107 #endif
 108         /* Add in link-vs-relocation offset */
 109         ldr     x9, [x18, #GD_RELOC_OFF]        /* x9 <- gd->reloc_off */
 110         add     lr, lr, x9      /* new return address after relocation */
 111         ldr     x0, [x18, #GD_RELOCADDR]        /* x0 <- gd->relocaddr */
 112         b       relocate_code
 113
 114 relocation_return:
 115
 116 /*
 117  * Set up final (full) environment
 118  */
 119         bl      c_runtime_cpu_setup             /* still call old routine */
 120 #endif /* !CONFIG_SPL_BUILD */
 121 #if defined(CONFIG_SPL_BUILD)
 122         bl      spl_relocate_stack_gd           /* may return NULL */
 123         /* set up gd here, outside any C code, if new stack is returned */
 124         cmp     x0, #0
 125         csel    x18, x0, x18, ne
 126         /*
 127          * Perform 'sp = (x0 != NULL) ? x0 : sp' while working
 128          * around the constraint that conditional moves can not
 129          * have 'sp' as an operand
 130          */
 131         mov     x1, sp
 132         cmp     x0, #0
 133         csel    x0, x0, x1, ne
 134         mov     sp, x0
 135 #endif
 136
 137 /*
 138  * Clear BSS section
 139  */
 140         ldr     x0, =__bss_start                /* this is auto-relocated! */
 141         ldr     x1, =__bss_end                  /* this is auto-relocated! */
 142 clear_loop:
 143         str     xzr, [x0], #8
 144         cmp     x0, x1
 145         b.lo    clear_loop
 146
 147         /* call board_init_r(gd_t *id, ulong dest_addr) */
 148         mov     x0, x18                         /* gd_t */
 149         ldr     x1, [x18, #GD_RELOCADDR]        /* dest_addr */
 150         b       board_init_r                    /* PC relative jump */
 151
 152         /* NOTREACHED - board_init_r() does not return */
 153
 154 ENDPROC(_main)