arch/powerpc/cpu/mpc5xxx/u-boot.lds

   1 /*
   2  * (C) Copyright 2003-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9
  10 SECTIONS
  11 {
  12   /* Read-only sections, merged into text segment: */
  13   .text      :
  14   {
  15     arch/powerpc/cpu/mpc5xxx/start.o    (.text*)
  16     arch/powerpc/cpu/mpc5xxx/traps.o    (.text*)
  17     *(.text*)
  18     . = ALIGN(16);
  19     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  20   }
  21
  22   /* Read-write section, merged into data segment: */
  23   . = (. + 0x0FFF) & 0xFFFFF000;
  24   _erotext = .;
  25   PROVIDE (erotext = .);
  26   .reloc   :
  27   {
  28     _GOT2_TABLE_ = .;
  29     KEEP(*(.got2))
  30     KEEP(*(.got))
  31     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  32     _FIXUP_TABLE_ = .;
  33     KEEP(*(.fixup))
  34   }
  35   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  36   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  37
  38   .data    :
  39   {
  40     *(.data*)
  41     *(.sdata*)
  42   }
  43   _edata  =  .;
  44   PROVIDE (edata = .);
  45
  46   . = .;
  47
  48   . = ALIGN(4);
  49   .u_boot_list : {
  50         KEEP(*(SORT(.u_boot_list*)));
  51   }
  52
  53
  54   . = .;
  55   __start___ex_table = .;
  56   __ex_table : { *(__ex_table) }
  57   __stop___ex_table = .;
  58
  59   . = ALIGN(4096);
  60   __init_begin = .;
  61   .text.init : { *(.text.init) }
  62   .data.init : { *(.data.init) }
  63   . = ALIGN(4096);
  64   __init_end = .;
  65
  66   __bss_start = .;
  67   .bss (NOLOAD)       :
  68   {
  69    *(COMMON)
  70    *(.bss*)
  71    *(.sbss*)
  72    . = ALIGN(4);
  73   }
  74   __bss_end = . ;
  75   PROVIDE (end = .);
  76 }