arch/powerpc/cpu/mpc512x/u-boot.lds

   1 /*
   2  * (C) Copyright 2007 DENX Software Engineering.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 OUTPUT_ARCH(powerpc)
  24 SECTIONS
  25 {
  26   /* Read-only sections, merged into text segment: */
  27   . = + SIZEOF_HEADERS;
  28   .interp : { *(.interp) }
  29   .hash          : { *(.hash)           }
  30   .dynsym        : { *(.dynsym)         }
  31   .dynstr        : { *(.dynstr)         }
  32   .rel.text      : { *(.rel.text)               }
  33   .rela.text     : { *(.rela.text)      }
  34   .rel.data      : { *(.rel.data)               }
  35   .rela.data     : { *(.rela.data)      }
  36   .rel.rodata    : { *(.rel.rodata)     }
  37   .rela.rodata   : { *(.rela.rodata)    }
  38   .rel.got       : { *(.rel.got)                }
  39   .rela.got      : { *(.rela.got)               }
  40   .rel.ctors     : { *(.rel.ctors)      }
  41   .rela.ctors    : { *(.rela.ctors)     }
  42   .rel.dtors     : { *(.rel.dtors)      }
  43   .rela.dtors    : { *(.rela.dtors)     }
  44   .rel.bss       : { *(.rel.bss)                }
  45   .rela.bss      : { *(.rela.bss)               }
  46   .rel.plt       : { *(.rel.plt)                }
  47   .rela.plt      : { *(.rela.plt)               }
  48   .init          : { *(.init)   }
  49   .plt : { *(.plt) }
  50   .text      :
  51   {
  52     arch/powerpc/cpu/mpc512x/start.o    (.text)
  53     *(.text)
  54     *(.got1)
  55     . = ALIGN(16);
  56     *(.eh_frame)
  57     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  58   }
  59   .fini      : { *(.fini)    } =0
  60   .ctors     : { *(.ctors)   }
  61   .dtors     : { *(.dtors)   }
  62
  63   /* Read-write section, merged into data segment: */
  64   . = (. + 0x0FFF) & 0xFFFFF000;
  65   _erotext = .;
  66   PROVIDE (erotext = .);
  67   .reloc   :
  68   {
  69     *(.got)
  70     _GOT2_TABLE_ = .;
  71     *(.got2)
  72     _FIXUP_TABLE_ = .;
  73     *(.fixup)
  74   }
  75   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  76   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  77
  78   .data    :
  79   {
  80     *(.data)
  81     *(.data1)
  82     *(.sdata)
  83     *(.sdata2)
  84     *(.dynamic)
  85     CONSTRUCTORS
  86   }
  87   _edata  =  .;
  88   PROVIDE (edata = .);
  89
  90   . = .;
  91   __u_boot_cmd_start = .;
  92   .u_boot_cmd : { *(.u_boot_cmd) }
  93   __u_boot_cmd_end = .;
  94
  95
  96   . = .;
  97   __start___ex_table = .;
  98   __ex_table : { *(__ex_table) }
  99   __stop___ex_table = .;
 100
 101   . = ALIGN(4096);
 102   __init_begin = .;
 103   .text.init : { *(.text.init) }
 104   .data.init : { *(.data.init) }
 105   . = ALIGN(4096);
 106   __init_end = .;
 107
 108   __bss_start = .;
 109   .bss (NOLOAD)       :
 110   {
 111    *(.sbss) *(.scommon)
 112    *(.dynbss)
 113    *(.bss)
 114    *(COMMON)
 115    . = ALIGN(4);
 116   }
 117   _end = . ;
 118   PROVIDE (end = .);
 119 }
 120 ENTRY(_start)